blaster.qc File Reference

#include "blaster.qh"

Include dependency graph for blaster.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	W_Blaster_Attack (entity actor,.entity weaponentity)
void	W_Blaster_Think (entity this)
void	W_Blaster_Touch (entity this, entity toucher)

Function Documentation

W_Blaster_Attack()

void W_Blaster_Attack	(	entity	actor,
		.entity	weaponentity )

Definition at line 54 of file blaster.qc.

{
    float atk_shotangle = WEP_CVAR_PRI(WEP_BLASTER, shotangle) * DEG2RAD;
    float atk_damage = WEP_CVAR_PRI(WEP_BLASTER, damage);
    vector s_forward = v_forward * cos(atk_shotangle) + v_up * sin(atk_shotangle);
    int atk_deathtype = WEP_BLASTER.m_id;
 
    W_SetupShot_Dir(actor, weaponentity, s_forward, false, 3, SND_BLASTER_FIRE, CH_WEAPON_B, atk_damage, atk_deathtype);
    W_MuzzleFlash(WEP_BLASTER, actor, weaponentity, w_shotorg, w_shotdir);
 
    entity missile = new(blasterbolt);
    missile.owner = missile.realowner = actor;
    missile.bot_dodge = true;
    missile.bot_dodgerating = atk_damage;
    PROJECTILE_MAKETRIGGER(missile);
 
    setorigin(missile, w_shotorg);
    setsize(missile, '0 0 0', '0 0 0');
 
    float atk_speed = WEP_CVAR_PRI(WEP_BLASTER, speed);
    float atk_spread = WEP_CVAR_PRI(WEP_BLASTER, spread);
    W_SetupProjVelocity_Explicit(missile, w_shotdir, v_up, atk_speed, 0, 0, atk_spread, false);
 
    missile.angles = vectoangles(missile.velocity);
 
    //missile.glow_color = 250; // 244, 250
    //missile.glow_size = 120;
 
    settouch(missile, W_Blaster_Touch);
    missile.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, missile);
    IL_PUSH(g_bot_dodge, missile);
    missile.missile_flags = MIF_SPLASH;
    missile.projectiledeathtype = atk_deathtype;
    missile.weaponentity_fld = weaponentity;
    setthink(missile, W_Blaster_Think);
    missile.nextthink = time + WEP_CVAR_PRI(WEP_BLASTER, delay);
 
    MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 
    if (time >= missile.nextthink)
    {
        getthink(missile)(missile);
    }
}

References CH_WEAPON_B, cos(), DEG2RAD, delay, entity(), FL_PROJECTILE, g_bot_dodge, g_projectiles, getthink, IL_PUSH(), MIF_SPLASH, MUTATOR_CALLHOOK, PROJECTILE_MAKETRIGGER, setthink, settouch, sin(), speed, time, v_forward, v_up, vectoangles(), vector, W_Blaster_Think(), W_Blaster_Touch(), W_MuzzleFlash(), W_SetupProjVelocity_Explicit(), W_SetupShot_Dir, w_shotdir, w_shotorg, and WEP_CVAR_PRI.

W_Blaster_Think()

void W_Blaster_Think

(

entity

this

)

Definition at line 46 of file blaster.qc.

{
    set_movetype(this, MOVETYPE_FLY);
    setthink(this, SUB_Remove);
    this.nextthink = time + WEP_CVAR_PRI(WEP_BLASTER, lifetime);
    CSQCProjectile(this, true, PROJECTILE_BLASTER, true);
}

References CSQCProjectile(), entity(), lifetime, MOVETYPE_FLY, nextthink, PROJECTILE_BLASTER, set_movetype(), setthink, SUB_Remove(), time, and WEP_CVAR_PRI.

Referenced by W_Blaster_Attack().

W_Blaster_Touch()

void W_Blaster_Touch	(	entity	this,
		entity	toucher )

Definition at line 5 of file blaster.qc.

{
    PROJECTILE_TOUCH(this, toucher);
 
    this.event_damage = func_null;
 
    vector force_xyzscale = '1 1 1';
    force_xyzscale.z = WEP_CVAR_PRI(WEP_BLASTER, force_zscale);
 
    // slightly hacky but probably not worth adding a parameter for this special case
    bool zero_damageforcescale = false;
    if (autocvar_g_projectiles_interact == 1 && (toucher.flags & FL_PROJECTILE) && !toucher.damageforcescale)
    {
        toucher.damageforcescale = 1;
        zero_damageforcescale = true;
    }
 
    RadiusDamageForSource(
        this,
        (this.origin + (this.mins + this.maxs) * 0.5),
        this.velocity,
        this.realowner,
        WEP_CVAR_PRI(WEP_BLASTER, damage),
        WEP_CVAR_PRI(WEP_BLASTER, edgedamage),
        WEP_CVAR_PRI(WEP_BLASTER, radius),
        NULL,
        NULL,
        false,
        WEP_CVAR_PRI(WEP_BLASTER, force),
        force_xyzscale,
        this.projectiledeathtype,
        this.weaponentity_fld,
        toucher
    );
 
    if (zero_damageforcescale)
        toucher.damageforcescale = 0;
 
    delete(this);
}

References autocvar_g_projectiles_interact, entity(), FL_PROJECTILE, func_null(), maxs, mins, NULL, origin, PROJECTILE_TOUCH, projectiledeathtype, radius, RadiusDamageForSource(), realowner, toucher, vector, velocity, weaponentity_fld, and WEP_CVAR_PRI.

Referenced by W_Blaster_Attack().