#include "all.qh"

Include dependency graph for all.qc:

This graph shows which files directly or indirectly include this file:

Functions
	NET_HANDLE (net_effect, bool isNew)
bool	Net_Write_Effect (entity this, entity client, int sf)
void	Send_Effect (entity eff, vector eff_loc, vector eff_vel, int eff_cnt)
void	Send_Effect_ (string eff_name, vector eff_loc, vector eff_vel, int eff_cnt)
void	Send_Effect_Except (entity eff, vector eff_loc, vector eff_vel, int eff_cnt, vector eff_col_min, vector eff_col_max, entity ignore)

Variables
const int	EFF_NET_COLOR_MAX = BIT(2)
const int	EFF_NET_COLOR_MIN = BIT(1)
const int	EFF_NET_COLOR_SAME = BIT(3)
const int	EFF_NET_VELOCITY = BIT(0)

Function Documentation

◆ NET_HANDLE()

NET_HANDLE	(	net_effect	,
		bool	isNew )

Definition at line 10 of file all.qc.

{
    int net_name = (REGISTRY_COUNT(Effects) >= 255) ? ReadShort() : ReadByte();
 
    entity eff = REGISTRY_GET(Effects, net_name);
 
    vector vel = '0 0 0';
    int eff_cnt = 1;
    int eff_flags = 0;
    bool eff_trail = eff.eent_eff_trail;
    vector v = ReadVector();
    int extraflags = ReadByte();
 
    particles_colormin = particles_colormax = '0 0 0';
 
    if(extraflags & EFF_NET_VELOCITY)
        vel = ReadVector();
 
    if(extraflags & EFF_NET_COLOR_MIN)
    {
        particles_colormin.x = ReadByte() / 16;
        particles_colormin.y = ReadByte() / 16;
        particles_colormin.z = ReadByte() / 16;
        eff_flags |= PARTICLES_USECOLOR;
    }
 
    if(extraflags & EFF_NET_COLOR_MAX)
    {
        particles_colormax.x = ReadByte() / 16;
        particles_colormax.y = ReadByte() / 16;
        particles_colormax.z = ReadByte() / 16;
        eff_flags |= PARTICLES_USECOLOR;
    }
    else if(extraflags & EFF_NET_COLOR_SAME)
        particles_colormax = particles_colormin;
 
    if(!eff_trail)
        eff_cnt = ReadByte();
 
    if(eff_trail)
        WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(eff), v, vel, 1, eff_flags);
    else
        boxparticles(particleeffectnum(eff), NULL, v, v, vel, vel, 1, eff_flags);
    return true;
}

References EFF_NET_COLOR_MAX, EFF_NET_COLOR_MIN, EFF_NET_COLOR_SAME, EFF_NET_VELOCITY, entity(), NULL, particleeffectnum, particles_colormax, particles_colormin, PARTICLES_USECOLOR, ReadByte(), ReadVector, REGISTRY_COUNT, REGISTRY_GET, vector, and WarpZone_TrailParticles_WithMultiplier().

◆ Net_Write_Effect()

bool Net_Write_Effect	(	entity	this,
		entity	client,
		int	sf )

Definition at line 58 of file all.qc.

{
    int channel = MSG_ONE;
    msg_entity = client;
    WriteHeader(channel, net_effect);
    (REGISTRY_COUNT(Effects) >= 255)
    ? WriteShort(channel, this.m_id)
    : WriteByte(channel, this.m_id);
    WriteVector(channel, this.eent_net_location);
 
    int extraflags = 0;
    if(this.eent_net_velocity != '0 0 0')
        extraflags |= EFF_NET_VELOCITY;
    if(this.eent_net_color_min != '0 0 0')
        extraflags |= EFF_NET_COLOR_MIN;
    // optimisation: only send one color if the min and max match
    if(this.eent_net_color_min != '0 0 0' && this.eent_net_color_min == this.eent_net_color_max)
        extraflags |= EFF_NET_COLOR_SAME;
    else if(this.eent_net_color_max != '0 0 0')
        extraflags |= EFF_NET_COLOR_MAX;
 
    WriteByte(channel, extraflags);
 
    // attempt to save a tiny bit more bandwidth by not sending velocity if it isn't set
    if(extraflags & EFF_NET_VELOCITY)
        WriteVector(channel, this.eent_net_velocity);
 
    if(extraflags & EFF_NET_COLOR_MIN)
    {
        vector col = this.eent_net_color_min;
        WriteByte(channel, rint(bound(0, 16 * col.x, 255)));
        WriteByte(channel, rint(bound(0, 16 * col.y, 255)));
        WriteByte(channel, rint(bound(0, 16 * col.z, 255)));
    }
 
    if(extraflags & EFF_NET_COLOR_MAX)
    {
        vector col = this.eent_net_color_max;
        WriteByte(channel, rint(bound(0, 16 * col.x, 255)));
        WriteByte(channel, rint(bound(0, 16 * col.y, 255)));
        WriteByte(channel, rint(bound(0, 16 * col.z, 255)));
    }
 
    if(!this.eent_eff_trail) { WriteByte(channel, this.eent_net_count); }
    return true;
}

References bound(), eent_eff_trail, eent_net_color_max, eent_net_color_min, eent_net_count, eent_net_location, eent_net_velocity, EFF_NET_COLOR_MAX, EFF_NET_COLOR_MIN, EFF_NET_COLOR_SAME, EFF_NET_VELOCITY, entity(), m_id, msg_entity, MSG_ONE, REGISTRY_COUNT, rint(), vector, WriteByte(), WriteHeader, and WriteShort().

Referenced by Send_Effect_Except().

◆ Send_Effect()

void Send_Effect	(	entity	eff,
		vector	eff_loc,
		vector	eff_vel,
		int	eff_cnt )

Definition at line 124 of file all.qc.

{
    Send_Effect_Except(eff, eff_loc, eff_vel, eff_cnt, '0 0 0', '0 0 0', NULL);
}

References entity(), NULL, Send_Effect_Except(), and vector.

Referenced by Arc_Smoke(), buff_Respawn(), buff_Think(), buff_Touch(), bumblebee_blowup(), bumblebee_diethink(), CheatImpulse(), ClientDisconnect(), GrapplingHook_Stop(), jumppad_push(), ka_RespawnBall(), ka_TouchEvent(), kh_WinnerTeam(), M_Golem_Attack_Lightning_Explode(), M_Golem_Attack_Smash(), M_Mage_Attack_Push(), M_Mage_Attack_Spike_Explode(), M_Mage_Attack_Teleport(), M_Mage_Defend_Heal(), M_Spider_Attack_Web_Explode(), M_Wyvern_Attack_Fireball_Explode(), Monster_Remove(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), nade_ammo_touch(), nade_darkness_think(), nade_heal_touch(), nade_ice_freeze(), nade_ice_think(), napalm_damage(), ons_ControlPoint_Icon_BuildThink(), ons_ControlPoint_Icon_Spawn(), ons_ControlPoint_Icon_Think(), ons_GeneratorDamage(), ons_Teleport(), PlayerDamage(), PlayerTouchExplode(), Portal_Remove(), PutObserverInServer(), raptor_diethink(), respawn(), spiderbot_blowup(), spiderbot_frame(), spiderbot_headfade(), TeleportPlayer(), tka_RespawnBall(), tka_TouchEvent(), turret_die(), vehicles_gib_explode(), vehicles_painframe(), vehicles_projectile(), vehicles_return(), vehicles_spawn(), W_Arc_Beam_Think(), W_Arc_Bolt_Touch(), W_Crylink_LinkJoinEffect_Think(), W_Devastator_Think(), W_Fireball_AttackEffect(), W_Fireball_Explode(), W_Fireball_LaserPlay(), W_Hagar_Touch2(), W_Mortar_Grenade_Touch1(), W_Mortar_Grenade_Touch2(), W_Shotgun_Melee_Think(), and W_Tuba_NoteOn().

◆ Send_Effect_()

void Send_Effect_	(	string	eff_name,
		vector	eff_loc,
		vector	eff_vel,
		int	eff_cnt )

Definition at line 129 of file all.qc.

{
    // problem with this is, we might not have all the available effects for it
    FOREACH(Effects, it.eent_eff_name == eff_name, {
        Send_Effect(it, eff_loc, eff_vel, eff_cnt);
        return;
    });
    // revert to engine handling TODO: send the effect name and draw it on the client side? not as light on networking, but resolves the use of server side effects
    __pointparticles(_particleeffectnum(eff_name), eff_loc, eff_vel, eff_cnt);
}

References FOREACH, and vector.

Referenced by buff_Effect(), CheatCommand(), ctf_Handle_Capture(), ctf_Handle_Pickup(), and sandbox_ObjectFunction_Touch().

◆ Send_Effect_Except()

void Send_Effect_Except	(	entity	eff,
		vector	eff_loc,
		vector	eff_vel,
		int	eff_cnt,
		vector	eff_col_min,
		vector	eff_col_max,
		entity	ignore )

Definition at line 105 of file all.qc.

{
    if(!eff) { return; }
    if(!eff.eent_eff_trail && !eff_cnt) { return; } // effect has no count!
    entity net_eff = new_pure(net_effect);
    net_eff.owner = eff;
    //net_eff.eent_broadcast = broadcast;
    net_eff.m_id = eff.m_id;
    net_eff.eent_net_velocity = eff_vel;
    net_eff.eent_net_location = eff_loc;
    net_eff.eent_net_count = eff_cnt;
    net_eff.eent_eff_trail = eff.eent_eff_trail;
    net_eff.eent_net_color_min = eff_col_min;
    net_eff.eent_net_color_max = eff_col_max;
 
    FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != ignore && !(IS_SPEC(it) && it.enemy && it.enemy == ignore), Net_Write_Effect(net_eff, it, 0));
    delete(net_eff);
}