cl_damagetext.qc File Reference

#include "cl_damagetext.qh"

Include dependency graph for cl_damagetext.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Classes
class	DamageText

Functions
float	current_alpha (entity damage_text)
	NET_HANDLE (damagetext, bool isNew)

Function Documentation

current_alpha()

float current_alpha

(

entity

damage_text

)

Definition at line 213 of file cl_damagetext.qc.

{
    // alpha doesn't change - actual alpha is always calculated from the initial value
    return damage_text.alpha - (time - damage_text.hit_time) * damage_text.fade_rate;
}

References current_alpha(), entity(), float(), and time.

Referenced by current_alpha().

NET_HANDLE()

NET_HANDLE	(	damagetext	,
		bool	isNew )

Definition at line 219 of file cl_damagetext.qc.

{
    make_pure(this);
    int server_entity_index = ReadByte();
    int deathtype = ReadInt24_t();
    int flags = ReadByte();
    bool friendlyfire = flags & DTFLAG_SAMETEAM;
 
    int health, armor, potential_damage;
    if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
    else health = ReadShort();
    if (flags & DTFLAG_NO_ARMOR) armor = 0;
    else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
    else armor = ReadShort();
    if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
    else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
    else potential_damage = ReadShort();
 
    return = true;
    if (!isNew) return;
    if (autocvar_cl_damagetext == 0) return;
    if (friendlyfire)
    {
        if (autocvar_cl_damagetext_friendlyfire == 0)
            return;
 
        if (autocvar_cl_damagetext_friendlyfire == 1
        && health == 0 && armor == 0)
            return;
    }
 
    int client_entity_index = server_entity_index - 1;
    entity entcs = entcs_receiver(client_entity_index);
 
    bool can_use_3d = entcs && entcs.has_origin;
    bool too_close = vdist(entcs.origin - view_origin, <, autocvar_cl_damagetext_2d_close_range);
    bool prefer_in_view = autocvar_cl_damagetext_2d_out_of_view && !projected_on_screen(project_3d_to_2d(entcs.origin));
    bool prefer_2d = spectatee_status != -1 && autocvar_cl_damagetext_2d && (too_close || prefer_in_view);
 
    vector position;
    bool is2d;
    entity entDT = NULL; // which DT to update
 
    float alphathreshold = autocvar_cl_damagetext_accumulate_alpha_rel
                    * autocvar_cl_damagetext_alpha_start;
 
    // check if this entity already has a DamageText for it
    IL_EACH(g_damagetext, it.m_group == server_entity_index, {
        // if the time window where damage accumulates closes,
        // disown the parent entity from this DamageText
        // and (likely) give the entity a new DT afterwards
        // this should only cancel damage accumulation for this DT
 
        if (flags & DTFLAG_STOP_ACCUMULATION
            || (current_alpha(it) < alphathreshold)
            || ((autocvar_cl_damagetext_accumulate_lifetime >= 0) // negative never disowns
                && (time - it.hit_time > autocvar_cl_damagetext_accumulate_lifetime)))
        {
            it.m_group = 0;
        }
        else
        {
            health += it.m_healthdamage;
            armor += it.m_armordamage;
            potential_damage += it.m_potential_damage;
 
            entDT = it;
        }
        break;
    });
 
    if (can_use_3d && !prefer_2d)
    {
        // world coords
        is2d = false;
        position = entcs.origin;
 
        if (entDT)
            goto updateDT;
 
        // 3D DamageTexts can later be changed into 2D,
        // increment this here just in case
        ++DamageText_screen_count;
        goto spawnnewDT;
    }
    else if (autocvar_cl_damagetext_2d && spectatee_status != -1)
    {
        // screen coords only
        is2d = true;
        position = vec2(vid_conwidth  * autocvar_cl_damagetext_2d_pos.x,
                        vid_conheight * autocvar_cl_damagetext_2d_pos.y);
 
        if (entDT)
            goto updateDT;
 
        // offset when hitting multiple enemies, dmgtext would overlap
        position += autocvar_cl_damagetext_2d_overlap_offset * DamageText_screen_count++;
        goto spawnnewDT;
    }
    return;
 
LABEL(updateDT)
    DamageText_update(entDT, position, is2d, health, armor, potential_damage, deathtype);
    return;
 
LABEL(spawnnewDT)
    NEW(DamageText, server_entity_index, position, is2d,
        health, armor, potential_damage, deathtype, friendlyfire);
    return;
}

References autocvar_cl_damagetext, autocvar_cl_damagetext_2d, autocvar_cl_damagetext_2d_close_range, autocvar_cl_damagetext_2d_out_of_view, autocvar_cl_damagetext_accumulate_alpha_rel, autocvar_cl_damagetext_alpha_start, autocvar_cl_damagetext_friendlyfire, DTFLAG_BIG_ARMOR, DTFLAG_BIG_HEALTH, DTFLAG_BIG_POTENTIAL, DTFLAG_NO_ARMOR, DTFLAG_NO_POTENTIAL, DTFLAG_SAMETEAM, entcs, entcs_receiver, entity(), flags, g_damagetext, health, IL_EACH, make_pure, NULL, project_3d_to_2d(), projected_on_screen(), ReadByte(), ReadInt24_t(), spectatee_status, vdist, vector, and view_origin.