utility.qc File Reference

#include "utility.qh"
#include <common/stats.qh>
#include <common/weapons/_all.qh>
#include <server/pathlib/pathlib.qh>

Include dependency graph for utility.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
bool	location_isok (vector point, bool waterok, bool air_isok)
entity	pathlib_nodeatpoint (vector where)
bool	tile_check_cross (entity this, vector where)
bool	tile_check_plus (entity this, vector where)
float	tile_check_plus2 (entity this, vector where)
bool	tile_check_star (entity this, vector where)

Function Documentation

location_isok()

bool location_isok	(	vector	point,
		bool	waterok,
		bool	air_isok )

Definition at line 7 of file utility.qc.

{
    if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
        return false;
 
    int pc = pointcontents(point);
    int pc2 = pointcontents(point - '0 0 1');
 
    if(pc == CONTENT_EMPTY && pc2 == CONTENT_SOLID)
        return true;
    if(pc == CONTENT_EMPTY && pc2 == CONTENT_WATER && waterok)
        return true;
    if(pc == CONTENT_EMPTY && pc2 == CONTENT_EMPTY && air_isok)
        return true;
    if(pc == CONTENT_WATER && waterok)
        return true;
    return false;
}

References CONTENT_EMPTY, CONTENT_SOLID, CONTENT_WATER, Q3SURFACEFLAG_SKY, trace_dphitq3surfaceflags, and vector.

Referenced by beamsweep(), tile_check_cross(), tile_check_plus(), and tile_check_plus2().

pathlib_nodeatpoint()

entity pathlib_nodeatpoint

(

vector

where

)

Definition at line 26 of file utility.qc.

{
    ++pathlib_searched_cnt;
 
    where.x = fsnap(where.x,pathlib_gridsize);
    where.y = fsnap(where.y,pathlib_gridsize);
 
    entity found = NULL; // TODO: using FOREACH_ENTITY_RADIUS here causes mutex loop warnings, this may need a proper fix!
    IL_EACH(g_pathlib_nodes, it.is_path_node && vdist(it.origin - where, <, pathlib_gridsize * 0.5),
    {
        found = it;
        break;
    });
 
    return found;
}

References entity(), fsnap(), g_pathlib_nodes, IL_EACH, NULL, pathlib_gridsize, pathlib_searched_cnt, vdist, and vector.

Referenced by pathlib_makenode_adaptive(), and pathlib_mknode().

tile_check_cross()

bool tile_check_cross	(	entity	this,
		vector	where )

Definition at line 43 of file utility.qc.

{
    vector p;
    vector f = PLIB_FORWARD * tile_check_size;
    vector r = PLIB_RIGHT   * tile_check_size;
 
 
    // forward-right
    p = where + f + r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (!location_isok(trace_endpos, 1, 0))
        return false;
 
    // Forward-left
    p = where + f - r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (!location_isok(trace_endpos, 1, 0))
        return false;
 
    // Back-right
    p = where - f + r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (!location_isok(trace_endpos, 1 ,0))
        return false;
 
    //Back-left
    p = where - f - r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (!location_isok(trace_endpos, 1, 0))
        return false;
 
    return true;
}

References entity(), location_isok(), MOVE_WORLDONLY, PLIB_FORWARD, PLIB_RIGHT, tile_check_down, tile_check_size, tile_check_up, trace_endpos, and vector.

Referenced by pathlib_astar(), and tile_check_star().

tile_check_plus()

bool tile_check_plus	(	entity	this,
		vector	where )

Definition at line 77 of file utility.qc.

{
    vector p;
 
    vector f = PLIB_FORWARD * tile_check_size;
    vector r = PLIB_RIGHT   * tile_check_size;
 
    // forward
    p = where + f;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (!location_isok(trace_endpos,1,0))
        return false;
 
 
    //left
    p = where - r;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (!location_isok(trace_endpos,1,0))
        return false;
 
    // Right
    p = where + r;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (!location_isok(trace_endpos,1,0))
        return false;
 
    //Back
    p = where - f;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (!location_isok(trace_endpos,1,0))
        return false;
 
    return true;
}

References entity(), location_isok(), MOVE_WORLDONLY, PLIB_FORWARD, PLIB_RIGHT, tile_check_down, tile_check_size, tile_check_up, trace_endpos, and vector.

Referenced by tile_check_star().

tile_check_plus2()

float tile_check_plus2	(	entity	this,
		vector	where )

Definition at line 112 of file utility.qc.

{
    vector p;
    int j = 0, e = 0;
 
    vector f = PLIB_FORWARD * pathlib_gridsize;
    vector r = PLIB_RIGHT   * pathlib_gridsize;
 
//#define pathlib_node_edgeflag_left    2
//#define pathlib_node_edgeflag_right   4
//#define pathlib_node_edgeflag_forward 8
//#define pathlib_node_edgeflag_back    16
 
    // forward
    p = where + f;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (location_isok(trace_endpos,1,0))
    {
       ++j;
       e |= pathlib_node_edgeflag_forward;
    }
 
 
    //left
    p = where - r;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (location_isok(trace_endpos,1,0))
    {
       ++j;
       e |= pathlib_node_edgeflag_left;
    }
 
 
    // Right
    p = where + r;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (location_isok(trace_endpos,1,0))
    {
       ++j;
       e |= pathlib_node_edgeflag_right;
    }
 
    //Back
    p = where - f;
    traceline(p+tile_check_up,p-tile_check_down,MOVE_WORLDONLY,this);
    if (location_isok(trace_endpos,1,0))
    {
       ++j;
       e |= pathlib_node_edgeflag_back;
    }
 
    // forward-right
    p = where + f + r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (location_isok(trace_endpos, 1, 0))
    {
       ++j;
       e |= pathlib_node_edgeflag_forwardright;
    }
 
    // Forward-left
    p = where + f - r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (location_isok(trace_endpos, 1, 0))
    {
       ++j;
       e |= pathlib_node_edgeflag_forwardleft;
    }
 
    // Back-right
    p = where - f + r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (location_isok(trace_endpos, 1 ,0))
    {
       ++j;
       e |= pathlib_node_edgeflag_backright;
    }
 
    //Back-left
    p = where - f - r;
    traceline(p + tile_check_up, p - tile_check_down, MOVE_WORLDONLY, this);
    if (location_isok(trace_endpos, 1, 0))
    {
       ++j;
       e |= pathlib_node_edgeflag_backleft;
    }
 
 
    if(j == 0)
        e = pathlib_node_edgeflag_none;
 
    return e;
}

References entity(), location_isok(), MOVE_WORLDONLY, pathlib_gridsize, pathlib_node_edgeflag_back, pathlib_node_edgeflag_backleft, pathlib_node_edgeflag_backright, pathlib_node_edgeflag_forward, pathlib_node_edgeflag_forwardleft, pathlib_node_edgeflag_forwardright, pathlib_node_edgeflag_left, pathlib_node_edgeflag_none, pathlib_node_edgeflag_right, PLIB_FORWARD, PLIB_RIGHT, tile_check_down, tile_check_up, trace_endpos, and vector.

Referenced by pathlib_expandnode_star().

tile_check_star()

bool tile_check_star	(	entity	this,
		vector	where )

Definition at line 206 of file utility.qc.

{
    if(tile_check_plus(this, where))
        return tile_check_cross(this, where);
 
    return false;
}

References entity(), tile_check_cross(), tile_check_plus(), and vector.