handicap.qc File Reference

Source file that contains implementation of the handicap system. More...

#include "handicap.qh"
#include <common/state.qh>
#include <common/ent_cs.qh>
#include <lib/replicate.qh>
#include <server/client.qh>

Include dependency graph for handicap.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
float	Handicap_GetForcedHandicap (entity player, bool receiving)
	Returns the forced handicap of the player.
float	Handicap_GetTotalHandicap (entity player, bool receiving)
	Returns the total handicap of the player.
float	Handicap_GetVoluntaryHandicap (entity player, bool receiving)
	Returns the voluntary handicap of the player.
void	Handicap_Initialize (entity player)
	Initializes handicap to its default value.
void	Handicap_SetForcedHandicap (entity player, float value, bool receiving)
	Sets the forced handicap of the player.
void	Handicap_UpdateHandicapLevel (entity player)
	Updates .handicap_level for the player.
	REPLICATE_APPLYCHANGE ("cl_handicap_damage_given", { Handicap_UpdateHandicapLevel(this);})
	REPLICATE_APPLYCHANGE ("cl_handicap_damage_taken", { Handicap_UpdateHandicapLevel(this);})

Variables
float	m_handicap_give
	Holds the forced handicap value.
float	m_handicap_take
	Holds the forced handicap value.

Detailed Description

Source file that contains implementation of the handicap system.

Author

Lyberta

Copyright

GNU GPLv2 or any later version.

Definition in file handicap.qc.

Function Documentation

Handicap_GetForcedHandicap()

float Handicap_GetForcedHandicap	(	entity	player,
		bool	receiving )

Returns the forced handicap of the player.

Parameters

[in]	player	Player to check.
[in]	receiving	Whether handicap is for receiving or dealing.

Returns

Forced handicap of the player.

Definition at line 71 of file handicap.qc.

{
    if (HANDICAP_DISABLED())
        return 1;
    if (receiving)
        return (CS(player)) ? CS(player).m_handicap_take : 1;
    else
        return (CS(player)) ? CS(player).m_handicap_give : 1;
}

References CS(), entity(), and HANDICAP_DISABLED.

Referenced by Handicap_GetTotalHandicap().

Handicap_GetTotalHandicap()

float Handicap_GetTotalHandicap	(	entity	player,
		bool	receiving )

Returns the total handicap of the player.

Parameters

[in]	player	Player to check.
[in]	receiving	Whether handicap is for receiving or dealing.

Returns

Total handicap of the player.

Definition at line 96 of file handicap.qc.

{
    if (HANDICAP_DISABLED())
        return 1;
    return Handicap_GetForcedHandicap(player, receiving) *
        Handicap_GetVoluntaryHandicap(player, receiving);
}

References entity(), HANDICAP_DISABLED, Handicap_GetForcedHandicap(), and Handicap_GetVoluntaryHandicap().

Referenced by Handicap_UpdateHandicapLevel(), PlayerDamage(), and PlayerFrame().

Handicap_GetVoluntaryHandicap()

float Handicap_GetVoluntaryHandicap	(	entity	player,
		bool	receiving )

Returns the voluntary handicap of the player.

Parameters

[in]	player	Player to check.
[in]	receiving	Whether handicap is for receiving or dealing.

Returns

Voluntary handicap of the player.

Definition at line 25 of file handicap.qc.

{
    if (HANDICAP_DISABLED())
        return 1;
#if 0
    if (receiving)
        return bound(1.0, CS_CVAR(player).cvar_cl_handicap_damage_taken, 10.0);
    else
        return bound(1.0, CS_CVAR(player).cvar_cl_handicap_damage_given, 10.0);
#else
    // TODO: remove the else vector branch after 0.9 release
    // Forwards compatibility for old clients on new servers. `cl_handicap 2`
    // ( '2 0 0' ) is treated the same as `cl_handicap_damage_{given,taken} 2`.
    // The x is give and y is take.
    // '2 0 0' gives and takes x2
    // '2 2 0' gives and takes x2
    // '2 1 0' only gives x2
    // '1 2 0' only takes x2
    // z is wasted
 
    int handicap_value;
 
    // First read if the new cvars have a valid value,
    // if they don't then read old cvar, checking if the old cvar has
    // separate give and take values or we should use the first value for both
    if (receiving)
    {
        if (CS_CVAR(player).cvar_cl_handicap_damage_taken > 1)
            handicap_value = CS_CVAR(player).cvar_cl_handicap_damage_taken;
        else if (CS_CVAR(player).cvar_cl_handicap.y > 0)
            handicap_value = CS_CVAR(player).cvar_cl_handicap.y;
        else
            handicap_value = CS_CVAR(player).cvar_cl_handicap.x;
    }
    else
    {
        if (CS_CVAR(player).cvar_cl_handicap_damage_given > 1)
            handicap_value = CS_CVAR(player).cvar_cl_handicap_damage_given;
        else
            handicap_value = CS_CVAR(player).cvar_cl_handicap.x;
    }
 
    return bound(1.0, handicap_value, 10.0);
#endif
}

References bound(), CS_CVAR, entity(), and HANDICAP_DISABLED.

Referenced by Handicap_GetTotalHandicap().

Handicap_Initialize()

void Handicap_Initialize

(

entity

player

)

Initializes handicap to its default value.

Parameters

[in,out]

player

Player to initialize.

Returns

No return.

Definition at line 16 of file handicap.qc.

{
    // forced handicap defaults
    CS(player).m_handicap_give = 1;
    CS(player).m_handicap_take = 1;
 
    Handicap_UpdateHandicapLevel(player);
}

References CS(), entity(), and Handicap_UpdateHandicapLevel().

Referenced by ClientConnect().

Handicap_SetForcedHandicap()

void Handicap_SetForcedHandicap	(	entity	player,
		float	value,
		bool	receiving )

Sets the forced handicap of the player.

Parameters

[in]	player	Player to alter.
[in]	value	Handicap value to set.
[in]	receiving	Whether handicap is for receiving or dealing.

Returns

No return.

Definition at line 81 of file handicap.qc.

{
    if (HANDICAP_DISABLED())
        return;
    if (value <= 0)
        error("Handicap_SetForcedHandicap: Invalid handicap value.");
 
    if (receiving)
        CS(player).m_handicap_take = value;
    else
        CS(player).m_handicap_give = value;
 
    Handicap_UpdateHandicapLevel(player);
}

References CS(), entity(), error, HANDICAP_DISABLED, and Handicap_UpdateHandicapLevel().

Referenced by DynamicHandicap_UpdateHandicap().

Handicap_UpdateHandicapLevel()

void Handicap_UpdateHandicapLevel

(

entity

player

)

Updates .handicap_level for the player.

Parameters

[in]

player

Player to check.

Definition at line 104 of file handicap.qc.

{
    if (HANDICAP_DISABLED())
    {
        player.handicap_level = 0;
        return;
    }
 
    float handicap_total = (Handicap_GetTotalHandicap(player, true) +
        Handicap_GetTotalHandicap(player, false)) / 2;
    player.handicap_level = floor(map_bound_ranges(handicap_total, 1, HANDICAP_MAX_LEVEL_EQUIVALENT, 0, 16));
}

References entity(), floor(), HANDICAP_DISABLED, Handicap_GetTotalHandicap(), HANDICAP_MAX_LEVEL_EQUIVALENT, and map_bound_ranges().

Referenced by Handicap_Initialize(), Handicap_SetForcedHandicap(), REPLICATE_APPLYCHANGE(), and REPLICATE_APPLYCHANGE().

REPLICATE_APPLYCHANGE() [1/2]

REPLICATE_APPLYCHANGE	(	"cl_handicap_damage_given"	,
		{ Handicap_UpdateHandicapLevel(this);}	)

References Handicap_UpdateHandicapLevel().

REPLICATE_APPLYCHANGE() [2/2]

REPLICATE_APPLYCHANGE	(	"cl_handicap_damage_taken"	,
		{ Handicap_UpdateHandicapLevel(this);}	)

References Handicap_UpdateHandicapLevel().

Variable Documentation

m_handicap_give

float m_handicap_give

Holds the forced handicap value.

Definition at line 13 of file handicap.qc.

m_handicap_take

float m_handicap_take

Holds the forced handicap value.

Definition at line 14 of file handicap.qc.