spawning.qc

Go to the documentation of this file.

#include "spawning.qh"

 
#include <common/mapobjects/subs.qh>
#include <common/mutators/mutator/powerups/_mod.qh>
#include <common/weapons/all.qh>
#include <server/items/items.qh>
#include <server/mutators/_mod.qh>
#include <server/weapons/spawning.qh>
#include <server/world.qh>
 
 
bool Item_IsDefinitionAllowed(entity definition)
{
    return !MUTATOR_CALLHOOK(FilterItemDefinition, definition);
}
 
// An optimised and generic way to initialise items (loot or permanent)
// required field: itemdef (faster, preferred) OR classname
// optional fields: origin, velocity, lifetime, noalign
// lifetime < 0 means permanent (not loot), lifetime > 0 overrides the default
// permanent items only: noalign means the item is suspended (won't drop to floor)
bool Item_Initialise(entity item)
{
    if (item.lifetime >= 0)
        ITEM_SET_LOOT(item, true);
    if (ITEM_IS_LOOT(item))
        item.pickup_anyway = true; // these are ALWAYS pickable
 
    if (item.itemdef) // no search required
        StartItem(item);
    else // fall back to classname search
    {
        FOREACH(Weapons, it.m_canonical_spawnfunc == item.classname,
        {
            item.itemdef = it;
            goto classname_found;
        });
        FOREACH(Items, it.m_canonical_spawnfunc == item.classname,
        {
            item.itemdef = it;
            goto classname_found;
        });
        LOG_WARNF("Item_Initialise: invalid item classname \"%s\"", item.classname);
        return false;
 
        LABEL(classname_found)
        StartItem(item);
    }
 
    if (wasfreed(item))
        return false;
 
    // StartItem sets the default .wait expiry time which is respected by Item_Think()
    if (item.lifetime > 0)
        item.wait = time + item.lifetime;
 
    item.spawnfunc_checked = true;
    return true;
}

entity Item_RandomFromList(string itemlist)
{
    if(itemlist == "")
        return NULL;
 
    RandomSelection_Init();
    FOREACH_WORD(itemlist, true,
    {
        string item = it;
 
        FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED),
        {
            if(it.netname == item || (item == "random" && (it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & WEP_FLAG_HIDDEN) && !(it.spawnflags & WEP_FLAG_SUPERWEAPON)))
                RandomSelection_AddEnt(it, 1, 1);
        });
        FOREACH(Items, Item_IsDefinitionAllowed(it),
        {
            if(it.netname == item || (item == "random" && (it.spawnflags & ITEM_FLAG_NORMAL) && !it.instanceOfPowerup))
                RandomSelection_AddEnt(it, 1, 1);
        });
    });
    return RandomSelection_chosen_ent;
}
 
 
// Compatibility spawn functions
 
// in Quake this is green armor, in Xonotic maps it is an armor shard
SPAWNFUNC_ITEM(item_armor1, autocvar_sv_mapformat_is_quake3 ? ITEM_ArmorSmall : ITEM_ArmorMedium)
SPAWNFUNC_ITEM(item_armor25, ITEM_ArmorMega) // Nexuiz used item_armor25 to spawn a Mega Armor
SPAWNFUNC_ITEM(item_health1, ITEM_HealthSmall)
SPAWNFUNC_ITEM(item_health25, ITEM_HealthMedium)
SPAWNFUNC_ITEM(item_health100, ITEM_HealthMega)
SPAWNFUNC_ITEM(item_armor_large, ITEM_ArmorMega)
SPAWNFUNC_ITEM(item_health_large, ITEM_HealthBig)