quickmenu.qh File Reference

#include "../panel.qh"

Include dependency graph for quickmenu.qh:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	HUD_Quickmenu_PlayerListEntries (string cmd, int teamplayers, bool without_me)
void	QuickMenu_Close ()
void	QuickMenu_Default (string submenu)
bool	QuickMenu_InputEvent (float bInputType, float nPrimary, float nSecondary)
bool	QuickMenu_IsOpened ()
void	QuickMenu_Mouse ()
bool	QuickMenu_Open (string mode, string submenu, string file)
float	QuickMenu_Page_Load (string target_submenu, float new_page)

Variables
string	autocvar__hud_panel_quickmenu_file_from_server
float	autocvar_hud_panel_quickmenu_align
string	autocvar_hud_panel_quickmenu_file
bool	autocvar_hud_panel_quickmenu_server_is_default
float	autocvar_hud_panel_quickmenu_time
float	autocvar_hud_panel_quickmenu_translatecommands

Function Documentation

HUD_Quickmenu_PlayerListEntries()

void HUD_Quickmenu_PlayerListEntries	(	string	cmd,
		int	teamplayers,
		bool	without_me )

Definition at line 803 of file quickmenu.qc.

{
    TC(int, teamplayers); TC(bool, without_me);
    if (teamplayers && !team_count)
        return;
 
    Scoreboard_UpdatePlayerTeams();
    for (entity pl = players.sort_next; pl; pl = pl.sort_next)
    {
        if (teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
            continue;
        if (teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
            continue;
        if (without_me && pl.sv_entnum == player_localnum)
            continue;
        QUICKMENU_ENTRY(strcat("^7", entcs_GetName(pl.sv_entnum)), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
    }
 
    return;
}

References cmd(), entcs_GetName(), entity(), myteam, NUM_SPECTATOR, player_localnum, players, QUICKMENU_ENTRY, Scoreboard_UpdatePlayerTeams(), strcat(), TC, and team_count.

Referenced by HUD_Quickmenu_PlayerListEntries_Create().

QuickMenu_Close()

void QuickMenu_Close

(

)

Definition at line 263 of file quickmenu.qc.

{
    strfree(QuickMenu_CurrentSubMenu);
    for (int i = 0; i < QUICKMENU_MAXLINES; ++i)
        QuickMenu_Page_ClearEntry(i);
    QuickMenu_Page_Entries = 0;
    mouseClicked = 0;
    prevMouseClicked = 0;
    QuickMenu_Buffer_Close();
}

References mouseClicked, prevMouseClicked, QuickMenu_Buffer_Close(), QuickMenu_CurrentSubMenu, QUICKMENU_MAXLINES, QuickMenu_Page_ClearEntry(), QuickMenu_Page_Entries, and strfree.

Referenced by HUD_QuickMenu(), LocalCommand_hud(), QuickMenu_InputEvent(), QuickMenu_Mouse(), and QuickMenu_Page_Load().

QuickMenu_Default()

void QuickMenu_Default

(

string

submenu

)

Definition at line 830 of file quickmenu.qc.

{
    bool target_submenu_found = false;
    if (target_submenu != "")
        QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 
    string tc_title;
    string tc_cmd;
 
    QUICKMENU_SMENU(_("Chat"), "Chat")
        QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send public message to")), "Send public message to", "commandmode say %s:^7", 0, 1)
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
        if (prvm_language != "en")
        QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
    QUICKMENU_SMENU(_("Chat"), "Chat")
 
    if (teamplay)
    {
    QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^strength soon")), "say_team %s", "strength soon", CTX(_("QMCMD^strength soon")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
        QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
    QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
    }
 
    QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 
    QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
        QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
            QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
            QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
        QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 
        QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
            QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
        QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 
        if (spectatee_status > 0)
        {
        QUICKMENU_ENTRY_TAG(CTX(_("QMCMD^Change spectator camera")), "dropweapon", QM_TAG_KCOMMAND)
        }
        else if (spectatee_status == -1)
        {
        QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
            QUICKMENU_ENTRY_TAG(CTX(_("QMCMD^Increase speed")), "weapnext", QM_TAG_KCOMMAND)
            QUICKMENU_ENTRY_TAG(CTX(_("QMCMD^Decrease speed")), "weapprev", QM_TAG_KCOMMAND)
            QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision")), "toggle cl_clippedspectating")
        QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
        }
 
        QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
    QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 
    QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
        QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
        QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
        if (STAT(TIMELIMIT) > 0)
        {
        QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
        QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
        }
        if (teamplay)
        QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
    QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 
    if (autocvar__hud_panel_quickmenu_file_from_server != "")
    {
    string entry_name = _("Server quick menu");
    if (autocvar__hud_panel_quickmenu_file_from_server == "wpeditor.txt")
        entry_name = _("Waypoint editor menu");
    QUICKMENU_ENTRY_SPECIAL(entry_name, "quickmenu; wait; quickmenu \"\" \"\" $_hud_panel_quickmenu_file_from_server")
    if (autocvar__hud_panel_quickmenu_file_from_server == "wpeditor.txt")
        entry_name = _("Waypoint editor menu as default");
    else
        entry_name = _("Server quick menu as default");
    QUICKMENU_ENTRY(entry_name, "toggle hud_panel_quickmenu_server_is_default")
    }
 
    if (spectatee_status != 0)
    {
    QUICKMENU_SMENU_PL(CTX(_("QMCMD^Spectate a player")), "Spectate a player", "spectate \"%s^7\"", 0, 1)
    }
 
    if (target_submenu != "" && !target_submenu_found)
    {
        LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
        if (prvm_language != "en")
            LOG_INFO("^3Warning: submenu title must be in English");
        QuickMenu_Buffer_Size = 0;
    }
}

References autocvar__hud_panel_quickmenu_file_from_server, CTX(), LOG_INFO, LOG_INFOF, prvm_language, QM_TAG_KCOMMAND, QUICKMENU_BUFFER_MAXENTRIES, QuickMenu_Buffer_Size, QUICKMENU_ENTRY, QUICKMENU_ENTRY_SPECIAL, QUICKMENU_ENTRY_TAG, QUICKMENU_ENTRY_TC, QUICKMENU_SMENU, QUICKMENU_SMENU_PL, spectatee_status, STAT, and teamplay.

Referenced by QuickMenu_Open().

QuickMenu_InputEvent()

bool QuickMenu_InputEvent	(	float	bInputType,
		float	nPrimary,
		float	nSecondary )

QuickMenu_IsOpened()

bool QuickMenu_IsOpened

(

)

Definition at line 291 of file quickmenu.qc.

{
    return QuickMenu_Page_Entries > 0;
}

Referenced by HUD_QuickMenu(), and QuickMenu_InputEvent().

QuickMenu_Mouse()

void QuickMenu_Mouse

(

)

Definition at line 546 of file quickmenu.qc.

{
    if (mv_active)
        return;
 
    if (!mouseClicked && (prevMouseClicked & S_MOUSE2))
    {
        QuickMenu_Close();
        return;
    }
 
    panel = HUD_PANEL(QUICKMENU);
    HUD_Panel_LoadCvars();
 
    if (panel_bg_padding)
    {
        panel_pos += '1 1 0' * panel_bg_padding;
        panel_size -= '2 2 0' * panel_bg_padding;
    }
 
    vector fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
    float first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) * 0.5;
    float entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 
    if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
    {
        int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
        if (entry_num != entry_num_prev)
        {
            QuickMenu_TimeOut_Set();
            entry_num_prev = entry_num;
        }
        if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
        {
            if (!mouseClicked && (prevMouseClicked & S_MOUSE1))
                QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 
            if (time > QuickMenu_Page_ActivatedEntry_Time)
            {
                vector entry_pos = panel_pos;
                entry_pos.y = first_entry_pos + entry_num * fontsize.y;
                vector color;
                if (mouseClicked & S_MOUSE1)
                    color = '0.5 1 0.5';
                else if (hudShiftState & S_CTRL)
                    color = '1 1 0.3';
                else
                    color = '1 1 1';
                drawfill(entry_pos, vec2(panel_size.x, fontsize.y), color, 0.2, DRAWFLAG_NORMAL);
            }
        }
    }
}

References color, drawfill, DRAWFLAG_NORMAL, entry_num_prev, floor(), HUD_PANEL, HUD_Panel_LoadCvars(), hudShiftState, min(), mouseClicked, mousepos, mv_active, panel, panel_bg_padding, panel_pos, panel_size, prevMouseClicked, QuickMenu_Close(), QuickMenu_IsLastPage, QUICKMENU_MAXLINES, QuickMenu_Page_ActivatedEntry_Time, QuickMenu_Page_ActiveEntry(), QuickMenu_Page_Entries, QuickMenu_TimeOut_Set(), S_CTRL, S_MOUSE1, S_MOUSE2, time, vec2, and vector.

Referenced by HUD_Mouse().

QuickMenu_Open()

bool QuickMenu_Open	(	string	mode,
		string	submenu,
		string	file )

Definition at line 107 of file quickmenu.qc.

{
    QuickMenu_TimeOut = 0;
    if (HUD_QuickMenu_Forbidden())
        return false;
 
    int fh = -1;
 
    if (mode == "")
    {
        if (file == "" || file == "0")
            mode = "default";
        else
            mode = "file";
    }
 
    if (mode == "default")
    {
        if (autocvar_hud_panel_quickmenu_server_is_default && autocvar__hud_panel_quickmenu_file_from_server != "")
        {
            mode = "file";
            file = autocvar__hud_panel_quickmenu_file_from_server;
        }
    }
 
    if (mode == "file")
    {
        if (file == "" || file == "0")
            LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
        else
        {
            fh = fopen(file, FILE_READ);
            if (fh < 0)
                LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
        }
        if (fh < 0)
            mode = "default";
    }
 
    if (mode == "default")
    {
        QuickMenu_Buffer = buf_create();
        if (QuickMenu_Buffer < 0)
            return false;
 
        QuickMenu_Default(submenu);
    }
    else if (mode == "file")
    {
        QuickMenu_Buffer = buf_create();
        if (QuickMenu_Buffer < 0)
        {
            fclose(fh);
            return false;
        }
 
        QuickMenu_Buffer_Size = 0;
        string s;
        while ((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
        {
            // first skip invalid entries, so we don't check them anymore
            int argc;
            argc = tokenize_console(s);
            if (argc == 0 || argv(0) == "")
                continue;
            if (argc == 1)
                QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
            else if (argc == 2)
            {
                if (argv(1) == "")
                    continue;
                QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
                ++QuickMenu_Buffer_Size;
                QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
            }
            else if (argc == 3 && argv(2) == "KEEP_OPEN")
            {
                if (argv(1) == "")
                    continue;
                QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
                ++QuickMenu_Buffer_Size;
                QuickMenu_Buffer_Set(QM_TAG_KCOMMAND, argv(1));
            }
            else if (argc == 3)
            {
                // check for special keywords
                float teamplayers = 0, without_me = 0;
                switch (argv(2))
                {
                    case "ALLPLAYERS_BUT_ME":      without_me = 1;  // fall through
                    case "ALLPLAYERS":             teamplayers = 0; break;
                    case "OWNTEAMPLAYERS_BUT_ME":  without_me = 1;  // fall through
                    case "OWNTEAMPLAYERS":         teamplayers = 1; break;
                    case "ENEMYTEAMPLAYERS":       teamplayers = 2; break;
                    default: continue;
                }
 
                if (QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
                {
                    QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
                    ++QuickMenu_Buffer_Size;
                    QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
                    ++QuickMenu_Buffer_Size;
                    QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
                    ++QuickMenu_Buffer_Size;
                    QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
                }
            }
            ++QuickMenu_Buffer_Size;
        }
        fclose(fh);
 
        // forcedly add this entry
        if (autocvar_hud_panel_quickmenu_server_is_default && autocvar__hud_panel_quickmenu_file_from_server != "")
        {
            string prev_value = cvar_string("hud_panel_quickmenu_server_is_default");
            QUICKMENU_ENTRY_SPECIAL(_("Standard quick menu"), sprintf("hud_panel_quickmenu_server_is_default 0; quickmenu; wait; quickmenu; wait; hud_panel_quickmenu_server_is_default \"%s\"", prev_value))
        }
    }
    else
    {
        LOG_WARNF("Unrecognized mode %s", mode);
        return false;
    }
 
    if (QuickMenu_Buffer_Size <= 0)
    {
        buf_del(QuickMenu_Buffer);
        QuickMenu_Buffer = -1;
        return false;
    }
 
    if (mode == "file")
        QuickMenu_Page_Load(submenu, 0);
    else
        QuickMenu_Page_Load("", 0);
 
    mouseClicked = 0;
    hudShiftState = 0;
 
    Release_Common_Keys();
 
    QuickMenu_TimeOut_Set();
    return true;
}

References argv(), autocvar__hud_panel_quickmenu_file_from_server, autocvar_hud_panel_quickmenu_server_is_default, buf_create, cvar_string(), fclose(), fgets(), FILE_READ, fopen(), ftos(), HUD_QuickMenu_Forbidden(), hudShiftState, LOG_INFO, LOG_INFOF, LOG_WARNF, mouseClicked, QM_TAG_COMMAND, QM_TAG_KCOMMAND, QM_TAG_PLCOMMAND, QM_TAG_SUBMENU, QM_TAG_TITLE, QuickMenu_Buffer, QUICKMENU_BUFFER_MAXENTRIES, QuickMenu_Buffer_Set, QuickMenu_Buffer_Size, QuickMenu_Default(), QUICKMENU_ENTRY_SPECIAL, QuickMenu_Page_Load(), QuickMenu_TimeOut, QuickMenu_TimeOut_Set(), Release_Common_Keys(), strcat(), and tokenize_console.

Referenced by LocalCommand_hud().

QuickMenu_Page_Load()

float QuickMenu_Page_Load	(	string	target_submenu,
		float	new_page )

References cmd().

Variable Documentation

autocvar__hud_panel_quickmenu_file_from_server

string autocvar__hud_panel_quickmenu_file_from_server

Definition at line 10 of file quickmenu.qh.

Referenced by QuickMenu_Default(), and QuickMenu_Open().

autocvar_hud_panel_quickmenu_align

float autocvar_hud_panel_quickmenu_align

Definition at line 5 of file quickmenu.qh.

Referenced by HUD_Quickmenu_DrawEntry().

autocvar_hud_panel_quickmenu_file

string autocvar_hud_panel_quickmenu_file

Definition at line 7 of file quickmenu.qh.

Referenced by LocalCommand_hud().

autocvar_hud_panel_quickmenu_server_is_default

bool autocvar_hud_panel_quickmenu_server_is_default

Definition at line 9 of file quickmenu.qh.

Referenced by QuickMenu_Open().

autocvar_hud_panel_quickmenu_time

float autocvar_hud_panel_quickmenu_time

Definition at line 8 of file quickmenu.qh.

Referenced by QuickMenu_TimeOut_Set().

autocvar_hud_panel_quickmenu_translatecommands

float autocvar_hud_panel_quickmenu_translatecommands

Definition at line 6 of file quickmenu.qh.