util.qc File Reference

#include "util.qh"

Include dependency graph for util.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	FireImoBeam (entity this, vector start, vector end, vector smin, vector smax, float bforce, float f_dmg, float f_velfactor, int deathtype)
float	turret_tag_fire_update (entity this)

Function Documentation

FireImoBeam()

void FireImoBeam	(	entity	this,
		vector	start,
		vector	end,
		vector	smin,
		vector	smax,
		float	bforce,
		float	f_dmg,
		float	f_velfactor,
		int	deathtype )

Definition at line 27 of file util.qc.

{
    vector dir = normalize(end - start);
    vector force = dir * bforce;
 
    // go a little bit into the wall because we need to hit this wall later
    end = end + dir;
 
    // trace multiple times until we hit a wall, each obstacle will be made unsolid.
    // note down which entities were hit so we can damage them later
    entity o = this;
    while (1)
    {
        if(CS(this).antilag_debug)
            WarpZone_tracebox_antilag (this, start, smin, smax, end, false, o, CS(this).antilag_debug);
        else
            WarpZone_tracebox_antilag (this, start, smin, smax, end, false, o, ANTILAG_LATENCY(this));
        if(o && WarpZone_trace_firstzone)
        {
            o = NULL;
            continue;
        }
 
        // if it is NULL we can't hurt it so stop now
        if (trace_ent == NULL || trace_fraction == 1)
            break;
 
        // make the entity non-solid so we can hit the next one
        IL_PUSH(g_railgunhit, trace_ent);
        trace_ent.railgunhit = true;
        trace_ent.railgunhitloc = end;
        trace_ent.railgunhitsolidbackup = trace_ent.solid;
        trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
        trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 
        // stop if this is a wall
        if (trace_ent.solid == SOLID_BSP)
            break;
 
        // make the entity non-solid
        trace_ent.solid = SOLID_NOT;
    }
 
    vector endpoint = trace_endpos;
    entity endent = trace_ent;
    float endq3surfaceflags = trace_dphitq3surfaceflags;
 
    // find all the entities the railgun hit and restore their solid state
    IL_EACH(g_railgunhit, it.railgunhit,
    {
        it.solid = it.railgunhitsolidbackup;
    });
 
    /*
        Unlike the railgun, this does NOT check for targets close by
    */
 
    // find all the entities the railgun hit and hurt them
    IL_EACH(g_railgunhit, it.railgunhit,
    {
        // removal from the list is handled below
        /* no falloff applied */
 
        // apply the damage
        if (it.takedamage)
        {
            Damage(it, this, this, f_dmg, deathtype, DMG_NOWEP, it.railgunhitloc, it.railgunforce);
            // slow down the target
            it.velocity = it.velocity * f_velfactor;
        }
 
        it.railgunhitloc = '0 0 0';
        it.railgunhitsolidbackup = SOLID_NOT;
        it.railgunhit = false;
        it.railgundistance = 0;
    });
 
    IL_CLEAR(g_railgunhit);
 
    /* no accuracy, as a weapon entity is not attached */
 
    trace_endpos = endpoint;
    trace_ent = endent;
    trace_dphitq3surfaceflags = endq3surfaceflags;
}

References antilag_debug, ANTILAG_LATENCY, CS(), dir, entity(), g_railgunhit, IL_EACH, IL_PUSH(), normalize(), NULL, SOLID_BSP, SOLID_NOT, trace_dphitq3surfaceflags, trace_endpos, trace_ent, trace_fraction, vector, vlen(), WarpZone_trace_firstzone, WarpZone_trace_transform, WarpZone_tracebox_antilag(), WarpZone_TransformVelocity(), and WarpZone_UnTransformOrigin().

Referenced by beam_think().

turret_tag_fire_update()

float turret_tag_fire_update

(

entity

this

)

Definition at line 9 of file util.qc.

{
    if(!this.tur_head)
    {
        LOG_DEBUG("Call to turret_tag_fire_update with this.tur_head missing!");
        this.tur_shotorg = '0 0 0';
        return false;
    }
 
    this.tur_shotorg = gettaginfo(this.tur_head, gettagindex(this.tur_head, "tag_fire"));
    v_forward = normalize(v_forward);
 
    return true;
}

References entity(), gettagindex, gettaginfo, LOG_DEBUG, normalize(), tur_head, tur_shotorg, and v_forward.

Referenced by turret_aim_generic(), turret_do_updates(), and turret_initialize().