speed.qc File Reference

#include "speed.qh"

Include dependency graph for speed.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	ARRAY_AS_VECTOR(a)
#define	VECTOR_TO_ARRAY(a, e)

Functions
	spawnfunc (target_speed)
vector	target_speed_calculatevelocity (entity this, float speed, entity pushed_entity)
void	target_speed_link (entity this)
void	target_speed_reset (entity this)
bool	target_speed_send (entity this, entity to, float sf)
void	target_speed_use (entity this, entity actor, entity trigger)

Macro Definition Documentation

ARRAY_AS_VECTOR

#define ARRAY_AS_VECTOR

(

a

)

Value:

vec3((a)[0], (a)[1], (a)[2])

Definition at line 5 of file speed.qc.

Referenced by target_speed_calculatevelocity().

VECTOR_TO_ARRAY

#define VECTOR_TO_ARRAY	(		a,
			e )

Value:

{ vector v = (e); (a)[0] = v.x; (a)[1] = v.y; (a)[2] = v.z; }

Definition at line 6 of file speed.qc.

Referenced by target_speed_calculatevelocity().

Function Documentation

spawnfunc()

spawnfunc

(

target_speed

)

Definition at line 155 of file speed.qc.

{
    this.active = ACTIVE_ACTIVE;
    this.setactive = generic_netlinked_setactive;
    this.use = target_speed_use;
    this.reset = target_speed_reset;
 
    // support a 0 speed setting AND a default
    string s = GetField_fullspawndata(this, "speed", false);
    if (!s || s == "")
        this.speed = 100;
 
    target_speed_link(this);
}

References active, ACTIVE_ACTIVE, generic_netlinked_setactive(), GetField_fullspawndata(), speed, target_speed_link(), target_speed_reset(), target_speed_use(), and use.

target_speed_calculatevelocity()

vector target_speed_calculatevelocity	(	entity	this,
		float	speed,
		entity	pushed_entity )

Definition at line 7 of file speed.qc.

{
    bool is_percentage = boolean(this.spawnflags & SPEED_PERCENTAGE);
    bool is_add = boolean(this.spawnflags & SPEED_ADD);
    bool is_launcher = boolean(this.spawnflags & SPEED_LAUNCHER);
 
    bool is_positive[3];
    is_positive[0] = boolean(this.spawnflags & SPEED_POSITIVE_X);
    is_positive[1] = boolean(this.spawnflags & SPEED_POSITIVE_Y);
    is_positive[2] = boolean(this.spawnflags & SPEED_POSITIVE_Z);
 
    bool is_negative[3];
    is_negative[0] = boolean(this.spawnflags & SPEED_NEGATIVE_X);
    is_negative[1] = boolean(this.spawnflags & SPEED_NEGATIVE_Y);
    is_negative[2] = boolean(this.spawnflags & SPEED_NEGATIVE_Z);
 
    // speed cannot be negative except when subtracting
    if(!is_add)
    {
        speed = max(speed, 0);
    }
 
    float pushvel[3];
    VECTOR_TO_ARRAY(pushvel, pushed_entity.velocity)
 
    for(int i = 0; i < 3; ++i)
    {
        // launcher can only be either positive or negative not both
        if(is_launcher && is_positive[i] && is_negative[i])
        {
            is_positive[i] = is_negative[i] = false;
        }
 
        // ignore this direction
        if(!is_positive[i] && !is_negative[i])
        {
            pushvel[i] = 0;
        }
    }
 
    float oldspeed = vlen(ARRAY_AS_VECTOR(pushvel));
 
    // the speed field is used to specify the percentage of the current speed
    if(is_percentage)
    {
        speed = oldspeed * speed / 100;
    }
 
    float launcherspeed = 0;
 
    // do this properly when not playing a Q3 map, do not put this in the loop
    if(!STAT(Q3COMPAT, pushed_entity))
    {
        launcherspeed += speed;
 
        // add the add speed in the same variable
        // as it goes in the same direction
        if(is_add) launcherspeed += oldspeed;
    }
 
    for(int i = 0; i < 3; ++i)
    {
        if(((pushvel[i] != 0) || is_launcher) && (is_positive[i] != is_negative[i]))
        {
            if(is_launcher)
            {
                // every direction weighs the same amount on launchers
                // movedir does not matter
                pushvel[i] = 1;
 
                // this does not belong inside the loop
                // only simulate this bug when playing a Q3 map
                if(STAT(Q3COMPAT, pushed_entity))
                {
                    launcherspeed += speed;
 
                    // add the add speed in the same variable
                    // as it goes in the same direction
                    if(is_add) launcherspeed += oldspeed;
                }
            }
 
            if(is_positive[i])
            {
                pushvel[i] = copysign(pushvel[i], 1);
            }
            else if(is_negative[i])
            {
                pushvel[i] = copysign(pushvel[i], -1);
            }
        }
    }
 
    float oldvel[3];
    VECTOR_TO_ARRAY(oldvel, pushed_entity.velocity)
 
    if(is_launcher)
    {
        // launcher will always launch you in the correct direction
        // even if speed is set to a negative value, fabs() is correct
        VECTOR_TO_ARRAY(pushvel, normalize(ARRAY_AS_VECTOR(pushvel)) * fabs(launcherspeed))
    }
    else
    {
        if(!is_add)
            VECTOR_TO_ARRAY(pushvel, normalize(ARRAY_AS_VECTOR(pushvel)) * speed)
        else
            VECTOR_TO_ARRAY(pushvel, normalize(ARRAY_AS_VECTOR(pushvel)) * speed + ARRAY_AS_VECTOR(oldvel))
    }
 
    for(int i = 0; i < 3; ++i)
    {
        // preserve unaffected directions
        if(!is_positive[i] && !is_negative[i])
        {
            pushvel[i] = oldvel[i];
        }
    }
 
    return ARRAY_AS_VECTOR(pushvel);
}

References ARRAY_AS_VECTOR, boolean, copysign(), entity(), fabs(), max(), normalize(), spawnflags, speed, SPEED_ADD, SPEED_LAUNCHER, SPEED_NEGATIVE_X, SPEED_NEGATIVE_Y, SPEED_NEGATIVE_Z, SPEED_PERCENTAGE, SPEED_POSITIVE_X, SPEED_POSITIVE_Y, SPEED_POSITIVE_Z, STAT, vector, VECTOR_TO_ARRAY, and vlen().

Referenced by target_speed_use().

target_speed_link()

void target_speed_link

(

entity

this

)

Definition at line 182 of file speed.qc.

{
    Net_LinkEntity(this, false, 0, target_speed_send);
}

References entity(), Net_LinkEntity(), and target_speed_send().

Referenced by spawnfunc().

target_speed_reset()

void target_speed_reset

(

entity

this

)

Definition at line 141 of file speed.qc.

{
    this.active = ACTIVE_ACTIVE;
}

References active, ACTIVE_ACTIVE, and entity().

Referenced by spawnfunc().

target_speed_send()

bool target_speed_send	(	entity	this,
		entity	to,
		float	sf )

Definition at line 170 of file speed.qc.

{
    WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_SPEED);
 
    WriteShort(MSG_ENTITY, this.spawnflags);
    WriteByte(MSG_ENTITY, this.active);
    WriteString(MSG_ENTITY, this.targetname);
    WriteCoord(MSG_ENTITY, this.speed);
 
    return true;
}

References active, entity(), MSG_ENTITY, spawnflags, speed, targetname, WriteByte(), WriteCoord(), WriteHeader, WriteShort(), and WriteString().

Referenced by target_speed_link().

target_speed_use()

void target_speed_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 133 of file speed.qc.

{
    if(this.active != ACTIVE_ACTIVE)
        return;
 
    actor.velocity = target_speed_calculatevelocity(this, this.speed, actor);
}

References active, ACTIVE_ACTIVE, entity(), speed, target_speed_calculatevelocity(), target_speed_use(), this, and void.

Referenced by spawnfunc(), and target_speed_use().