round_handler.qc File Reference

#include "round_handler.qh"
#include <common/mapobjects/triggers.qh>
#include <common/scores.qh>
#include <common/util.qh>
#include <server/campaign.qh>
#include <server/command/vote.qh>
#include <server/scores.qh>
#include <server/world.qh>

Include dependency graph for round_handler.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	round_handler_FirstThink (entity this)
void	round_handler_Init (float the_delay, float the_count, float the_round_timelimit)
void	round_handler_Remove ()
void	round_handler_Reset (float next_think)
void	round_handler_Spawn (bool() canRoundStart_func, bool() canRoundEnd_func, void() roundStart_func)
void	round_handler_Think (entity this)

Function Documentation

round_handler_FirstThink()

void round_handler_FirstThink

(

entity

this

)

Definition at line 91 of file round_handler.qc.

{
    round_starttime = max(time, game_starttime) + this.count;
    setthink(this, round_handler_Think);
    this.nextthink = max(time, game_starttime);
}

References count, entity(), game_starttime, max(), nextthink, round_handler_Think(), round_starttime, setthink, and time.

Referenced by round_handler_Spawn().

round_handler_Init()

void round_handler_Init	(	float	the_delay,
		float	the_count,
		float	the_round_timelimit )

Definition at line 79 of file round_handler.qc.

{
    entity this = round_handler;
    this.delay = (the_delay > 0) ? the_delay : 0;
    this.count = fabs(floor(the_count));
    this.cnt = this.count + 1;
    this.round_timelimit = (the_round_timelimit > 0) ? the_round_timelimit : 0;
    round_limit = the_round_timelimit;
}

References cnt, count, delay, entity(), fabs(), floor(), round_handler, round_limit, and round_timelimit.

Referenced by CA_CheckWinner(), dom_DelayedInit(), Domination_CheckWinner(), freezetag_CheckWinner(), freezetag_Initialize(), Invasion_CheckWinner(), invasion_DelayedInit(), ons_DelayedInit(), Onslaught_CheckWinner(), REGISTER_MUTATOR(), round_handler_Spawn(), Surv_CheckWinner(), and surv_Initialize().

round_handler_Remove()

void round_handler_Remove

(

)

Definition at line 134 of file round_handler.qc.

{
    delete(round_handler);
    round_handler = NULL;
}

References NULL, and round_handler.

Referenced by round_handler_Think().

round_handler_Reset()

void round_handler_Reset

(

float

next_think

)

Definition at line 119 of file round_handler.qc.

{
    entity this = round_handler;
    this.wait = false;
    round_handler_ResetEndDelayTime();
    if (this.count)
        if (this.cnt < this.count + 1) this.cnt = this.count + 1;
    this.nextthink = next_think;
    if (next_think)
    {
        if (next_think <= game_starttime) rounds_played = 0;
        round_starttime = next_think + this.count;
    }
}

References cnt, count, entity(), game_starttime, nextthink, round_handler, round_handler_ResetEndDelayTime, round_starttime, rounds_played, and wait.

Referenced by reset_map(), and round_handler_Think().

round_handler_Spawn()

void round_handler_Spawn	(	bool()	canRoundStart_func,
		bool()	canRoundEnd_func,
		void()	roundStart_func )

Definition at line 98 of file round_handler.qc.

{
    if (round_handler)
    {
        backtrace("Can't spawn round_handler again!");
        return;
    }
    entity this = round_handler = new_pure(round_handler);
 
    setthink(this, round_handler_FirstThink);
    this.canRoundStart = canRoundStart_func;
    this.canRoundEnd = canRoundEnd_func;
    this.roundStart = roundStart_func;
    this.wait = false;
    round_handler_ResetEndDelayTime();
    round_handler_Init(5, 5, 180);
    this.nextthink = time;
 
    ScoreInfo_SetLabel_PlayerScore(SP_ROUNDS_PL, "rounds_pl", 0);
}

References backtrace, entity(), new_pure, nextthink, round_handler, round_handler_FirstThink(), round_handler_Init(), round_handler_ResetEndDelayTime, ScoreInfo_SetLabel_PlayerScore(), setthink, time, and wait.

Referenced by dom_DelayedInit(), freezetag_Initialize(), invasion_DelayedInit(), ons_DelayedInit(), REGISTER_MUTATOR(), and surv_Initialize().

round_handler_Think()

void round_handler_Think

(

entity

this

)

Definition at line 11 of file round_handler.qc.

{
    if (intermission_running)
    {
        round_handler_Reset(0);
        round_handler_Remove();
        return;
    }
 
    if (time < game_starttime)
    {
        round_handler_Reset(game_starttime);
        return;
    }
 
    game_stopped = false;
 
    if (this.wait)
    {
        this.wait = false;
        this.cnt = this.count + 1;  // init countdown
        round_starttime = time + this.count;
        reset_map(false);
    }
 
    if (this.cnt > 0)  // countdown running
    {
        if (this.canRoundStart() && !(autocvar_g_campaign && !campaign_bots_may_start))
        {
            if (this.cnt == this.count + 1) round_starttime = time + this.count;
            int f = this.cnt - 1;
            if (f == 0)
            {
                FOREACH_CLIENT((IS_PLAYER(it) || INGAME(it)), {
                    GameRules_scoring_add(it, ROUNDS_PL, 1);
                });
                this.cnt = 0;
                this.round_endtime = (this.round_timelimit) ? time + this.round_timelimit : 0;
                this.nextthink = time;
                rounds_played++;
                if (this.roundStart) this.roundStart();
                return;
            }
            this.cnt = this.cnt - 1;
        }
        else
        {
            round_handler_Reset(0);
            round_starttime = -1; // can't start
        }
        this.nextthink = time + 1;  // canRoundStart every second
    }
    else
    {
        if (this.canRoundEnd())
        {
            // schedule a new round
            this.wait = true;
            this.nextthink = time + this.delay;
            round_handler_ResetEndDelayTime();
        }
        else
        {
            this.nextthink = time;  // canRoundEnd every frame
        }
    }
}

References autocvar_g_campaign, campaign_bots_may_start, cnt, count, delay, entity(), FOREACH_CLIENT, game_starttime, game_stopped, GameRules_scoring_add, INGAME, intermission_running, IS_PLAYER, nextthink, reset_map(), round_endtime, round_handler_Remove(), round_handler_Reset(), round_handler_ResetEndDelayTime, round_starttime, round_timelimit, rounds_played, time, and wait.

Referenced by round_handler_FirstThink().