maplist.qc File Reference

#include "maplist.qh"
#include <common/mapinfo.qh>
#include "dialog_multiplayer_create_mapinfo.qh"
#include "mainwindow.qh"
#include "inputbox.qh"

Include dependency graph for maplist.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
entity	makeXonoticMapList ()
void	MapList_Add_All (entity btn, entity me)
void	MapList_Add_Shown (entity btn, entity me)
void	MapList_LoadMap (entity btn, entity me)
void	MapList_Remove_All (entity btn, entity me)
void	MapList_Remove_Shown (entity btn, entity me)
entity	MapList_Set_StringFilterBox (entity me, entity e)
void	MapList_StringFilterBox_Change (entity box, entity me)
float	MapList_StringFilterBox_keyDown (entity me, float scan, float ascii, float shift)
void	XonoticMapList_clickListBoxItem (entity me, float i, vector where)
void	XonoticMapList_configureXonoticMapList (entity me)
void	XonoticMapList_destroy (entity me)
void	XonoticMapList_doubleClickListBoxItem (entity me, float i, vector where)
void	XonoticMapList_draw (entity me)
void	XonoticMapList_drawListBoxItem (entity me, int i, vector absSize, bool isSelected, bool isFocused)
float	XonoticMapList_g_maplistCacheQuery (entity me, float i)
void	XonoticMapList_g_maplistCacheToggle (entity me, float i)
float	XonoticMapList_keyDown (entity me, float scan, float ascii, float shift)
void	XonoticMapList_loadCvars (entity me)
void	XonoticMapList_refilter (entity me)
void	XonoticMapList_refilterCallback (entity me, entity cb)
void	XonoticMapList_resizeNotify (entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)

Variables
bool	disabled

Function Documentation

makeXonoticMapList()

entity makeXonoticMapList

(

)

Definition at line 15 of file maplist.qc.

{
    entity me;
    me = NEW(XonoticMapList);
    me.configureXonoticMapList(me);
    return me;
}

References entity(), and NEW.

Referenced by XonoticServerCreateTab_fill().

MapList_Add_All()

void MapList_Add_All	(	entity	btn,
		entity	me )

Definition at line 260 of file maplist.qc.

{
    float i;
    string s;
    _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MapInfo_ForbiddenFlags(), 0); // all
    s = "";
    for(i = 0; i < MapInfo_count; ++i)
        s = cons(s, MapInfo_BSPName_ByID(i));
    cvar_set("g_maplist", s);
    me.refilter(me);
}

References _MapInfo_FilterGametype(), cons(), cvar_set(), entity(), MapInfo_BSPName_ByID(), MapInfo_count, MapInfo_ForbiddenFlags(), and MAPINFO_TYPE_ALL.

Referenced by XonoticServerCreateTab_fill().

MapList_Add_Shown()

void MapList_Add_Shown	(	entity	btn,
		entity	me )

Definition at line 236 of file maplist.qc.

{
    float i, n;
    n = strlen(me.g_maplistCache);
    for (i = 0 ; i < n; ++i)
    {
        if (!me.g_maplistCacheQuery(me, i))
            me.g_maplistCacheToggle(me, i);
    }
    me.refilter(me);
}

References entity(), and strlen.

Referenced by XonoticServerCreateTab_fill().

MapList_LoadMap()

void MapList_LoadMap	(	entity	btn,
		entity	me )

Definition at line 278 of file maplist.qc.

{
    string m;
    float i;
 
    i = me.selectedItem;
 
    if(btn.parent.instanceOfXonoticMapInfoDialog)
    {
        i = btn.parent.currentMapIndex;
        Dialog_Close(btn, btn.parent);
    }
 
    if(i >= me.nItems || i < 0)
        return;
 
    m = MapInfo_BSPName_ByID(i);
    if (!m)
    {
        LOG_INFO(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again."));
        me.refilter(me);
        return;
    }
    if(MapInfo_CheckMap(m))
    {
        localcmd("\nmenu_loadmap_prepare\n");
        if(cvar("menu_use_default_hostname"))
            localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
        MapInfo_LoadMap(m, 1);
    }
    else
    {
        LOG_INFO(_("Huh? Can't play this (invalid gametype). Refiltering so this won't happen again."));
        me.refilter(me);
        return;
    }
}

References cvar(), cvar_string(), Dialog_Close(), entity(), localcmd(), LOG_INFO, MapInfo_BSPName_ByID(), MapInfo_CheckMap(), and MapInfo_LoadMap().

Referenced by XonoticMapInfoDialog_fill(), and XonoticServerCreateTab_fill().

MapList_Remove_All()

void MapList_Remove_All	(	entity	btn,
		entity	me )

Definition at line 272 of file maplist.qc.

{
    cvar_set("g_maplist", "");
    me.refilter(me);
}

References cvar_set(), and entity().

Referenced by XonoticServerCreateTab_fill().

MapList_Remove_Shown()

void MapList_Remove_Shown	(	entity	btn,
		entity	me )

Definition at line 248 of file maplist.qc.

{
    float i, n;
    n = strlen(me.g_maplistCache);
    for (i = 0 ; i < n; ++i)
    {
        if (me.g_maplistCacheQuery(me, i))
            me.g_maplistCacheToggle(me, i);
    }
    me.refilter(me);
}

References entity(), and strlen.

Referenced by XonoticServerCreateTab_fill().

MapList_Set_StringFilterBox()

entity MapList_Set_StringFilterBox	(	entity	me,
		entity	e )

Definition at line 23 of file maplist.qc.

{
    me.stringFilterBox = e;
    return e;
}

References entity().

MapList_StringFilterBox_Change()

void MapList_StringFilterBox_Change	(	entity	box,
		entity	me )

Definition at line 227 of file maplist.qc.

{
    strfree(me.stringFilter);
    if(box.text != "")
        me.stringFilter = strzone(box.text);
 
    me.refilter(me);
}

References entity(), strfree, and strzone().

Referenced by XonoticMapList_keyDown(), and XonoticServerCreateTab_fill().

MapList_StringFilterBox_keyDown()

float MapList_StringFilterBox_keyDown	(	entity	me,
		float	scan,
		float	ascii,
		float	shift )

Definition at line 391 of file maplist.qc.

{
    // in this section, note that onChangeEntity has the ref to mapListBox
    // we make use of that, instead of extending a class to add one more attrib
    switch(scan)
    {
        case K_KP_ENTER:
        case K_ENTER:
            // move the focus to the mapListBox
            me.onChangeEntity.parent.setFocus(me.onChangeEntity.parent, me.onChangeEntity);
            return 1;
        case K_KP_UPARROW:
        case K_UPARROW:
        case K_KP_DOWNARROW:
        case K_DOWNARROW:
            // pass the event to the mapListBox (to scroll up and down)
            return me.onChangeEntity.keyDown(me.onChangeEntity, scan, ascii, shift);
    }
    return SUPER(XonoticInputBox).keyDown(me, scan, ascii, shift);
}

References entity(), K_DOWNARROW, K_ENTER, K_KP_DOWNARROW, K_KP_ENTER, K_KP_UPARROW, K_UPARROW, and SUPER.

Referenced by XonoticServerCreateTab_fill().

XonoticMapList_clickListBoxItem()

void XonoticMapList_clickListBoxItem	(	entity	me,
		float	i,
		vector	where )

Definition at line 108 of file maplist.qc.

{
    if(where.x <= me.columnPreviewOrigin + me.columnPreviewSize)
        if(where.x >= 0)
        {
            m_play_click_sound(MENU_SOUND_SELECT);
            me.g_maplistCacheToggle(me, i);
        }
}

References entity(), m_play_click_sound(), MENU_SOUND_SELECT, and vector.

XonoticMapList_configureXonoticMapList()

void XonoticMapList_configureXonoticMapList

(

entity

me

)

Definition at line 29 of file maplist.qc.

{
    me.configureXonoticListBox(me);
    me.refilter(me);
}

References entity().

XonoticMapList_destroy()

void XonoticMapList_destroy

(

entity

me

)

Definition at line 10 of file maplist.qc.

{
    MapInfo_Shutdown();
}

References entity(), and MapInfo_Shutdown().

XonoticMapList_doubleClickListBoxItem()

void XonoticMapList_doubleClickListBoxItem	(	entity	me,
		float	i,
		vector	where )

Definition at line 118 of file maplist.qc.

{
    if(where.x >= me.columnNameOrigin)
        if(where.x <= 1)
        {
            // pop up map info screen
            m_play_click_sound(MENU_SOUND_OPEN);
            main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
            DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
        }
}

References DialogOpenButton_Click_withCoords(), entity(), eX, eY, m_play_click_sound(), main, MENU_SOUND_OPEN, NULL, and vector.

XonoticMapList_draw()

void XonoticMapList_draw

(

entity

me

)

Definition at line 79 of file maplist.qc.

{
    if(me.startButton)
        me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems)
            || ((gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) && cvar("g_campaign")));
    SUPER(XonoticMapList).draw(me);
}

References cvar(), entity(), GAME_CONNECTED, GAME_ISSERVER, gamestatus, and SUPER.

XonoticMapList_drawListBoxItem()

void XonoticMapList_drawListBoxItem	(	entity	me,
		int	i,
		vector	absSize,
		bool	isSelected,
		bool	isFocused )

Definition at line 130 of file maplist.qc.

{
    // layout: Ping, Map name, Map name, NP, TP, MP
    string s;
    float theAlpha;
    float included;
 
    if(!MapInfo_Get_ByID(i))
        return;
 
    included = me.g_maplistCacheQuery(me, i);
    if(included || isSelected)
        theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
    else
        theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 
    if(isSelected)
        draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
    else
    {
        if(included)
            draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
        if(isFocused)
        {
            me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
            draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
        }
    }
 
    if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
    {
        if(draw_PictureSize(strcat("/levelshots/", MapInfo_Map_bspname)) == '0 0 0')
            draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
        else
            draw_Picture(me.columnPreviewOrigin * eX, strcat("/levelshots/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
    }
    else
        draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 
    if(included)
        draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
    s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
    draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
    s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
    draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 
    MapInfo_ClearTemps();
}

References draw_Fill(), draw_Picture(), draw_PictureSize(), draw_Text(), draw_TextShortenToWidth(), draw_TextWidth(), entity(), eX, eY, getFadedAlpha(), MapInfo_ClearTemps(), MapInfo_Get_ByID(), MapInfo_Map_author, MapInfo_Map_bspname, MapInfo_Map_titlestring, strcat(), and vector.

XonoticMapList_g_maplistCacheQuery()

float XonoticMapList_g_maplistCacheQuery	(	entity	me,
		float	i )

Definition at line 41 of file maplist.qc.

{
    return stof(substring(me.g_maplistCache, i, 1));
}

References entity(), stof(), and substring().

XonoticMapList_g_maplistCacheToggle()

void XonoticMapList_g_maplistCacheToggle	(	entity	me,
		float	i )

Definition at line 45 of file maplist.qc.

{
    string a, b, c, s, bspname;
    float n;
    s = me.g_maplistCache;
    if (!s)
        return;
    b = substring(s, i, 1);
    if(b == "0")
        b = "1";
    else if(b == "1")
        b = "0";
    else
        return; // nothing happens
    a = substring(s, 0, i);
    c = substring(s, i+1, strlen(s) - (i+1));
    strunzone(s);
    me.g_maplistCache = strzone(strcat(a, b, c));
    // TODO also update the actual cvar
    if (!((bspname = MapInfo_BSPName_ByID(i))))
        return;
    if(b == "1")
        cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
    else
    {
        s = "";
        n = tokenize_console(cvar_string("g_maplist"));
        for(i = 0; i < n; ++i)
            if(argv(i) != bspname)
                s = strcat(s, " ", argv(i));
        cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
    }
}

References argv(), cvar_set(), cvar_string(), entity(), MapInfo_BSPName_ByID(), strcat(), strlen, strunzone(), strzone(), substring(), and tokenize_console.

XonoticMapList_keyDown()

float XonoticMapList_keyDown	(	entity	me,
		float	scan,
		float	ascii,
		float	shift )

Definition at line 316 of file maplist.qc.

{
    string ch, save;
    if(me.nItems <= 0)
        return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
    if(scan == K_MOUSE2 || scan == K_SPACE || scan == K_ENTER || scan == K_KP_ENTER)
    {
        // pop up map info screen
        m_play_click_sound(MENU_SOUND_OPEN);
        main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
        DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
    }
    else if(scan == K_MOUSE3 || scan == K_INS || scan == K_KP_INS || ((shift & S_CTRL) && scan == K_MOUSE1))
    {
        m_play_click_sound(MENU_SOUND_SELECT);
        me.g_maplistCacheToggle(me, me.selectedItem);
    }
    else if(ascii == '+')
    {
        if (!me.g_maplistCacheQuery(me, me.selectedItem))
        {
            m_play_click_sound(MENU_SOUND_SELECT);
            me.g_maplistCacheToggle(me, me.selectedItem);
        }
    }
    else if(ascii == '-')
    {
        if(me.g_maplistCacheQuery(me, me.selectedItem))
        {
            m_play_click_sound(MENU_SOUND_SELECT);
            me.g_maplistCacheToggle(me, me.selectedItem);
        }
    }
    else if(scan == K_BACKSPACE)
    {
        if(time < me.typeToSearchTime)
        {
            save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
            strcpy(me.typeToSearchString, save);
            me.typeToSearchTime = time + 0.5;
            if(strlen(me.typeToSearchString))
            {
                MapInfo_FindName(me.typeToSearchString);
                if(MapInfo_FindName_firstResult >= 0)
                    me.setSelected(me, MapInfo_FindName_firstResult);
            }
        }
    }
    else if(ascii >= 32 && ascii != 127)
    {
        ch = chr(ascii);
        if(time > me.typeToSearchTime)
            save = ch;
        else
            save = strcat(me.typeToSearchString, ch);
        strcpy(me.typeToSearchString, save);
        me.typeToSearchTime = time + 0.5;
        MapInfo_FindName(me.typeToSearchString);
        if(MapInfo_FindName_firstResult >= 0)
            me.setSelected(me, MapInfo_FindName_firstResult);
    }
    else if((shift & S_CTRL) && scan == 'f') // ctrl-f (as in "F"ind)
    {
        me.parent.setFocus(me.parent, me.stringFilterBox);
    }
    else if((shift & S_CTRL) && scan == 'u') // ctrl-u (remove stringFilter line)
    {
        me.stringFilterBox.setText(me.stringFilterBox, "");
        MapList_StringFilterBox_Change(me.stringFilterBox, me);
    }
    else
        return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
    return 1;
}

References chr(), DialogOpenButton_Click_withCoords(), entity(), eX, eY, K_BACKSPACE, K_ENTER, K_INS, K_KP_ENTER, K_KP_INS, K_MOUSE1, K_MOUSE2, K_MOUSE3, K_SPACE, m_play_click_sound(), main, MapInfo_FindName(), MapInfo_FindName_firstResult, MapList_StringFilterBox_Change(), MENU_SOUND_OPEN, MENU_SOUND_SELECT, NULL, S_CTRL, strcat(), strcpy, strlen, substring(), SUPER, and time.

XonoticMapList_loadCvars()

void XonoticMapList_loadCvars

(

entity

me

)

Definition at line 35 of file maplist.qc.

{
    me.refilter(me);
}

References entity().

XonoticMapList_refilter()

void XonoticMapList_refilter

(

entity

me

)

Definition at line 179 of file maplist.qc.

{
    float i, j, n;
    string s;
    Gametype gt = MapInfo_CurrentGametype();
    int f = MapInfo_CurrentFeatures();
    MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
    if (me.stringFilter)
        MapInfo_FilterString(me.stringFilter);
    me.nItems = MapInfo_count;
 
    for(i = 0; i < MapInfo_count; ++i)
    {
        if(draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i))) == "")
            draw_PreloadPicture(strcat("/levelshots/", MapInfo_BSPName_ByID(i)));
    }
    s = "0";
    for(i = 1; i < MapInfo_count; i *= 2)
        s = strcat(s, s);
    n = tokenize_console(cvar_string("g_maplist"));
    for(i = 0; i < n; ++i)
    {
        j = MapInfo_FindName(argv(i));
        if(j >= 0)
        {
            // double check that the two mapnames are "identical", not just share the same prefix
            if (strlen(MapInfo_BSPName_ByID(j)) == strlen(argv(i)))
                s = strcat(
                    substring(s, 0, j),
                    "1",
                    substring(s, j+1, MapInfo_count - (j+1))
                );
        }
    }
    strcpy(me.g_maplistCache, s);
    if(gt != me.lastGametype || f != me.lastFeatures)
    {
        me.lastGametype = gt;
        me.lastFeatures = f;
        me.setSelected(me, 0);
    }
}

References argv(), cvar_string(), draw_PreloadPicture(), entity(), MapInfo_BSPName_ByID(), MapInfo_count, MapInfo_CurrentFeatures(), MapInfo_CurrentGametype(), MapInfo_FilterGametype(), MapInfo_FilterString(), MapInfo_FindName(), MapInfo_ForbiddenFlags(), MapInfo_RequiredFlags(), strcat(), strcpy, strlen, substring(), and tokenize_console.

XonoticMapList_refilterCallback()

void XonoticMapList_refilterCallback	(	entity	me,
		entity	cb )

Definition at line 222 of file maplist.qc.

{
    me.refilter(me);
}

References entity().

XonoticMapList_resizeNotify()

void XonoticMapList_resizeNotify	(	entity	me,
		vector	relOrigin,
		vector	relSize,
		vector	absOrigin,
		vector	absSize )

Definition at line 87 of file maplist.qc.

{
    me.itemAbsSize = '0 0 0';
    SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 
    me.itemAbsSize.y = absSize.y * me.itemHeight;
    me.itemAbsSize.x = absSize.x * (1 - me.controlWidth);
    me.realFontSize.y = me.fontSize / me.itemAbsSize.y;
    me.realFontSize.x = me.fontSize / me.itemAbsSize.x;
    me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
    me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 
    me.columnPreviewOrigin = 0;
    me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
    me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
    me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 
    me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
    me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
}

References entity(), eX, eY, SUPER, and vector.

Variable Documentation

disabled

bool disabled

Definition at line 8 of file maplist.qc.