#include "models.qh"
#include <client/csqcmodel_hooks.qh>
#include <common/constants.qh>
#include <common/mapobjects/bgmscript.qh>
#include <common/mapobjects/subs.qh>
#include <common/mapobjects/triggers.qh>
#include <common/net_linked.qh>
#include <common/stats.qh>
#include <common/weapons/_all.qh>
#include <lib/csqcmodel/sv_model.qh>

Include dependency graph for models.qc:

This graph shows which files directly or indirectly include this file:

Functions
void	g_clientmodel_dropbyspawnflags (entity this)
bool	g_clientmodel_genericsendentity (entity this, entity to, int sf)
void	g_clientmodel_init (entity ent, float sol)
void	g_clientmodel_setcolormaptoactivator (entity this, entity actor, entity trigger)
void	g_clientmodel_think (entity this)
void	g_clientmodel_use (entity this, entity actor, entity trigger)
void	g_model_dropbyspawnflags (entity this)
void	g_model_init (entity ent, float sol)
void	g_model_setcolormaptoactivator (entity this, entity actor, entity trigger)
	spawnfunc (func_clientillusionary)
	spawnfunc (func_clientwall)
	spawnfunc (func_illusionary)
	spawnfunc (func_static)
	spawnfunc (func_wall)
	spawnfunc (misc_clientmodel)
	spawnfunc (misc_gamemodel)
	spawnfunc (misc_models)

Function Documentation

◆ g_clientmodel_dropbyspawnflags()

void g_clientmodel_dropbyspawnflags ( entity this )

Definition at line 92 of file models.qc.

{
    vector o0;
    o0 = this.origin;
    g_model_dropbyspawnflags(this);
    if(this.origin != o0)
        this.SendFlags |= BIT(1);
}

References BIT, entity(), g_model_dropbyspawnflags(), origin, SendFlags, and vector.

Referenced by g_clientmodel_init().

◆ g_clientmodel_genericsendentity()

bool g_clientmodel_genericsendentity	(	entity	this,
		entity	to,
		int	sf )

Definition at line 101 of file models.qc.

{
    sf = sf & 0x0F;
    if(this.angles != '0 0 0')
        sf |= 0x10;
    if(this.mins != '0 0 0' || this.maxs != '0 0 0')
        sf |= 0x20;
    if(this.colormap != 0)
        sf |= 0x40;
    if(this.lodmodelindex1)
        sf |= 0x80;
 
    WriteHeader(MSG_ENTITY, ENT_CLIENT_WALL);
    WriteByte(MSG_ENTITY, sf);
 
    if(sf & BIT(0))
    {
        if(sf & 0x40)
            WriteShort(MSG_ENTITY, this.colormap);
        WriteByte(MSG_ENTITY, this.skin);
    }
 
    if(sf & BIT(1))
    {
        WriteVector(MSG_ENTITY, this.origin);
    }
 
    if(sf & BIT(2))
    {
        if(sf & 0x10)
            WriteAngleVector(MSG_ENTITY, this.angles);
    }
 
    if(sf & BIT(3))
    {
        if(sf & 0x80)
        {
            WriteShort(MSG_ENTITY, this.lodmodelindex0);
            WriteShort(MSG_ENTITY, bound(0, this.loddistance1, 32767));
            WriteShort(MSG_ENTITY, this.lodmodelindex1);
            WriteShort(MSG_ENTITY, bound(0, this.loddistance2, 32767));
            WriteShort(MSG_ENTITY, this.lodmodelindex2);
        }
        else
            WriteShort(MSG_ENTITY, this.modelindex);
        WriteByte(MSG_ENTITY, this.solid);
        WriteShort(MSG_ENTITY, floor(this.scale * 256));
        if(sf & 0x20)
        {
            WriteVector(MSG_ENTITY, this.mins);
            WriteVector(MSG_ENTITY, this.maxs);
        }
        WriteString(MSG_ENTITY, this.bgmscript);
        if(this.bgmscript != "")
        {
            WriteByte(MSG_ENTITY, floor(this.bgmscriptattack * 64));
            WriteByte(MSG_ENTITY, floor(this.bgmscriptdecay * 64));
            WriteByte(MSG_ENTITY, floor(this.bgmscriptsustain * 255));
            WriteByte(MSG_ENTITY, floor(this.bgmscriptrelease * 64));
            WriteVector(MSG_ENTITY, this.movedir);
            WriteByte(MSG_ENTITY, floor(this.lip * 255));
        }
        WriteShort(MSG_ENTITY, bound(0, this.fade_start, 32767));
        WriteShort(MSG_ENTITY, bound(0, this.fade_end, 32767));
        WriteByte(MSG_ENTITY, floor(this.alpha_max * 256));
        WriteByte(MSG_ENTITY, floor(this.alpha_min * 256));
        WriteByte(MSG_ENTITY, this.inactive);
        WriteShort(MSG_ENTITY, this.fade_vertical_offset);
    }
 
    return true;
}

References alpha_max, alpha_min, angles, BIT, bound(), colormap, entity(), fade_end, fade_start, fade_vertical_offset, floor(), inactive, lip, loddistance1, loddistance2, lodmodelindex0, lodmodelindex1, lodmodelindex2, maxs, mins, modelindex, movedir, MSG_ENTITY, origin, scale, skin, solid, WriteByte(), WriteHeader, WriteShort(), and WriteString().

Referenced by g_clientmodel_init().

◆ g_clientmodel_init()

void g_clientmodel_init	(	entity	ent,
		float	sol )

Definition at line 187 of file models.qc.

{
    if(ent.geomtype && autocvar_physics_ode && checkextension("DP_PHYSICS_ODE")) set_movetype(ent, MOVETYPE_PHYSICS);
    if(!ent.scale) ent.scale = ent.modelscale;
 
    if(!ent.solid) ent.solid = (sol);
    else if(ent.solid < 0) ent.solid = SOLID_NOT;
    SetBrushEntityModel(ent,true); // called after setting .solid to ensure correct area grid linking/unlinking
 
    ent.use = g_clientmodel_use;
    setthink(ent, g_clientmodel_think);
    ent.nextthink = time;
    ent.oldorigin = ent.origin; // don't run an initial double update
    InitializeEntity(ent, g_clientmodel_dropbyspawnflags, INITPRIO_DROPTOFLOOR);
    if(!ent.bgmscriptsustain) ent.bgmscriptsustain = 1;
    else if(ent.bgmscriptsustain < 0) ent.bgmscriptsustain = 0;
    Net_LinkEntity(ent, true, 0, g_clientmodel_genericsendentity);
    ent.default_solid = sol;
}

References autocvar_physics_ode, checkextension(), entity(), g_clientmodel_dropbyspawnflags(), g_clientmodel_genericsendentity(), g_clientmodel_think(), g_clientmodel_use(), InitializeEntity(), INITPRIO_DROPTOFLOOR, MOVETYPE_PHYSICS, Net_LinkEntity(), set_movetype(), SetBrushEntityModel(), setthink, SOLID_NOT, and time.

Referenced by spawnfunc(), spawnfunc(), and spawnfunc().

◆ g_clientmodel_setcolormaptoactivator()

void g_clientmodel_setcolormaptoactivator	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 31 of file models.qc.

{
    g_model_setcolormaptoactivator(this, actor, trigger);
    this.SendFlags |= (BIT(3) | BIT(0));
}

References BIT, entity(), g_model_setcolormaptoactivator(), and SendFlags.

Referenced by g_clientmodel_use().

◆ g_clientmodel_think()

void g_clientmodel_think ( entity this )

Definition at line 84 of file models.qc.

{
    this.nextthink = time;
    if(this.oldorigin != this.origin)
        this.SendFlags |= BIT(1);
    this.oldorigin = this.origin;
}

References BIT, entity(), nextthink, oldorigin, origin, SendFlags, and time.

Referenced by g_clientmodel_init().

◆ g_clientmodel_use()

void g_clientmodel_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 37 of file models.qc.

{
    // Flag to set func_clientwall state
    // 1 == deactivate, 2 == activate, 0 == do nothing
    if(this.classname == "func_clientwall" || this.classname == "func_clientillusionary")
        this.antiwall_flag = trigger.antiwall_flag;
 
    if (this.antiwall_flag == 1)
    {
        this.inactive = 1;
        if (this.solid != SOLID_NOT)
        {
            this.solid = SOLID_NOT;
            setorigin(this, this.origin); // unlink
        }
    }
    else if (this.antiwall_flag == 2)
    {
        this.inactive = 0;
        if (this.solid != this.default_solid)
        {
            this.solid = this.default_solid;
            setorigin(this, this.origin); // link
        }
    }
    g_clientmodel_setcolormaptoactivator(this, actor, trigger);
}

References antiwall_flag, classname, default_solid, entity(), g_clientmodel_setcolormaptoactivator(), inactive, origin, solid, and SOLID_NOT.

Referenced by g_clientmodel_init().

◆ g_model_dropbyspawnflags()

void g_model_dropbyspawnflags ( entity this )

Definition at line 65 of file models.qc.

{
    if((this.spawnflags & 3) == 1) // ALIGN_ORIGIN
    {
        traceline(this.origin, this.origin - '0 0 4096', MOVE_NOMONSTERS, this);
        setorigin(this, trace_endpos);
    }
    else if((this.spawnflags & 3) == 2) // ALIGN_BOTTOM
    {
        tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 4096', MOVE_NOMONSTERS, this);
        setorigin(this, trace_endpos);
    }
    else if((this.spawnflags & 3) == 3) // ALIGN_ORIGIN | ALIGN_BOTTOM
    {
        traceline(this.origin, this.origin - '0 0 4096', MOVE_NOMONSTERS, this);
        setorigin(this, trace_endpos - '0 0 1' * this.mins.z);
    }
}

References entity(), maxs, mins, MOVE_NOMONSTERS, origin, spawnflags, and trace_endpos.

Referenced by g_clientmodel_dropbyspawnflags(), and g_model_init().

◆ g_model_init()

void g_model_init	(	entity	ent,
		float	sol )

Definition at line 174 of file models.qc.

{
    if(ent.geomtype && autocvar_physics_ode && checkextension("DP_PHYSICS_ODE")) set_movetype(ent, MOVETYPE_PHYSICS);
    if(!ent.scale) ent.scale = ent.modelscale;
 
    if(!ent.solid) ent.solid = (sol);
    else if(ent.solid < 0) ent.solid = SOLID_NOT;
    SetBrushEntityModel(ent,true); // called after setting .solid to ensure correct area grid linking/unlinking
 
    ent.use = g_model_setcolormaptoactivator;
    InitializeEntity(ent, g_model_dropbyspawnflags, INITPRIO_DROPTOFLOOR);
}

References autocvar_physics_ode, checkextension(), entity(), g_model_dropbyspawnflags(), g_model_setcolormaptoactivator(), InitializeEntity(), INITPRIO_DROPTOFLOOR, MOVETYPE_PHYSICS, set_movetype(), SetBrushEntityModel(), and SOLID_NOT.

Referenced by spawnfunc(), spawnfunc(), spawnfunc(), spawnfunc(), and spawnfunc().

◆ g_model_setcolormaptoactivator()

void g_model_setcolormaptoactivator	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 17 of file models.qc.

{
    if(teamplay)
    {
        if(actor.team)
            this.colormap = (actor.team - 1) * 0x11;
        else
            this.colormap = 0x00;
    }
    else
        this.colormap = floor(random() * 256);
    this.colormap |= BIT(10); // RENDER_COLORMAPPED
}