weaponsystem.qh File Reference

#include <common/weapons/all.qh>

Include dependency graph for weaponsystem.qh:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	ATTACK_FINISHED(ent, w)
#define	ATTACK_FINISHED_FOR(ent, w, slot)
#define	INDEPENDENT_ATTACK_FINISHED   1

Functions
void	CL_SpawnWeaponentity (entity e,.entity weaponentity)
vector	CL_Weapon_GetShotOrg (int wpn)
	void (Weapon thiswep, entity actor,.entity weaponentity, int fire) weapon_think
void	W_AttachToShotorg (entity actor,.entity weaponentity, entity flash, vector offset)
void	w_clear (Weapon thiswep, entity actor,.entity weaponentity, int fire)
void	W_DecreaseAmmo (Weapon wep, entity actor, float ammo_use,.entity weaponentity)
void	W_DropEvent (.void(Weapon, entity actor,.entity) event, entity player, int weapon_type, entity weapon_item,.entity weaponentity)
void	w_ready (Weapon thiswep, entity actor,.entity weaponentity, int fire)
void	W_Reload (entity actor,.entity weaponentity, float sent_ammo_min, Sound sent_sound)
void	W_ResetGunAlign (entity player, int preferred_alignment)
void	W_WeaponFrame (Player actor,.entity weaponentity)
float	W_WeaponRateFactor (entity this)
float	W_WeaponSpeedFactor (entity this)
bool	weapon_prepareattack (Weapon thiswep, entity actor,.entity weaponentity, bool secondary, float attacktime)
bool	weapon_prepareattack_check (Weapon thiswep, entity actor,.entity weaponentity, bool secondary, float attacktime)
void	weapon_prepareattack_do (entity actor,.entity weaponentity, bool secondary, float attacktime)
void	weapon_thinkf (entity actor,.entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,.entity weaponentity, int fire) func)
bool	weaponLocked (entity player)
bool	weaponUseForbidden (entity player)

Variables
int	ammo_none
float	attack_finished_for [REGISTRY_MAX(Weapons) *MAX_WEAPONSLOTS]
float	attack_finished_single [MAX_WEAPONSLOTS]
float	autocvar_g_weapondamagefactor
float	autocvar_g_weaponforcefactor
float	autocvar_g_weaponratefactor
float	autocvar_g_weaponspeedfactor
float	bulletcounter
int	clip_load
int	clip_size
float	internalteam
int	old_clip_load
const int	W_TICSPERFRAME = 2
entity	weapon_dropevent_item
float	weapon_load [REGISTRY_MAX(Weapons)]
float	weapon_nextthink
entity	weaponentity_fld

Macro Definition Documentation

ATTACK_FINISHED

#define ATTACK_FINISHED	(		ent,
			w )

Value:

ATTACK_FINISHED_FOR(ent, ent.(w).m_weapon.m_id, weaponslot(w))

Definition at line 41 of file weaponsystem.qh.

Referenced by bot_cmd_debug_assert_canfire(), havocbot_chooseweapon(), W_Arc_Attack_Bolt(), W_Devastator_DoRemoteExplode(), W_Devastator_Explode(), W_Hagar_Attack_Auto(), W_HLAC_Attack_Frame(), W_MachineGun_Attack(), W_MachineGun_Attack_Auto(), W_MachineGun_Attack_Burst(), W_MineLayer_DoRemoteExplode(), W_MineLayer_Explode(), W_OverkillHeavyMachineGun_Attack_Auto(), W_OverkillMachineGun_Attack_Auto(), W_Rifle_BulletHail_Continue(), W_WeaponFrame(), weapon_prepareattack_check(), and weapon_prepareattack_do().

ATTACK_FINISHED_FOR

#define ATTACK_FINISHED_FOR	(		ent,
			w,
			slot )

Value:

((ent).attack_finished_single[slot])

Definition at line 39 of file weaponsystem.qh.

Referenced by PlayerDamage().

INDEPENDENT_ATTACK_FINISHED

#define INDEPENDENT_ATTACK_FINISHED   1

Definition at line 10 of file weaponsystem.qh.

Referenced by W_WeaponFrame().

Function Documentation

CL_SpawnWeaponentity()

void CL_SpawnWeaponentity	(	entity	e,
		.entity	weaponentity )

Definition at line 176 of file weaponsystem.qc.

{
    entity w_ent = actor.(weaponentity) = new(weaponentity);
    w_ent.solid = SOLID_NOT;
    w_ent.owner = actor;
    setmodel(w_ent, MDL_Null);  // precision set when changed
    setorigin(w_ent, '0 0 0');
    w_ent.weaponentity_fld = weaponentity;
    setthink(w_ent, CL_Weaponentity_Think);
    w_ent.nextthink = time;
    w_ent.viewmodelforclient = actor;
    w_ent.draggable = drag_undraggable;
    setcefc(w_ent, CL_Weaponentity_CustomizeEntityForClient);
 
    wepent_link(w_ent);
 
    if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
    {
        entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
        exterior.solid = SOLID_NOT;
        exterior.owner = actor;
        exterior.draggable = drag_undraggable;
        exterior.weaponentity_fld = weaponentity;
        setorigin(exterior, '0 0 0');
        setthink(exterior, CL_ExteriorWeaponentity_Think);
        exterior.nextthink = time;
 
        CSQCMODEL_AUTOINIT(exterior);
    }
}

References CL_ExteriorWeaponentity_Think(), CL_Weaponentity_CustomizeEntityForClient(), CL_Weaponentity_Think(), CSQCMODEL_AUTOINIT, drag_undraggable(), entity(), exteriorweaponentity, setcefc, setmodel, setthink, SOLID_NOT, time, weaponentities, and wepent_link().

Referenced by PutPlayerInServer().

CL_Weapon_GetShotOrg()

vector CL_Weapon_GetShotOrg

(

int

wpn

)

Definition at line 63 of file weaponsystem.qc.

{
    entity wi = REGISTRY_GET(Weapons, wpn);
    entity e = spawn();
    CL_WeaponEntity_SetModel(e, wi.mdl, false);
    vector ret = e.movedir;
    CL_WeaponEntity_SetModel(e, "", false);
    delete(e);
    return ret;
}

References CL_WeaponEntity_SetModel(), entity(), REGISTRY_GET, spawn, vector, and Weapons.

Referenced by PRECACHE().

void()

void	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		int	fire )

References entity().

W_AttachToShotorg()

void W_AttachToShotorg	(	entity	actor,
		.entity	weaponentity,
		entity	flash,
		vector	offset )

Definition at line 660 of file weaponsystem.qc.

{
    flash.owner = actor;
    flash.angles_z = random() * 360;
 
    entity w_ent = actor.(weaponentity);
    entity exterior = actor.exteriorweaponentity;
 
    if (gettagindex(w_ent, "shot")) setattachment(flash, w_ent, "shot");
    else setattachment(flash, w_ent, "tag_shot");
    setorigin(flash, offset);
 
    entity xflash = spawn();
    copyentity_qc(flash, xflash);
 
    flash.viewmodelforclient = actor;
 
    if (w_ent.oldorigin.x > 0)
    {
        setattachment(xflash, exterior, "");
        setorigin(xflash, w_ent.oldorigin + offset);
    }
    else
    {
        if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
        else setattachment(xflash, exterior, "tag_shot");
        setorigin(xflash, offset);
    }
}

References copyentity_qc(), entity(), gettagindex, random(), spawn, and vector.

w_clear()

void w_clear	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		int	fire )

Definition at line 208 of file weaponsystem.qc.

{
    entity w_ent = actor.(weaponentity);
    if (w_ent)
    {
        w_ent.m_weapon = WEP_Null;
        w_ent.m_switchingweapon = WEP_Null;
        w_ent.state = WS_CLEAR;
        w_ent.effects = 0;
    }
}

References entity(), and WS_CLEAR.

Referenced by W_WeaponFrame().

W_DecreaseAmmo()

void W_DecreaseAmmo	(	Weapon	wep,
		entity	actor,
		float	ammo_use,
		.entity	weaponentity )

Definition at line 690 of file weaponsystem.qc.

{
    if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
    if ((actor.items & IT_UNLIMITED_AMMO) && !wep.reloading_ammo) return;
 
    ammo_use = M_ARGV(2, float);
 
    entity w_ent = actor.(weaponentity);
 
    // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
    if (wep.reloading_ammo)
    {
        w_ent.clip_load -= ammo_use;
        w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
    }
    else if (wep.ammo_type != RES_NONE)
    {
        float ammo = GetResource(actor, wep.ammo_type);
        if (ammo < ammo_use)
        {
            backtrace(sprintf(
                "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
                "Please notify the developers immediately with a copy of this backtrace!\n",
                ammo_use, wep.netname, wep.ammo_type.netname, actor.netname, ammo));
        }
        SetResource(actor, wep.ammo_type, ammo - ammo_use);
    }
}

References ammo, Weapon::ammo_type, backtrace, entity(), GetResource(), IT_UNLIMITED_AMMO, M_ARGV, MUTATOR_CALLHOOK, Resource::netname, Weapon::netname, SetResource(), and W_DecreaseAmmo().

Referenced by MUTATOR_HOOKABLE(), W_Crylink_Attack(), W_Crylink_Attack2(), W_DecreaseAmmo(), W_Devastator_Attack(), W_Electro_Attack_Bolt(), W_Electro_Attack_Orb(), W_Hagar_Attack(), W_Hagar_Attack2(), W_Hagar_Attack2_Load(), W_HLAC_Attack(), W_HLAC_Attack2(), W_MachineGun_Attack(), W_MachineGun_Attack_Auto(), W_MineLayer_Attack(), W_Mortar_Attack(), W_Mortar_Attack2(), W_OverkillHeavyMachineGun_Attack_Auto(), W_OverkillMachineGun_Attack_Auto(), W_OverkillNex_Attack(), W_OverkillRocketPropelledChainsaw_Attack(), W_Rifle_FireBullet(), W_Seeker_Fire_Flac(), W_Seeker_Fire_Missile(), W_Seeker_Fire_Tag(), W_Shotgun_Attack(), W_Vaporizer_Attack(), and W_Vortex_Attack().

W_DropEvent()

void W_DropEvent	(	.void(Weapon, entity actor,.entity)	event,
		entity	player,
		int	weapon_type,
		entity	weapon_item,
		.entity	weaponentity )

Definition at line 836 of file weaponsystem.qc.

{
    Weapon w = REGISTRY_GET(Weapons, weapon_type);
    weapon_dropevent_item = weapon_item;
    w.event(w, player, weaponentity);
}

References entity(), REGISTRY_GET, weapon_dropevent_item, and Weapons.

Referenced by Item_GiveTo(), and W_ThrowNewWeapon().

w_ready()

void w_ready	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		int	fire )

Definition at line 220 of file weaponsystem.qc.

{
    entity w_ent = actor.(weaponentity);
    if (w_ent) w_ent.state = WS_READY;
    weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
}

References entity(), w_ready(), weapon_thinkf(), and WS_READY.

Referenced by SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), SOUND(), W_Arc_Attack(), W_Arc_Attack_Bolt(), W_Electro_CheckAttack(), W_Fireball_Attack1_Frame4(), W_Hagar_Attack2_Load_Release(), W_Hagar_Attack_Auto(), W_HLAC_Attack_Frame(), W_MachineGun_Attack_Auto(), W_MachineGun_Attack_Burst(), W_MachineGun_Attack_Frame(), W_OverkillHeavyMachineGun_Attack_Auto(), W_OverkillMachineGun_Attack_Auto(), w_ready(), W_ReloadedAndReady(), W_Rifle_BulletHail(), W_Shotgun_Attack2(), W_Shotgun_Attack3_Frame1(), W_Shotgun_Attack3_Frame2(), W_WeaponFrame(), and weapon_thinkf().

W_Reload()

void W_Reload	(	entity	actor,
		.entity	weaponentity,
		float	sent_ammo_min,
		Sound	sent_sound )

Definition at line 758 of file weaponsystem.qc.

{
    TC(Sound, sent_sound);
    // set global values to work with
    entity this = actor.(weaponentity);
    Weapon e = this.m_weapon;
 
    if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 
    this.reload_ammo_min = sent_ammo_min;
    this.reload_ammo_amount = e.reloading_ammo;
    this.reload_time = e.reloading_time;
    strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
 
    // don't reload weapons that don't have the RELOADABLE flag
    if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
    {
        LOG_TRACE(
            "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
        return;
    }
 
    // return if reloading is disabled for this weapon
    if (!this.reload_ammo_amount) return;
 
    // our weapon is fully loaded, no need to reload
    if (this.clip_load >= this.reload_ammo_amount) return;
 
    // no ammo, so nothing to load
    if (e.ammo_type != RES_NONE)
    {
        if (!GetResource(actor, e.ammo_type) && this.reload_ammo_min)
        {
            if (!(actor.items & IT_UNLIMITED_AMMO))
            {
                if (autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
                    return; // in this case the primary weapon will do the switching when it runs out of ammo (TODO: do this same check but for other slots)
                if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
                {
                    play2(actor, SND(UNAVAILABLE));
                    sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
                    actor.reload_complain = time + 1;
                }
                // switch away if the amount of ammo is not enough to keep using this weapon
                if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
                {
                    this.clip_load = -1;  // reload later
                    W_SwitchToOtherWeapon(actor, weaponentity);
                }
                return;
            }
        }
    }
    if (this)
    {
        if (this.wframe == WFRAME_RELOAD) return;
 
        // allow switching away while reloading, but this will cause a new reload!
        this.state = WS_READY;
    }
 
    // now begin the reloading process
 
    _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 
    // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
    // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
    // so your weapon is disabled for a few seconds without reason
 
    // ATTACK_FINISHED(actor, weaponentity) = max(time, ATTACK_FINISHED(actor, weaponentity)) + this.reload_time + 1;
 
    weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 
    if (this.clip_load < 0) this.clip_load = 0;
    this.old_clip_load = this.clip_load;
    this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
}

References _sound, ATTEN_NORM, autocvar_g_weaponswitch_debug, CH_WEAPON_SINGLE, clip_load, entity(), GetResource(), IS_REAL_CLIENT, IT_UNLIMITED_AMMO, LOG_TRACE, m_weapon, MUTATOR_CALLHOOK, old_clip_load, play2(), reload_ammo_amount, SND, Sound_fixpath, sprint(), state, strcat(), strcpy, TC, time, VOL_BASE, W_Reload(), W_ReloadedAndReady(), W_SwitchToOtherWeapon(), weapon_load, weapon_thinkf(), weaponslot(), WEP_FLAG_RELOADABLE, wframe, and WS_READY.

Referenced by MUTATOR_HOOKABLE(), and W_Reload().

W_ResetGunAlign()

void W_ResetGunAlign	(	entity	player,
		int	preferred_alignment )

Definition at line 436 of file weaponsystem.qc.

{
    if(W_DualWielding(player))
        preferred_alignment = 3; // right align, the second gun will default to left
 
    // clear current weapon slots' alignments so we can redo the calculations!
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if (player.(weaponentity))
            player.(weaponentity).m_gunalign = 0;
    }
 
    // now set the new values
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if (player.(weaponentity))
            player.(weaponentity).m_gunalign = W_GunAlign(player.(weaponentity), preferred_alignment);
    }
}

References entity(), m_gunalign, MAX_WEAPONSLOTS, W_DualWielding(), W_GunAlign(), and weaponentities.

Referenced by PlayerThink(), and PutPlayerInServer().

W_WeaponFrame()

void W_WeaponFrame	(	Player	actor,
		.entity	weaponentity )

Definition at line 460 of file weaponsystem.qc.

{
    TC(Player, actor);
    TC(PlayerState, PS(actor));
    entity this = actor.(weaponentity);
    if (frametime) this.weapon_frametime = frametime;
 
    if (!this || GetResource(actor, RES_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
 
    int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
    int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 
    if (weaponUseForbidden(actor))
        button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 
    if (weaponLocked(actor))
    {
        if (this.state != WS_CLEAR)
        {
            Weapon wpn = this.m_weapon;
            w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
            return;
        }
    }
 
    if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
    {
        .entity wepe1 = weaponentities[0];
        entity wep1 = actor.(wepe1);
        this.m_switchweapon = wep1.m_switchweapon;
        entity store = IS_PLAYER(actor) ? PS(actor) : actor;
        if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
        {
            this.m_weapon = WEP_Null;
            this.m_switchingweapon = WEP_Null;
            this.m_switchweapon = WEP_Null;
            this.state = WS_CLEAR;
            this.weaponname = "";
            this.clip_load = this.clip_size = this.old_clip_load = 0;
            return;
        }
    }
 
    if (this.m_switchweapon == WEP_Null)
    {
        if (this.state != WS_CLEAR)
            w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
        this.m_weapon = WEP_Null;
        this.m_switchingweapon = WEP_Null;
        this.state = WS_CLEAR;
        this.weaponname = "";
        this.clip_load = this.clip_size = this.old_clip_load = 0;
        return;
    }
 
    vector fo, ri, up;
    MAKE_VECTORS(actor.v_angle, fo, ri, up);
 
    // Change weapon
    if (this.m_weapon != this.m_switchweapon)
    {
        switch (this.state)
        {
            default:
                LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
                break;
            case WS_INUSE:
            case WS_RAISE:
                break;
            case WS_CLEAR:
            {
                // end switching!
                Weapon newwep = this.m_switchweapon;
                this.m_switchingweapon = newwep;
 
                // the two weapon entities will notice this has changed and update their models
                this.m_weapon = newwep;
                this.weaponname = newwep.mdl;
                this.bulletcounter = 0;
                newwep.wr_setup(newwep, actor, weaponentity);
                this.state = WS_RAISE;
 
                // set our clip load to the load of the weapon we switched to, if it's reloadable
                if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
                {
                    this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
                    this.clip_size = newwep.reloading_ammo;
                }
                else
                {
                    this.clip_load = this.clip_size = 0;
                }
 
                weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
                break;
            }
            case WS_DROP:
            {
                // in dropping phase we can switch at any time
                this.m_switchingweapon = this.m_switchweapon;
                break;
            }
            case WS_READY:
            {
                // start switching!
                this.m_switchingweapon = this.m_switchweapon;
                entity oldwep = this.m_weapon;
 
                // set up weapon switch think in the future, and start drop anim
                if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponentity) <= time + this.weapon_frametime * 0.5)
                {
                    sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
                    this.state = WS_DROP;
                    weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
                }
                break;
            }
        }
    }
 
    // LordHavoc: network timing test code
    // if (actor.button0)
    //  print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, weaponentity)), " >= ", ftos(this.weapon_nextthink), "\n");
 
    Weapon w = this.m_weapon;
 
    // call the think code which may fire the weapon
    // and do so multiple times to resolve framerate dependency issues if the
    // server framerate is very low and the weapon fire rate very high
    for (int c = 0; c < W_TICSPERFRAME; ++c)
    {
        if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
        {
            if (this.m_weapon == this.m_switchweapon)
                W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
            w = WEP_Null;
        }
 
        v_forward = fo;
        v_right = ri;
        v_up = up;
 
        bool block_weapon = false;
        {
            bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
            if (weaponUseForbidden(actor))
                key_pressed = false;
 
            Weapon off = actor.offhand;
            if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
            {
                if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
            }
            else
            {
                if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
                    W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
                actor.hook_switchweapon = key_pressed;
                Weapon h = WEP_HOOK;
                block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
                h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
            }
        }
 
        v_forward = fo;
        v_right = ri;
        v_up = up;
 
        if (!block_weapon)
        {
            Weapon e = this.m_weapon;
            TC(Weapon, e);
            if (w != WEP_Null)
            {
                e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
            }
            else if (e)
            {
                e.wr_gonethink(e, actor, weaponentity);
            }
        }
 
        if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
        {
            if (this.weapon_think)
            {
                v_forward = fo;
                v_right = ri;
                v_up = up;
                Weapon wpn = this.m_weapon;
                this.weapon_think(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
            }
            else
            {
                bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
            }
        }
    }
}

References ATTACK_FINISHED, ATTN_NORM, autocvar_g_weaponswitch_debug, bprint(), bulletcounter, CH_WEAPON_SINGLE, clip_load, clip_size, entity(), frametime, GetResource(), INDEPENDENT_ATTACK_FINISHED, IS_PLAYER, LOG_WARNF, m_switchingweapon, m_switchweapon, m_weapon, MAKE_VECTORS, Weapon::mdl, Client::netname, OFFHAND_HOOK, old_clip_load, PHYS_INPUT_BUTTON_ATCK, PHYS_INPUT_BUTTON_ATCK2, PHYS_INPUT_BUTTON_HOOK, PS, sound, Weapon::spawnflags, STAT, state, TC, time, Client::v_angle, v_forward, v_right, v_up, vector, VOL_BASE, w_clear(), w_getbestweapon, w_ready(), W_SwitchWeapon(), W_SwitchWeapon_Force(), W_TICSPERFRAME, weapon_frametime, weapon_load, weapon_nextthink, weapon_thinkf(), weaponentities, weaponLocked(), weaponname, weaponslot(), weaponUseForbidden(), WEP_FLAG_DUALWIELD, WEP_FLAG_RELOADABLE, WEPSET, WepSet_FromWeapon, Weapon::wr_gonethink(), Weapon::wr_setup(), Weapon::wr_think(), WS_CLEAR, WS_DROP, WS_INUSE, WS_RAISE, and WS_READY.

Referenced by PlayerThink(), and PutPlayerInServer().

W_WeaponRateFactor()

float W_WeaponRateFactor

(

entity

this

)

Definition at line 33 of file weaponsystem.qc.

{
    float t = 1;
    if(autocvar_g_weaponratefactor > 0)
        t = 1.0 / autocvar_g_weaponratefactor;
 
    MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
    t = M_ARGV(0, float);
 
    return t;
}

Referenced by weapon_prepareattack_do(), and weapon_thinkf().

W_WeaponSpeedFactor()

float W_WeaponSpeedFactor

(

entity

this

)

Definition at line 45 of file weaponsystem.qc.

{
    float t = 1.0 * autocvar_g_weaponspeedfactor;
 
    MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
    t = M_ARGV(0, float);
 
    return t;
}

References autocvar_g_weaponspeedfactor, entity(), M_ARGV, and MUTATOR_CALLHOOK.

Referenced by bot_aim(), W_CalculateProjectileVelocity(), and W_Devastator_Think().

weapon_prepareattack()

bool weapon_prepareattack	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		bool	secondary,
		float	attacktime )

Definition at line 342 of file weaponsystem.qc.

{
    if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
    {
        weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
        return true;
    }
    return false;
}

References entity(), weapon_prepareattack_check(), and weapon_prepareattack_do().

Referenced by SOUND(), SOUND(), W_Electro_CheckAttack(), and W_Rifle_BulletHail_Continue().

weapon_prepareattack_check()

bool weapon_prepareattack_check	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		bool	secondary,
		float	attacktime )

Definition at line 273 of file weaponsystem.qc.

{
    if (actor.weaponentity == NULL) return true;
    if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 
    // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
    // if all players readied up and the countdown is running
    if (time < game_starttime || time < actor.race_penalty) return false;
 
    if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
        return false;
 
    // do not even think about shooting if switching
    if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 
    if (attacktime >= 0)
    {
        // don't fire if previous attack is not finished
        if (ATTACK_FINISHED(actor, weaponentity) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
        entity this = actor.(weaponentity);
        // don't fire while changing weapon
        if (!actor.vehicle && this.state != WS_READY) return false;
    }
    return true;
}

References ATTACK_FINISHED, entity(), game_starttime, NULL, time, TIMEOUT_ACTIVE, timeout_status, weapon_prepareattack_checkammo(), and WS_READY.

Referenced by W_Arc_Beam_Think(), W_Hagar_Attack_Auto(), W_MachineGun_Attack_Auto(), W_MachineGun_Attack_Frame(), and weapon_prepareattack().

weapon_prepareattack_do()

void weapon_prepareattack_do	(	entity	actor,
		.entity	weaponentity,
		bool	secondary,
		float	attacktime )

Definition at line 299 of file weaponsystem.qc.

{
    entity this = actor.(weaponentity);
    if (this == NULL) return;
    this.state = WS_INUSE;
 
    if(StatusEffects_active(STATUSEFFECT_SpawnShield, actor)) // given this is performed often, perform a lighter check first
        StatusEffects_remove(STATUSEFFECT_SpawnShield, actor, STATUSEFFECT_REMOVE_CLEAR); // kill spawn shield when you fire
 
    // if the weapon hasn't been firing continuously, reset the timer
    if (attacktime >= 0)
    {
        if (ATTACK_FINISHED(actor, weaponentity) < time - this.weapon_frametime * 1.5)
        {
            ATTACK_FINISHED(actor, weaponentity) = time;
            // dprint("resetting attack finished to ", ftos(time), "\n");
        }
        float arate = W_WeaponRateFactor(actor);
        ATTACK_FINISHED(actor, weaponentity) = ATTACK_FINISHED(actor, weaponentity) + attacktime * arate;
 
        if(autocvar_g_weaponswitch_debug_alternate && W_DualWielding(actor))
        {
            int slot = weaponslot(weaponentity);
            for(int wepslot = 0; wepslot < MAX_WEAPONSLOTS; ++wepslot)
            {
                if(slot == wepslot)
                    continue;
                .entity wepent = weaponentities[wepslot];
                if(actor.(wepent) && actor.(wepent).m_weapon != WEP_Null)
                {
                    if(ATTACK_FINISHED(actor, wepent) > time + actor.(wepent).weapon_frametime * 0.5)
                        continue; // still cooling down!
                    if (ATTACK_FINISHED(actor, wepent) < time - actor.(wepent).weapon_frametime * 1.5)
                        ATTACK_FINISHED(actor, wepent) = time;
                    ATTACK_FINISHED(actor, wepent) = ATTACK_FINISHED(actor, wepent) + (attacktime * arate) / MAX_WEAPONSLOTS;
                }
            }
        }
    }
    this.bulletcounter += 1;
    // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, weaponentity)), "\n");
}

References ATTACK_FINISHED, autocvar_g_weaponswitch_debug_alternate, bulletcounter, entity(), MAX_WEAPONSLOTS, NULL, state, STATUSEFFECT_REMOVE_CLEAR, StatusEffects_active(), StatusEffects_remove(), time, W_DualWielding(), W_WeaponRateFactor(), weapon_frametime, weaponentities, weaponslot(), and WS_INUSE.

Referenced by W_Hagar_Attack2_Load_Release(), and weapon_prepareattack().

weapon_thinkf()

void weapon_thinkf	(	entity	actor,
		.entity	weaponentity,
		WFRAME	fr,
		float	t,
		void(Weapon thiswep, entity actor,.entity weaponentity, int fire)	func )

Parameters

t	defer thinking until time + t
func	next think function

Definition at line 356 of file weaponsystem.qc.

{
    entity this = actor.(weaponentity);
    if (this == NULL) return;
    bool restartanim;
    if (fr == WFRAME_DONTCHANGE)
    {
        // this can happen when the weapon entity is newly spawned, since it has a clear state and no previous weapon frame
        if (this.wframe == WFRAME_DONTCHANGE)
            this.wframe = WFRAME_IDLE;
        fr = this.wframe;
        restartanim = false;
    }
    else
    {
        restartanim = fr != WFRAME_IDLE;
    }
 
    this.wframe = fr;
 
    if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE)
        backtrace("Tried to override initial weapon think function - should this really happen?");
 
    t *= W_WeaponRateFactor(actor);
 
    // VorteX: haste can be added here
    if (this.weapon_think == w_ready)
    {
        this.weapon_nextthink = time;
        // dprint("started firing at ", ftos(time), "\n");
    }
    float w_frametime_limit = this.weapon_frametime * 1.5;
    if (this.weapon_nextthink < time - w_frametime_limit || this.weapon_nextthink > time + w_frametime_limit)
    {
        this.weapon_nextthink = time;
        // dprint("reset weapon animation timer at ", ftos(time), "\n");
    }
    this.weapon_nextthink += t;
    this.weapon_think = func;
    // dprint("next ", ftos(this.weapon_nextthink), "\n");
 
    if (this)
    {
        FOREACH_CLIENT(true, {
            if(it == actor || (IS_SPEC(it) && it.enemy == actor))
                wframe_send(it, this, fr, autocvar_g_weaponratefactor, restartanim);
        });
    }
 
    if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
    {
        bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
        bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
        int act = (primary_melee || secondary_melee) ? ANIMACTION_MELEE : ANIMACTION_SHOOT;
        animdecide_setaction(actor, act, restartanim);
    }
    else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
    {
        actor.anim_upper_action = 0;
    }
}

References ANIMACTION_MELEE, ANIMACTION_SHOOT, animdecide_setaction(), autocvar_g_weaponratefactor, backtrace, boolean, entity(), FOREACH_CLIENT, IS_SPEC, m_weapon, NULL, state, time, w_ready(), W_WeaponRateFactor(), weapon_frametime, weapon_nextthink, WEP_TYPE_MELEE_PRI, WEP_TYPE_MELEE_SEC, wframe, wframe_send(), and WS_RAISE.

Referenced by W_Arc_Attack(), W_Arc_Attack_Bolt(), W_Electro_CheckAttack(), W_Fireball_Attack1_Frame0(), W_Fireball_Attack1_Frame1(), W_Fireball_Attack1_Frame2(), W_Fireball_Attack1_Frame3(), W_Fireball_Attack1_Frame4(), W_Hagar_Attack2_Load_Release(), W_Hagar_Attack_Auto(), W_HLAC_Attack_Frame(), W_MachineGun_Attack_Auto(), W_MachineGun_Attack_Burst(), W_MachineGun_Attack_Frame(), W_OverkillHeavyMachineGun_Attack_Auto(), W_OverkillMachineGun_Attack_Auto(), w_ready(), W_Reload(), W_Rifle_BulletHail(), W_Rifle_BulletHail_Continue(), W_Shotgun_Attack2(), W_Shotgun_Attack3_Frame1(), W_Shotgun_Attack3_Frame2(), and W_WeaponFrame().

weaponLocked()

bool weaponLocked

(

entity

player

)

Definition at line 426 of file weaponsystem.qc.

{
    if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
    if (player.player_blocked) return true;
    if (game_stopped) return true;
    if (StatusEffects_active(STATUSEFFECT_Frozen, player)) return true;
    if (MUTATOR_CALLHOOK(LockWeapon, player)) return true;
    return false;
}

References entity(), game_starttime, game_stopped, MUTATOR_CALLHOOK, StatusEffects_active(), sv_ready_restart_after_countdown, and time.

Referenced by bumblebee_gunner_frame(), bumblebee_pilot_frame(), CanThrowNade(), FireGrapplingHook(), IMPULSE(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), racer_frame(), raptor_frame(), spiderbot_frame(), spiderbot_rocket_do(), vehicles_touch(), W_SwitchWeapon(), and W_WeaponFrame().

weaponUseForbidden()

bool weaponUseForbidden

(

entity

player

)

Definition at line 419 of file weaponsystem.qc.

{
    if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
    if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
    return false;
}

References entity(), MUTATOR_CALLHOOK, round_handler_IsActive, and round_handler_IsRoundStarted.

Referenced by bumblebee_gunner_frame(), bumblebee_pilot_frame(), racer_frame(), raptor_frame(), spiderbot_frame(), spiderbot_rocket_do(), W_Hagar_Attack2_Load(), and W_WeaponFrame().

Variable Documentation

ammo_none

int ammo_none

Definition at line 29 of file weaponsystem.qh.

attack_finished_for

float attack_finished_for[REGISTRY_MAX(Weapons) *MAX_WEAPONSLOTS]

Definition at line 34 of file weaponsystem.qh.

attack_finished_single

float attack_finished_single[MAX_WEAPONSLOTS]

Definition at line 35 of file weaponsystem.qh.

Referenced by M_Mage_Attack_Push(), M_Mage_Attack_Teleport(), M_Mage_Defend_Heal(), M_Mage_Defend_Shield(), M_Zombie_Defend_Block(), Monster_Attack_Check(), Monster_Attack_Leap(), Monster_Attack_Leap_Check(), Monster_Attack_Melee(), Monster_Dead(), Monster_Move(), Monster_Move_2D(), Monster_Reset(), spiderbot_rocket_do(), turret_aim_generic(), turret_fire(), turret_firecheck(), and turret_fusionreactor_firecheck().

autocvar_g_weapondamagefactor

float autocvar_g_weapondamagefactor

Definition at line 6 of file weaponsystem.qh.

Referenced by Damage().

autocvar_g_weaponforcefactor

float autocvar_g_weaponforcefactor

Definition at line 5 of file weaponsystem.qh.

Referenced by Damage().

autocvar_g_weaponratefactor

float autocvar_g_weaponratefactor

Definition at line 7 of file weaponsystem.qh.

Referenced by W_WeaponRateFactor(), and weapon_thinkf().

autocvar_g_weaponspeedfactor

float autocvar_g_weaponspeedfactor

Definition at line 8 of file weaponsystem.qh.

Referenced by W_WeaponSpeedFactor().

bulletcounter

float bulletcounter

Definition at line 24 of file weaponsystem.qh.

Referenced by W_Fireball_Attack2(), W_Seeker_Fire_Flac(), W_WeaponFrame(), and weapon_prepareattack_do().

clip_load

int clip_load

Definition at line 30 of file weaponsystem.qh.

clip_size

int clip_size

Definition at line 32 of file weaponsystem.qh.

internalteam

float internalteam

Definition at line 19 of file weaponsystem.qh.

Referenced by weapon_defaultspawnfunc().

old_clip_load

int old_clip_load

Definition at line 31 of file weaponsystem.qh.

Referenced by W_Reload(), and W_WeaponFrame().

W_TICSPERFRAME

const int W_TICSPERFRAME = 2

Definition at line 13 of file weaponsystem.qh.

Referenced by PlayerThink(), and W_WeaponFrame().

weapon_dropevent_item

entity weapon_dropevent_item

Definition at line 20 of file weaponsystem.qh.

Referenced by W_DropEvent().

weapon_load

float weapon_load[REGISTRY_MAX(Weapons)]

Definition at line 28 of file weaponsystem.qh.

Referenced by havocbot_chooseweapon_checkreload(), NIX_GiveCurrentWeapon(), PutPlayerInServer(), W_Hagar_Attack2_Load(), W_Reload(), W_ThrowNewWeapon(), and W_WeaponFrame().

weapon_nextthink

float weapon_nextthink

Definition at line 16 of file weaponsystem.qh.

weaponentity_fld

entity weaponentity_fld

Definition at line 26 of file weaponsystem.qh.

Referenced by CL_ExteriorWeaponentity_Think(), CL_Weaponentity_Think(), GrapplingHookSend(), GrapplingHookThink(), RemoveHook(), W_Arc_Beam_Send(), W_Arc_Beam_Think(), W_Arc_Bolt_Explode(), W_Arc_Bolt_Touch(), W_Blaster_Touch(), W_Crylink_LinkJoinEffect_Think(), W_Crylink_Touch(), W_Devastator_DoRemoteExplode(), W_Devastator_Explode(), W_Devastator_Think(), W_Electro_Explode(), W_Electro_ExplodeComboThink(), W_Electro_Orb_ExplodeOverTime(), W_Electro_Orb_Stick(), W_Fireball_Explode(), W_Hagar_Explode(), W_Hagar_Explode2(), W_HLAC_Touch(), W_Hook_ExplodeThink(), W_MineLayer_DoRemoteExplode(), W_MineLayer_Explode(), W_MineLayer_Stick(), W_MineLayer_Think(), W_Mortar_Grenade_Explode(), W_Mortar_Grenade_Explode2(), W_OverkillRocketPropelledChainsaw_Explode(), W_OverkillRocketPropelledChainsaw_Think(), W_Porto_Fail(), W_RocketMinsta_Laser_Damage(), W_Seeker_Flac_Explode(), W_Seeker_Missile_Explode(), W_Seeker_Tag_Touch(), W_Seeker_Tracker_Think(), W_Seeker_Vollycontroller_Think(), and W_Tuba_NoteOff().