This graph shows which files directly or indirectly include this file:

Functions
void	WarpZone_FixPMove ()
void	WarpZone_FixView ()
void	WarpZone_Shutdown ()

Variables
vector	warpzone_save_view_angles
vector	warpzone_save_view_origin

Function Documentation

◆ WarpZone_FixPMove()

void WarpZone_FixPMove ( )

Definition at line 211 of file client.qc.

{
    entity e = WarpZone_Find(pmove_org, pmove_org);
    if(e)
    {
        pmove_org = WarpZone_TransformOrigin(e, pmove_org);
        input_angles = WarpZone_TransformVAngles(e, input_angles);
    }
}

References entity(), input_angles, pmove_org, WarpZone_Find(), WarpZone_TransformOrigin(), and WarpZone_TransformVAngles().

◆ WarpZone_FixView()

void WarpZone_FixView ( )

Definition at line 224 of file client.qc.

{
    entity e;
    vector org, ang, nearclip, corner0, corner1, corner2, corner3, o;
 
    warpzone_save_view_origin = org = getpropertyvec(VF_ORIGIN);
    warpzone_save_view_angles = ang = getpropertyvec(VF_ANGLES);
 
    e = WarpZone_Find(org, org);
    if(e)
    {
        org = WarpZone_TransformOrigin(e, org);
        ang = WarpZone_TransformVAngles(e, ang);
        WarpZone_View_Inside();
    }
    else
        WarpZone_View_Outside();
 
#ifndef KEEP_ROLL
    float rick;
    float f;
    static float rollkill;
    if (STAT(HEALTH) > 0 || STAT(HEALTH) == -666 || STAT(HEALTH) == -2342)
    {
        f = 0;
        // reset roll when passing through a warpzone that change player's roll angle
        if(autocvar_cl_rollkillspeed)
            f = max(0, (1 - frametime * autocvar_cl_rollkillspeed));
        if(rollkill)
            rollkill = 0;
    }
    else
    {
        f = 1;
        // roll the view when killed (v_deathtilt)
        if(autocvar_cl_rollkillspeed)
        {
            rollkill += frametime * autocvar_cl_rollkillspeed;
            f = min(1, rollkill);
        }
        else if(rollkill)
            rollkill = 0;
    }
 
    rick = getproperty(VF_CL_VIEWANGLES_Z);
    rick *= f;
    setproperty(VF_CL_VIEWANGLES_Z, rick);
    ang.z *= f;
#endif
 
    setproperty(VF_ORIGIN, org);
    setproperty(VF_ANGLES, ang);
 
    vector width = '1 0 0' * cvar("vid_conwidth");
    vector height = '0 1 0' * cvar("vid_conheight");
    nearclip = '0 0 1' * (cvar("r_nearclip") * 1.125);
    corner0 = cs_unproject('0 0 0' + nearclip);
    corner1 = cs_unproject(width + nearclip);
    corner2 = cs_unproject(height + nearclip);
    corner3 = cs_unproject(width + height + nearclip);
    o = WarpZone_FixNearClip(org, corner0, corner1, corner2, corner3);
    if(o != '0 0 0')
        setproperty(VF_ORIGIN, org + o);
}