vote.qc File Reference

#include "vote.qh"
#include <common/command/_mod.qh>
#include <common/constants.qh>
#include <common/gametypes/_mod.qh>
#include <common/items/inventory.qh>
#include <common/mapinfo.qh>
#include <common/net_linked.qh>
#include <common/notifications/all.qh>
#include <common/playerstats.qh>
#include <common/stats.qh>
#include <common/util.qh>
#include <common/weapons/_all.qh>
#include <server/campaign.qh>
#include <server/client.qh>
#include <server/command/banning.qh>
#include <server/command/common.qh>
#include <server/damage.qh>
#include <server/gamelog.qh>
#include <server/intermission.qh>
#include <server/mutators/_mod.qh>
#include <server/race.qh>
#include <server/round_handler.qh>
#include <server/scores.qh>
#include <server/teamplay.qh>
#include <server/weapons/accuracy.qh>
#include <server/weapons/selection.qh>
#include <server/world.qh>

Include dependency graph for vote.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	spectators_allowed   (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
#define	VOTE_COMMAND(name, function, description, assignment)
#define	VOTE_COMMAND(name, function, description, assignment)
#define	VOTE_COMMAND(name, function, description, assignment)
#define	VOTE_COMMANDS(request, caller, arguments, command)

Functions
void	Nagger_Init ()
void	Nagger_ReadyCounted ()
bool	Nagger_SendEntity (entity this, entity to, float sendflags)
void	Nagger_VoteChanged ()
void	Nagger_VoteCountChanged ()
string	OriginalCallerName ()
void	print_available_commands_to (entity caller)
void	ReadyCount ()
void	ReadyRestart (bool forceWarmupEnd)
void	ReadyRestart_force (bool is_fake_round_start)
void	ReadyRestart_think (entity this)
void	reset_map (bool is_fake_round_start)
string	ValidateMap (string validated_map, entity caller)
void	VoteAccept ()
void	VoteCommand (int request, entity caller, int argc, string vote_command)
void	VoteCommand_abstain (int request, entity caller)
void	VoteCommand_call (int request, entity caller, int argc, string vote_command)
bool	Votecommand_check_assignment (entity caller, float assignment)
float	VoteCommand_checkargs (float startpos, int argc)
bool	VoteCommand_checkinlist (string vote_command, string list)
bool	VoteCommand_checknasty (string vote_command)
string	VoteCommand_checkreplacements (string input)
string	VoteCommand_extractcommand (string input, float startpos, int argc)
float	VoteCommand_macro_command (entity caller, int argc, string vote_command)
void	VoteCommand_macro_help (entity caller, int argc)
void	VoteCommand_master (int request, entity caller, int argc, string vote_command)
void	VoteCommand_no (int request, entity caller)
int	VoteCommand_parse (entity caller, string vote_command, string vote_list, float startpos, int argc)
void	VoteCommand_status (int request, entity caller)
void	VoteCommand_stop (int request, entity caller)
void	VoteCommand_yes (int request, entity caller)
void	VoteCount (float first_count)
void	VoteReject ()
void	VoteReset (bool verbose)
void	VoteSpam (float notvoters, float mincount, string result)
void	VoteStop (entity stopper, bool show_name)
void	VoteThink ()
void	VoteTimeout ()

Macro Definition Documentation

spectators_allowed

#define spectators_allowed   (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))

Definition at line 218 of file vote.qc.

Referenced by VoteCommand_call(), VoteCommand_master(), and VoteCount().

VOTE_COMMAND [1/3]

#define VOTE_COMMAND	(		name,
			function,
			description,
			assignment )

Value:

            { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }

VOTE_COMMAND [2/3]

#define VOTE_COMMAND	(		name,
			function,
			description,
			assignment )

Value:

            { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }

VOTE_COMMAND [3/3]

#define VOTE_COMMAND	(		name,
			function,
			description,
			assignment )

Value:

        { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }

VOTE_COMMANDS

#define VOTE_COMMANDS	(		request,
			caller,
			arguments,
			command )

Value:

    VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
    /* nothing */

Definition at line 1371 of file vote.qc.

#define VOTE_COMMANDS(request, caller, arguments, command) \
    VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
    VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
    VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
    /* nothing */

Referenced by VoteCommand_macro_command(), and VoteCommand_macro_help().

Function Documentation

Nagger_Init()

void Nagger_Init

(

)

Definition at line 97 of file vote.qc.

{
    Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
}

References nagger, Nagger_SendEntity(), Net_LinkEntity(), and new_pure.

Referenced by spawnfunc().

Nagger_ReadyCounted()

void Nagger_ReadyCounted

(

)

Definition at line 112 of file vote.qc.

{
    if (nagger) nagger.SendFlags |= BIT(0);
}

References BIT, and nagger.

Referenced by ReadyCount(), and ReadyRestart_force().

Nagger_SendEntity()

bool Nagger_SendEntity	(	entity	this,
		entity	to,
		float	sendflags )

Definition at line 37 of file vote.qc.

{
    int nags = 0;
    WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
 
    // bits:
    //   1 = ready
    //   2 = player needs to ready up
    //   4 = vote
    //   8 = player needs to vote
    //  16 = warmup
    // sendflags:
    //  64 = vote counts
    // 128 = vote string
 
    if (warmup_stage)
    {
        if (readycount)
        {
            nags |= BIT(0);
            if (!to.ready) nags |= BIT(1);
        }
        nags |= BIT(4);
    }
 
    if (vote_called)
    {
        nags |= BIT(2);
        if (to.vote_selection == 0) nags |= BIT(3);
        nags |= sendflags & BIT(6);
        nags |= sendflags & BIT(7);
    }
 
    WriteByte(MSG_ENTITY, nags);
 
    if (nags & BIT(6))
    {
        WriteByte(MSG_ENTITY, vote_accept_count);
        WriteByte(MSG_ENTITY, vote_reject_count);
        WriteByte(MSG_ENTITY, vote_needed_overall);
        WriteChar(MSG_ENTITY, to.vote_selection);
    }
 
    if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
 
    if (nags & BIT(0))
    {
        for (int i = 1; i <= maxclients;)
        {
            int f = 0;
            for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
                if (edict_num(i).ready)
                    f |= BIT(b);
            WriteByte(MSG_ENTITY, f);
        }
    }
 
    return true;
}

References BIT, entity(), maxclients, MSG_ENTITY, ready, readycount, vote_accept_count, vote_called, vote_called_display, vote_needed_overall, vote_reject_count, warmup_stage, WriteByte(), WriteChar(), WriteHeader, and WriteString().

Referenced by Nagger_Init().

Nagger_VoteChanged()

void Nagger_VoteChanged

(

)

Definition at line 102 of file vote.qc.

{
    if (nagger) nagger.SendFlags |= BIT(7);
}

References BIT, and nagger.

Referenced by VoteCommand_call(), VoteCommand_master(), and VoteReset().

Nagger_VoteCountChanged()

void Nagger_VoteCountChanged

(

)

Definition at line 107 of file vote.qc.

{
    if (nagger) nagger.SendFlags |= BIT(6);
}

References BIT, and nagger.

Referenced by VoteCount().

OriginalCallerName()

string OriginalCallerName

(

)

Definition at line 118 of file vote.qc.

{
    if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
    return vote_caller_name;
}

References IS_REAL_CLIENT, playername(), vote_caller, and vote_caller_name.

Referenced by VoteAccept(), VoteCommand_call(), VoteCommand_master(), VoteCommand_status(), VoteReject(), VoteStop(), and VoteTimeout().

print_available_commands_to()

void print_available_commands_to

(

entity

caller

)

Definition at line 981 of file vote.qc.

{
    print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
}

References autocvar_sv_vote_commands, entity(), print_to(), and strcat().

Referenced by VoteCommand_call(), and VoteCommand_macro_help().

ReadyCount()

void ReadyCount

(

)

Definition at line 553 of file vote.qc.

{
    // cannot reset the game while a timeout is active or pending
    if (timeout_status) return;
 
    int total_players = 0, human_players = 0, humans_ready = 0;
    readycount = 0;
 
    FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
        ++total_players;
        if (it.ready) ++readycount;
        if (IS_REAL_CLIENT(it))
        {
            ++human_players;
            if (it.ready) ++humans_ready;
        }
    });
 
    Nagger_ReadyCounted();
 
    // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
    // and we need to use this when checking if we should abort the countdown
    // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
    int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 
    // This allows warmup to end with zero players to prevent complaints
    // of server never changing map with legacy config (sv_autopause 0).
    bool badteams = (teamplay && total_players && autocvar_sv_teamnagger)
        ? TeamBalance_SizeDifference(NULL) >= autocvar_sv_teamnagger
        : false;
 
    if (total_players < minplayers || badteams)
    {
        if (game_starttime > time) // someone bailed during countdown, back to warmup
        {
            warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
            game_starttime = time;
            if (total_players < minplayers)
                Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP_MINPLAYERS, minplayers);
            else
                Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP_BADTEAMS);
            if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
                FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
        }
        warmup_limit = -1;
        return; // don't ReadyRestart if players are ready but too few or teams are bad
    }
    else if (warmup_limit <= 0
    && game_starttime <= time) // No countdown in progress, check prevents early countdown end if only player leaves
    {
        // there's enough players now and teams are ok
        // but we're still in infinite warmup and may need to switch to timed warmup
        warmup_limit = cvar("g_warmup_limit");
        if (warmup_limit == 0)
            warmup_limit = autocvar_timelimit * 60;
        if (warmup_limit > 0)
            game_starttime = time;
        // implicit else: g_warmup -1 && g_warmup_limit -1 means
        // warmup continues until enough players AND enough RUPs (no time limit)
    }
 
    if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
        ReadyRestart(true);
}

References autocvar_g_warmup, autocvar_sv_teamnagger, autocvar_timelimit, bound(), cvar(), FOREACH_CLIENT, game_starttime, GiveWarmupResources(), INGAME_JOINED, IS_PLAYER, IS_REAL_CLIENT, map_minplayers, Nagger_ReadyCounted(), NULL, readycount, ReadyRestart(), rint(), Send_Notification(), sv_ready_restart_after_countdown, TeamBalance_SizeDifference(), teamplay, time, timeout_status, total_players, warmup_limit, and warmup_stage.

Referenced by bot_think(), ClientCommand_ready(), ClientDisconnect(), PutObserverInServer(), PutPlayerInServer(), SetPlayerTeam(), and timeout_handler_reset().

ReadyRestart()

void ReadyRestart

(

bool

forceWarmupEnd

)

Definition at line 526 of file vote.qc.

{
    if (MUTATOR_CALLHOOK(ReadyRestart_Deny))
    {
        // NOTE: ReadyRestart support is mandatory in campaign
        if (autocvar_g_campaign)
            error("ReadyRestart must be supported in campaign mode!");
        localcmd("restart\n"); // if ReadyRestart is denied, restart the server
    }
    else if (intermission_running || race_completing) // game is over, ReadyRestart no longer available
        localcmd("restart\n");
    else
        localcmd("\nsv_hook_readyrestart\n");
 
    if(forceWarmupEnd || autocvar_g_campaign)
        warmup_stage = 0; // forcefully end warmup and go to match stage
    else
        warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 
    ReadyRestart_force(false);
}

References autocvar_g_campaign, autocvar_g_warmup, error, intermission_running, localcmd(), MUTATOR_CALLHOOK, race_completing, ReadyRestart_force(), and warmup_stage.

Referenced by CheckRules_World(), GameCommand_allready(), GameCommand_resetmatch(), Join(), ReadyCount(), and StartFrame().

ReadyRestart_force()

void ReadyRestart_force

(

bool

is_fake_round_start

)

Definition at line 441 of file vote.qc.

{
    if (time <= game_starttime && game_stopped)
        return;
    if (!is_fake_round_start && !autocvar_g_campaign)
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 
    VoteReset(true);
 
    // clear overtime, we have to decrease timelimit to its original value again.
    if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
        cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
    checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 
    if(warmup_stage)
        game_starttime = time; // Warmup: No countdown in warmup
    else if (autocvar_g_campaign)
        game_starttime = time + 3;
    else
        game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 
    // clear player attributes
    FOREACH_CLIENT(IS_PLAYER(it), {
        it.alivetime_start = 0;
        CS(it).killcount = 0;
    });
 
    // if we're ending the warmup stage call the corresponding hook
    if(!is_fake_round_start && !warmup_stage)
        localcmd("\nsv_hook_warmupend\n");
 
    // reset the .ready status of all clients (including spectators and bots)
    FOREACH_CLIENT(true, { it.ready = false; });
    readycount = 0;
    Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 
    // lock teams with lockonrestart
    if (autocvar_teamplay_lockonrestart && teamplay)
        lockteams = !warmup_stage;
 
    // initiate the restart-countdown-announcer entity
    if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
    {
        entity restart_timer = new_pure(restart_timer);
        setthink(restart_timer, ReadyRestart_think);
        restart_timer.nextthink = game_starttime;
    }
 
    // If we're returning to warmup join/switch all queued players for consistency:
    // there's no queueing in warmup and imbalances are handled by sv_teamnagger blocking end of warmup.
    if (warmup_stage)
    {
        // First pass: join player(s) queued for specific team(s)
        FOREACH_CLIENT(it.wants_join > 0, Join(it, false));
        // Second pass: join player(s) queued for team autoselection
        FOREACH_CLIENT(it.wants_join < 0, Join(it, false));
    }
 
    // after a restart every players number of allowed timeouts gets reset, too
    if (autocvar_sv_timeout)
    {
        FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
    }
 
    if (autocvar_sv_spectate == 2 && !warmup_stage)
    {
        FOREACH_CLIENT(IS_SPEC(it),
        {
            if (it.vote_master)
                ClientData_Touch(it.enemy, true);
            else
            {
                Send_Notification(NOTIF_ONE_ONLY, it, MSG_MULTI, SPECTATE_SPEC_NOTALLOWED);
                TRANSMUTE(Observer, it);
                PutClientInServer(it);
            }
        });
    }
 
    if (!sv_ready_restart_after_countdown || warmup_stage)
        reset_map(is_fake_round_start);
 
    if (autocvar_sv_eventlog) GameLogEcho(":restart");
}

References autocvar_g_campaign, autocvar_sv_eventlog, autocvar_sv_spectate, autocvar_sv_timeout, autocvar_sv_timeout_number, autocvar_teamplay_lockonrestart, autocvar_timelimit, autocvar_timelimit_overtime, checkrules_overtimesadded, checkrules_suddendeathend, checkrules_suddendeathwarning, ClientData_Touch(), CS(), cvar_set(), entity(), FOREACH_CLIENT, ftos(), g_race_qualifying, game_starttime, game_stopped, GameLogEcho(), IS_PLAYER, IS_REAL_CLIENT, IS_SPEC, Join(), localcmd(), lockteams, Nagger_ReadyCounted(), new_pure, NULL, overtimes, PutClientInServer, readycount, ReadyRestart_think(), reset_map(), RESTART_COUNTDOWN, Send_Notification(), setthink, sv_ready_restart_after_countdown, teamplay, time, TRANSMUTE, VoteReset(), and warmup_stage.

Referenced by assault_new_round(), and ReadyRestart().

ReadyRestart_think()

void ReadyRestart_think

(

entity

this

)

Definition at line 433 of file vote.qc.

{
    if (!warmup_stage) // if the countdown was not aborted
        reset_map(false);
    delete(this);
}

References entity(), reset_map(), and warmup_stage.

Referenced by ReadyRestart_force().

reset_map()

void reset_map

(

bool

is_fake_round_start

)

Definition at line 351 of file vote.qc.

{
    if (time <= game_starttime)
    {
        if (game_stopped)
            return;
 
        if (!is_fake_round_start)
        {
            Score_ClearAll();
            PlayerStats_GameReport_Reset_All();
        }
 
        if (round_handler_IsActive())
            round_handler_Reset(game_starttime);
    }
 
    if (shuffleteams_on_reset_map)
    {
        shuffleteams();
        shuffleteams_on_reset_map = false;
    }
 
    FOREACH_CLIENT(true, {
        if (time <= game_starttime)
            accuracy_reset(it); // for spectators too because weapon accuracy is persistent
        if (!IS_PLAYER(it))
            continue;
        player_powerups_remove_all(it, true);
        entity store = PS(it);
        if (store)
        {
            Inventory_clear(store.inventory);
            Inventory_update(store);
        }
    });
 
    MUTATOR_CALLHOOK(reset_map_global);
 
    FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
    {
        if(IS_CLIENT(it))
            continue;
        if (it.reset)
        {
            it.reset(it);
            continue;
        }
        if (it.team_saved) it.team = it.team_saved;
        if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
    });
 
    // Waypoints and assault start come LAST
    FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
        if (it.reset2) it.reset2(it);
    });
 
    // Moving the player reset code here since the player-reset depends
    // on spawnpoint entities which have to be reset first --blub
    if (!MUTATOR_CALLHOOK(reset_map_players))
    {
        FOREACH_CLIENT(IS_PLAYER(it),
        {
            // PlayerScore_Clear(it);
            CS(it).killcount = 0;
            // stop the player from moving so that they stand still once they get respawned
            it.velocity = '0 0 0';
            it.avelocity = '0 0 0';
            CS(it).movement = '0 0 0';
            PutClientInServer(it);
 
            if(IS_BOT_CLIENT(it))
            {
                .entity weaponentity = weaponentities[0];
                if(it.(weaponentity).m_weapon == WEP_Null)
                    W_NextWeapon(it, 0, weaponentity);
            }
        });
    }
}

References accuracy_reset(), CS(), entity(), FL_PROJECTILE, FOREACH_CLIENT, FOREACH_ENTITY_FLOAT_ORDERED, FOREACH_ENTITY_ORDERED, game_starttime, game_stopped, Inventory_clear(), Inventory_update(), IS_BOT_CLIENT, IS_CLIENT, IS_NOT_A_CLIENT, IS_PLAYER, MUTATOR_CALLHOOK, player_powerups_remove_all(), PlayerStats_GameReport_Reset_All(), PS, pure_data, PutClientInServer, round_handler_IsActive, round_handler_Reset(), Score_ClearAll(), shuffleteams(), shuffleteams_on_reset_map, time, W_NextWeapon(), and weaponentities.

Referenced by ReadyRestart_force(), ReadyRestart_think(), and round_handler_Think().

ValidateMap()

string ValidateMap	(	string	validated_map,
		entity	caller )

Definition at line 672 of file vote.qc.

{
    validated_map = MapInfo_FixName(validated_map);
 
    if (!validated_map)
    {
        print_to(caller, "This map is not available on this server.");
        return string_null;
    }
 
    if (!autocvar_sv_vote_override_mostrecent && caller)
    {
        if (Map_IsRecent(validated_map))
        {
            print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
            return string_null;
        }
    }
 
    if (!MapInfo_CheckMap(validated_map))
    {
        print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current gametype."));
        return string_null;
    }
 
    return validated_map;
}

References autocvar_sv_vote_override_mostrecent, entity(), Map_IsRecent(), MapInfo_CheckMap(), MapInfo_FixName(), print_to(), strcat(), and string_null.

Referenced by GameCommand_nextmap(), and VoteCommand_parse().

VoteAccept()

void VoteAccept

(

)

Definition at line 171 of file vote.qc.

{
    bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 
    if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
    else localcmd(strcat(vote_called_command, "\n"));
 
    if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 
    VoteReset(false);
    Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
}

References bprint(), localcmd(), NULL, OriginalCallerName(), Send_Notification(), strcat(), vote_called, vote_called_command, vote_called_display, vote_caller, VOTE_MASTER, and VoteReset().

Referenced by VoteCount().

VoteCommand()

void VoteCommand	(	int	request,
		entity	caller,
		int	argc,
		string	vote_command )

Definition at line 1431 of file vote.qc.

{
    // Guide for working with argc arguments by example:
    // argc:   1    - 2      - 3     - 4
    // argv:   0    - 1      - 2     - 3
    // cmd     vote - master - login - password
 
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (VoteCommand_macro_command(caller, argc, vote_command)) return;
        }
 
        default:
            print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
        case CMD_REQUEST_USAGE:
        {
            VoteCommand_macro_help(caller, argc);
            return;
        }
    }
}

References argv(), CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), print_to(), strcat(), VoteCommand_macro_command(), and VoteCommand_macro_help().

Referenced by COMMON_COMMAND().

VoteCommand_abstain()

void VoteCommand_abstain	(	int	request,
		entity	caller )

Definition at line 940 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
            {
                print_to(caller, "^1You are banned from voting.");
                Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
                return;
            }
 
            if (!vote_called) { print_to(caller, "^1No vote called."); }
            else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
            {
                print_to(caller, "^1You have already voted.");
            }
 
            else  // everything went okay, continue changing vote
            {
                print_to(caller, "^1You abstained from your vote.");
                caller.vote_selection = VOTE_SELECT_ABSTAIN;
                msg_entity = caller;
                if (!autocvar_sv_vote_singlecount)
                    VoteCount(false);
            }
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
            print_to(caller, "  No arguments required.");
            return;
        }
    }
}

References autocvar_g_voteban_list, autocvar_sv_vote_change, autocvar_sv_vote_singlecount, CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), msg_entity, PlayerInList(), print_to(), Send_Notification(), strcat(), vote_called, VOTE_SELECT_ABSTAIN, VOTE_SELECT_NULL, and VoteCount().

VoteCommand_call()

void VoteCommand_call	(	int	request,
		entity	caller,
		int	argc,
		string	vote_command )

Definition at line 986 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            float tmp_playercount = 0;
            int parse_error;
 
            if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
            {
                print_to(caller, "^1You are banned from calling a vote.");
                Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
                return;
            }
 
            vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 
            if (!autocvar_sv_vote_call && caller)
            {
                print_to(caller, "^1Vote calling is not allowed.");
            }
            else if (!autocvar_sv_vote_gamestart && time < game_starttime)
            {
                print_to(caller, "^1Vote calling is not allowed before the match has started.");
            }
            else if (vote_called)
            {
                print_to(caller, "^1There is already a vote called.");
            }
            else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
            {
                print_to(caller, "^1Only players can call a vote.");
            }
            else if (caller && !IS_CLIENT(caller))
            {
                print_to(caller, "^1Only connected clients can vote.");
            }
            else if (timeout_status && vote_command != "timein")
            {
                print_to(caller, "^1You can not call a vote while a timeout is active.");
            }
            else if (caller && (time < caller.vote_waittime))
            {
                print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
            }
            else if (!VoteCommand_checknasty(vote_command))
            {
                print_to(caller, "^1Syntax error in command.");
            }
            else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
            {
                if(parse_error == 0)
                {
                    if (vote_called_command == "")
                        VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
                    else
                        print_to(caller, "^1This command is not acceptable or not available.");
                }
            }
            else  // everything went okay, continue with calling the vote
            {
                vote_caller = caller;  // remember who called the vote
                vote_caller_name = strzone(GetCallerName(vote_caller));
                vote_called = VOTE_NORMAL;
                vote_called_command = strzone(vote_parsed_command);
                vote_called_display = strzone(vote_parsed_display);
                vote_endtime = time + autocvar_sv_vote_timeout;
 
                if (caller)
                {
                    caller.vote_selection = VOTE_SELECT_ACCEPT;
                    caller.vote_waittime = time + autocvar_sv_vote_wait;
                    msg_entity = caller;
                }
 
                FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 
                bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
                if (autocvar_sv_vote_debug)
                    bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
                if (autocvar_sv_eventlog)
                    GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
                Nagger_VoteChanged();
                VoteCount(true);  // needed if you are the only one
 
                if (tmp_playercount > 1 && vote_called != VOTE_NULL)
                    Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
            }
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
            print_to(caller, "  Where <command> is the command to request a vote upon.");
            print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
            print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
            print_available_commands_to(caller);
            print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
            return;
        }
    }
}

References autocvar_g_voteban_list, autocvar_sv_eventlog, autocvar_sv_vote_call, autocvar_sv_vote_commands, autocvar_sv_vote_debug, autocvar_sv_vote_gamestart, autocvar_sv_vote_timeout, autocvar_sv_vote_wait, bprint(), ceil(), CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), FOREACH_CLIENT, ftos(), game_starttime, GameLogEcho(), GetCallerName(), GetCommandPrefix(), IS_CLIENT, IS_PLAYER, IS_REAL_CLIENT, msg_entity, Nagger_VoteChanged(), NULL, OriginalCallerName(), PlayerInList(), print_available_commands_to(), print_to(), Send_Notification(), spectators_allowed, strcat(), strzone(), time, timeout_status, vote_called, vote_called_command, vote_called_display, vote_caller, vote_caller_name, vote_endtime, VOTE_NORMAL, VOTE_NULL, vote_parsed_command, vote_parsed_display, VOTE_SELECT_ACCEPT, VoteCommand_call(), VoteCommand_checknasty(), VoteCommand_extractcommand(), VoteCommand_parse(), and VoteCount().

Referenced by VoteCommand_call().

Votecommand_check_assignment()

bool Votecommand_check_assignment	(	entity	caller,
		float	assignment )

Definition at line 623 of file vote.qc.

{
    bool from_server = (!caller);
 
    if ((assignment == VC_ASGNMNT_BOTH)
        || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
        || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 
    return false;
}

References entity(), VC_ASGNMNT_BOTH, VC_ASGNMNT_CLIENTONLY, and VC_ASGNMNT_SERVERONLY.

VoteCommand_checkargs()

float VoteCommand_checkargs	(	float	startpos,
		int	argc )

Definition at line 700 of file vote.qc.

{
    float p, q, check, minargs;
    string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
    string cmdrestriction = "";  // No we don't.
    string charlist, arg;
    float checkmate;
 
    if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
        cmdrestriction = cvar_string(cvarname);
    else
        LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 
    if (cmdrestriction == "") return true;
 
    ++startpos;  // skip command name
 
    // check minimum arg count
 
    // 0 args: argc == startpos
    // 1 args: argc == startpos + 1
    // ...
 
    minargs = stof(cmdrestriction);
    if (argc - startpos < minargs) return false;
 
    p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 
    for ( ; ; )
    {
        // we know that at any time, startpos <= argc - minargs
        // so this means: argc-minargs >= startpos >= argc, thus
        // argc-minargs >= argc, thus minargs <= 0, thus all minargs
        // have been seen already
 
        if (startpos >= argc) // all args checked? GOOD
            break;
 
        if (p < 0)            // no more args? FAIL
        {
            // exception: exactly minargs left, this one included
            if (argc - startpos == minargs) break;
 
            // otherwise fail
            return false;
        }
 
        // cut to next semicolon
        q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
        if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
        else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 
        // in case we ever want to allow semicolons in VoteCommand_checknasty
        // charlist = strreplace("^^", ";", charlist);
 
        if (charlist != "")
        {
            // verify the arg only contains allowed chars
            arg = argv(startpos);
            checkmate = strlen(arg);
            for (check = 0; check < checkmate; ++check)
                if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
            // not allowed character
            // all characters are allowed. FINE.
        }
 
        ++startpos;
        --minargs;
        p = q;
    }
 
    return true;
}

References argv(), cvar_string(), CVAR_TYPEFLAG_EXISTS, LOG_INFO, stof(), strcat(), strlen, strstrofs, and substring().

Referenced by VoteCommand_parse().

VoteCommand_checkinlist()

bool VoteCommand_checkinlist	(	string	vote_command,
		string	list )

Definition at line 663 of file vote.qc.

{
    if (vote_command == "" || list == "")
        return false;
 
    string l = VoteCommand_checkreplacements(list);
    return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
}

References strstrofs, and VoteCommand_checkreplacements().

Referenced by VoteCommand_parse().

VoteCommand_checknasty()

bool VoteCommand_checknasty

(

string

vote_command

)

Definition at line 644 of file vote.qc.

{
    return !((strstrofs(vote_command, ";", 0) >= 0)
        || (strstrofs(vote_command, "\n", 0) >= 0)
        || (strstrofs(vote_command, "\r", 0) >= 0)
        || (strstrofs(vote_command, "$", 0) >= 0));
}

References strstrofs.

Referenced by VoteCommand_call(), and VoteCommand_master().

VoteCommand_checkreplacements()

string VoteCommand_checkreplacements

(

string

input

)

Definition at line 653 of file vote.qc.

{
    // add a space around the input so the start and end of the list is captured
    string output = strcat(" ", input, " ");
    // allow gotomap replacements
    output = strreplace(" map ", " gotomap ", output);
    output = strreplace(" chmap ", " gotomap ", output);
    return output;
}

References strcat().

Referenced by VoteCommand_checkinlist().

VoteCommand_extractcommand()

string VoteCommand_extractcommand	(	string	input,
		float	startpos,
		int	argc )

Definition at line 634 of file vote.qc.

{
    string output;
 
    if ((argc - 1) < startpos) output = "";
    else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 
    return output;
}

References argv_end_index, argv_start_index, and substring().

Referenced by VoteCommand_call(), and VoteCommand_master().

VoteCommand_macro_command()

float VoteCommand_macro_command	(	entity	caller,
		int	argc,
		string	vote_command )

Definition at line 1415 of file vote.qc.

{
    #define VOTE_COMMAND(name, function, description, assignment) \
        { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
 
    VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
    #undef VOTE_COMMAND
 
    return false;
}

References CMD_REQUEST_COMMAND, entity(), and VOTE_COMMANDS.

Referenced by VoteCommand().

VoteCommand_macro_help()

void VoteCommand_macro_help	(	entity	caller,
		int	argc )

Definition at line 1382 of file vote.qc.

{
    string command_origin = GetCommandPrefix(caller);
 
    if (argc == 2 || argv(2) == "help")  // help display listing all commands
    {
        print_to(caller, "\nVoting commands:\n");
        #define VOTE_COMMAND(name, function, description, assignment) \
            { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
 
        VOTE_COMMANDS(0, caller, 0, "");
        #undef VOTE_COMMAND
 
        print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
        print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
        print_available_commands_to(caller);
    }
    else  // usage for individual command
    {
        #define VOTE_COMMAND(name, function, description, assignment) \
            { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
 
        VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
        #undef VOTE_COMMAND
 
        string cvarname = strcat("sv_vote_command_help_", argv(2));
        if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
            wordwrap_sprint(caller, cvar_string(cvarname), 1000);
        else if (argv(2) != "")
            print_to(caller, "No documentation exists for this vote");
    }
}

References argv(), CMD_REQUEST_USAGE, cvar_string(), CVAR_TYPEFLAG_EXISTS, entity(), GetCommandPrefix(), print_available_commands_to(), print_to(), strcat(), VOTE_COMMANDS, and wordwrap_sprint().

Referenced by VoteCommand().

VoteCommand_master()

void VoteCommand_master	(	int	request,
		entity	caller,
		int	argc,
		string	vote_command )

Definition at line 1093 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (autocvar_sv_vote_master)
            {
                switch (strtolower(argv(2)))
                {
                    case "do":
                    {
                        int parse_error;
                        vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 
                        if (!caller.vote_master)
                            print_to(caller, "^1You do not have vote master privileges.");
                        else if (!VoteCommand_checknasty(vote_command))
                        {
                            print_to(caller, "^1Syntax error in command.");
                        }
                        else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
                        {
                            if(parse_error == 0)
                            {
                                if (vote_called_command == "")
                                    VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
                                else
                                    print_to(caller, "^1This command is not acceptable or not available.");
                            }
                        }
                        else  // everything went okay, proceed with command
                        {
                            localcmd(strcat(vote_parsed_command, "\n"));
                            print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
                            bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
                            if (autocvar_sv_eventlog)
                                GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
                        }
 
                        return;
                    }
 
                    case "login":
                    {
                        if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
                        else if (caller.vote_master)
                        {
                            print_to(caller, "^1You are already logged in as vote master.");
                        }
                        else if (autocvar_sv_vote_master_password != argv(3))
                        {
                            print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
                        }
                        else  // everything went okay, proceed with giving this player master privilages
                        {
                            caller.vote_master = true;
                            print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
                            bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
                            if (autocvar_sv_eventlog)
                                GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
                        }
 
                        return;
                    }
 
                    default:  // calling a vote for master
                    {
                        if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
                        else if (vote_called)
                        {
                            print_to(caller, "^1There is already a vote called.");
                        }
                        else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
                        {
                            print_to(caller, "^1Only players can call a vote.");
                        }
                        else if (timeout_status)
                        {
                            print_to(caller, "^1You can not call a vote while a timeout is active.");
                        }
                        else  // everything went okay, continue with creating vote
                        {
                            vote_caller = caller;
                            vote_caller_name = strzone(GetCallerName(vote_caller));
                            vote_called = VOTE_MASTER;
                            vote_called_command = strzone("XXX");
                            vote_called_display = strzone("^3master");
                            vote_endtime = time + autocvar_sv_vote_timeout;
 
                            caller.vote_selection = VOTE_SELECT_ACCEPT;
                            caller.vote_waittime = time + autocvar_sv_vote_wait;
 
                            bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
                            if (autocvar_sv_eventlog)
                                GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
                            Nagger_VoteChanged();
                            VoteCount(true);  // needed if you are the only one
                        }
 
                        return;
                    }
                }
            }
            else { print_to(caller, "^1Master control of voting is not allowed."); }
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
            print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
            print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
            return;
        }
    }
}

References argv(), autocvar_sv_eventlog, autocvar_sv_vote_commands, autocvar_sv_vote_master, autocvar_sv_vote_master_callable, autocvar_sv_vote_master_commands, autocvar_sv_vote_master_password, autocvar_sv_vote_timeout, autocvar_sv_vote_wait, bprint(), CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), ftos(), GameLogEcho(), GetCallerName(), GetCommandPrefix(), IS_PLAYER, localcmd(), Nagger_VoteChanged(), OriginalCallerName(), print_to(), spectators_allowed, strcat(), strtolower(), strzone(), time, timeout_status, vote_called, vote_called_command, vote_called_display, vote_caller, vote_caller_name, vote_endtime, VOTE_MASTER, vote_parsed_command, vote_parsed_display, VOTE_SELECT_ACCEPT, VoteCommand_checknasty(), VoteCommand_extractcommand(), VoteCommand_master(), VoteCommand_parse(), and VoteCount().

Referenced by VoteCommand_master().

VoteCommand_no()

void VoteCommand_no	(	int	request,
		entity	caller )

Definition at line 1213 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
            {
                print_to(caller, "^1You are banned from voting.");
                Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
                return;
            }
 
            if (!vote_called) { print_to(caller, "^1No vote called."); }
            else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
            {
                print_to(caller, "^1You have already voted.");
            }
            else if (caller == vote_caller && autocvar_sv_vote_no_stops_vote)
            {
                VoteStop(caller, false);
            }
 
            else  // everything went okay, continue changing vote
            {
                print_to(caller, "^1You rejected the vote.");
                caller.vote_selection = VOTE_SELECT_REJECT;
                msg_entity = caller;
                if (!autocvar_sv_vote_singlecount)
                    VoteCount(false);
            }
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
            print_to(caller, "  No arguments required.");
            return;
        }
    }
}

References autocvar_g_voteban_list, autocvar_sv_vote_change, autocvar_sv_vote_no_stops_vote, autocvar_sv_vote_singlecount, CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), msg_entity, PlayerInList(), print_to(), Send_Notification(), strcat(), vote_called, vote_caller, VOTE_SELECT_NULL, VOTE_SELECT_REJECT, VoteCount(), and VoteStop().

VoteCommand_parse()

int VoteCommand_parse	(	entity	caller,
		string	vote_command,
		string	vote_list,
		float	startpos,
		int	argc )

Definition at line 774 of file vote.qc.

{
    string first_command = argv(startpos);
    int missing_chars = argv_start_index(startpos);
 
    if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
        return 0;
 
    if (caller && !VoteCommand_checkinlist(first_command, vote_list)) return 0;
 
    if (!VoteCommand_checkargs(startpos, argc)) return 0;
 
    switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
    {
        case MUT_VOTEPARSE_CONTINUE: { break; }
        case MUT_VOTEPARSE_SUCCESS: { return 1; }
        case MUT_VOTEPARSE_INVALID: { return -1; }
        case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
    }
 
    switch (first_command) // now go through and parse the proper commands to adjust as needed.
    {
        case "movetoauto":
        case "movetored":
        case "movetoblue":
        case "movetoyellow":
        case "movetopink":
        case "movetospec":
        {
            entity victim = GetIndexedEntity(argc, (startpos + 1));
            float accepted = VerifyClientEntity(victim, true, false);
            if (accepted > 0)
            {
                vote_parsed_command = vote_command;
                vote_parsed_display = sprintf("^1%s #%d ^7%s", first_command, etof(victim), victim.netname);
            }
            else
            {
                print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
                return 0;
            }
 
            break;
        }
 
        case "kick":
        case "kickban":    // catch all kick/kickban commands
        {
            entity victim = GetIndexedEntity(argc, (startpos + 1));
            float accepted = VerifyClientEntity(victim, true, false);
 
            if (accepted > 0)
            {
                string reason = "No reason provided";
                if(argc > next_token)
                    reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 
                string command_arguments = reason;
                if (first_command == "kickban")
                    command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 
                vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
                vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
            }
            else
            {
                print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
                return 0;
            }
 
            break;
        }
 
        case "map":
        case "chmap":
        case "gotomap":  // re-direct all map selection commands to gotomap
        {
            vote_command = ValidateMap(argv(startpos + 1), caller);
            if (!vote_command)  return -1;
            vote_parsed_command = strcat("gotomap ", vote_command);
            vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 
            break;
        }
 
        // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
        // maybe fallback instead of aborting if map name is invalid?
        case "nextmap":
        {
            vote_command = ValidateMap(argv(startpos + 1), caller);
            if (!vote_command)  return -1;
            vote_parsed_command = strcat("nextmap ", vote_command);
            vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 
            break;
        }
 
        case "fraglimit": // include restrictions on the maximum votable frag limit
        {
            float fraglimit_vote = stof(argv(startpos + 1));
            float fraglimit_min = 0;
            float fraglimit_max = 999999;
            if(fraglimit_vote > fraglimit_max || fraglimit_vote < fraglimit_min)
            {
                print_to(caller, strcat("Invalid fraglimit vote, accepted values are between ", ftos(fraglimit_min), " and ", ftos(fraglimit_max), "."));
                return -1;
            }
            vote_parsed_command = strcat("fraglimit ", ftos(fraglimit_vote));
            vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 
            break;
        }
 
        case "timelimit": // include restrictions on the maximum votable time limit
        {
            float timelimit_vote = stof(argv(startpos + 1));
            if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
            {
                print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
                return -1;
            }
            vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
            vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 
            break;
        }
 
        case "restart":
        {
            // add a delay so that vote result can be seen and announcer can be heard
            // if the vote is accepted
            vote_parsed_command = strcat("defer 1 ", vote_command);
            vote_parsed_display = strzone(strcat("^1", vote_command));
 
            break;
        }
 
        case "allready":
        {
            if(!warmup_stage) {
                print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
                return -1;
            }
 
            vote_parsed_command = vote_command;
            vote_parsed_display = strzone(strcat("^1", vote_command));
            break;
        }
 
        default:
        {
            vote_parsed_command = vote_command;
            vote_parsed_display = strzone(strcat("^1", vote_command));
 
            break;
        }
    }
 
    return 1;
}

References argv(), argv_start_index, autocvar_g_ban_default_bantime, autocvar_g_ban_default_masksize, autocvar_sv_vote_limit, autocvar_timelimit_max, autocvar_timelimit_min, entity(), etof, ftos(), GetClientErrorString, GetIndexedEntity(), MUT_VOTEPARSE_CONTINUE, MUT_VOTEPARSE_INVALID, MUT_VOTEPARSE_SUCCESS, MUT_VOTEPARSE_UNACCEPTABLE, MUTATOR_CALLHOOK, next_token, print_to(), stof(), strcat(), strlen, strzone(), substring(), ValidateMap(), VerifyClientEntity(), vote_parsed_command, vote_parsed_display, VoteCommand_checkargs(), VoteCommand_checkinlist(), and warmup_stage.

Referenced by VoteCommand_call(), and VoteCommand_master().

VoteCommand_status()

void VoteCommand_status	(	int	request,
		entity	caller )

Definition at line 1258 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
            else print_to(caller, "^1No vote called.");
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
            print_to(caller, "  No arguments required.");
            return;
        }
    }
}

References CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), OriginalCallerName(), print_to(), strcat(), vote_called, and vote_called_display.

VoteCommand_stop()

void VoteCommand_stop	(	int	request,
		entity	caller )

Definition at line 1280 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (!vote_called)   print_to(caller, "^1No vote called.");
            else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
            else   print_to(caller, "^1You are not allowed to stop that vote.");
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
            print_to(caller, "  No arguments required.");
            return;
        }
    }
}

References CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), print_to(), strcat(), vote_called, vote_caller, and VoteStop().

VoteCommand_yes()

void VoteCommand_yes	(	int	request,
		entity	caller )

Definition at line 1302 of file vote.qc.

{
    switch (request)
    {
        case CMD_REQUEST_COMMAND:
        {
            if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
            {
                print_to(caller, "^1You are banned from voting.");
                Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
                return;
            }
 
            if (!vote_called) { print_to(caller, "^1No vote called."); }
            else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
            {
                print_to(caller, "^1You have already voted.");
            }
            else  // everything went okay, continue changing vote
            {
                print_to(caller, "^1You accepted the vote.");
                caller.vote_selection = VOTE_SELECT_ACCEPT;
                msg_entity = caller;
                if (!autocvar_sv_vote_singlecount)
                    VoteCount(false);
            }
 
            return;
        }
 
        default:
        case CMD_REQUEST_USAGE:
        {
            print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
            print_to(caller, "  No arguments required.");
            return;
        }
    }
}

References autocvar_g_voteban_list, autocvar_sv_vote_change, autocvar_sv_vote_singlecount, CMD_REQUEST_COMMAND, CMD_REQUEST_USAGE, entity(), GetCommandPrefix(), msg_entity, PlayerInList(), print_to(), Send_Notification(), strcat(), vote_called, VOTE_SELECT_ACCEPT, VOTE_SELECT_NULL, and VoteCount().

VoteCount()

void VoteCount

(

float

first_count

)

Definition at line 220 of file vote.qc.

{
    vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 
    float vote_player_count = 0, notvoters = 0;
    float vote_real_player_count = 0, vote_real_accept_count = 0;
    float vote_real_reject_count = 0, vote_real_abstain_count = 0;
    float vote_needed_of_voted, final_needed_votes;
    float vote_factor_overall, vote_factor_of_voted;
 
    Nagger_VoteCountChanged();
 
    // add up all the votes from each connected client
    FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_vote_debug, {
        ++vote_player_count;
        if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
        switch (it.vote_selection)
        {
            case VOTE_SELECT_REJECT:
                ++vote_reject_count;
                if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
                break;
            case VOTE_SELECT_ACCEPT:
                ++vote_accept_count;
                if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
                break;
            case VOTE_SELECT_ABSTAIN:
                ++vote_abstain_count;
                if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
                break;
            default: break;
        }
    });
 
    // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
    if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
    {
        if (vote_caller)   vote_caller.vote_waittime = 0;
        print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
        VoteReset(false);
        return;
    }
 
    // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
    if (!spectators_allowed && (vote_real_player_count > 0))
    {
        vote_accept_count = vote_real_accept_count;
        vote_reject_count = vote_real_reject_count;
        vote_abstain_count = vote_real_abstain_count;
        vote_player_count = vote_real_player_count;
    }
 
    // people who have no opinion in any way :D
    notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 
    // determine the goal for the vote to be passed or rejected normally
    vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
    vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 
    // if the vote times out, determine the amount of votes needed of the people who actually already voted
    vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
    vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 
    // are there any players at all on the server? it could be an admin vote
    if (vote_player_count == 0 && first_count)
    {
        VoteSpam(0, -1, "yes");  // no players at all, just accept it
        VoteAccept();
        return;
    }
 
    // since there ARE players, finally calculate the result of the vote
    if (vote_accept_count >= vote_needed_overall)
    {
        VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
        VoteAccept();
        return;
    }
 
    if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
    {
        VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
        VoteReject();
        return;
    }
 
    // there is not enough votes in either direction, now lets just calculate what the voters have said
    if (time > vote_endtime)
    {
        final_needed_votes = vote_needed_overall;
 
        if (autocvar_sv_vote_majority_factor_of_voted)
        {
            if (vote_accept_count >= vote_needed_of_voted)
            {
                VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
                VoteAccept();
                return;
            }
 
            if (vote_accept_count + vote_reject_count > 0)
            {
                VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
                VoteReject();
                return;
            }
 
            final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
        }
 
        // it didn't pass or fail, so not enough votes to even make a decision.
        VoteSpam(notvoters, final_needed_votes, "timeout");
        VoteTimeout();
    }
}

References autocvar_sv_vote_debug, autocvar_sv_vote_majority_factor, autocvar_sv_vote_majority_factor_of_voted, autocvar_sv_vote_master_playerlimit, bound(), floor(), FOREACH_CLIENT, INGAME, IS_PLAYER, IS_REAL_CLIENT, min(), Nagger_VoteCountChanged(), print_to(), spectators_allowed, time, vote_abstain_count, vote_accept_count, vote_called, vote_caller, vote_endtime, VOTE_MASTER, vote_needed_overall, vote_reject_count, VOTE_SELECT_ABSTAIN, VOTE_SELECT_ACCEPT, VOTE_SELECT_REJECT, VoteAccept(), VoteReject(), VoteReset(), VoteSpam(), and VoteTimeout().

Referenced by ClientDisconnect(), PutObserverInServer(), VoteCommand_abstain(), VoteCommand_call(), VoteCommand_master(), VoteCommand_no(), VoteCommand_yes(), and VoteThink().

VoteReject()

void VoteReject

(

)

Definition at line 184 of file vote.qc.

{
    bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
    VoteReset(false);
    Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
}

References bprint(), NULL, OriginalCallerName(), Send_Notification(), vote_called_display, and VoteReset().

Referenced by VoteCount().

VoteReset()

void VoteReset

(

bool

verbose

)

Definition at line 129 of file vote.qc.

{
    if (verbose && vote_called)
    {
        VoteStop(NULL, true);
        return;
    }
 
    FOREACH_CLIENT(true, { it.vote_selection = 0; });
 
    if (vote_called)
    {
        strfree(vote_called_command);
        strfree(vote_called_display);
        strfree(vote_caller_name);
    }
 
    vote_called = VOTE_NULL;
    vote_caller = NULL;
    vote_endtime = 0;
 
    vote_parsed_command = string_null;
    vote_parsed_display = string_null;
 
    Nagger_VoteChanged();
}

References FOREACH_CLIENT, Nagger_VoteChanged(), NULL, strfree, string_null, vote_called, vote_called_command, vote_called_display, vote_caller, vote_caller_name, vote_endtime, VOTE_NULL, vote_parsed_command, vote_parsed_display, and VoteStop().

Referenced by InitGameplayMode(), NextLevel(), ReadyRestart_force(), VoteAccept(), VoteCount(), VoteReject(), VoteStop(), and VoteTimeout().

VoteSpam()

void VoteSpam	(	float	notvoters,
		float	mincount,
		string	result )

Definition at line 198 of file vote.qc.

{
    bprint(strcat(
        strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
        strcat("^2:^1", ftos(vote_reject_count)),
        ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
        strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
        strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 
    if (autocvar_sv_eventlog)
    {
        GameLogEcho(strcat(
            strcat(":vote:v", result, ":", ftos(vote_accept_count)),
            strcat(":", ftos(vote_reject_count)),
            strcat(":", ftos(vote_abstain_count)),
            strcat(":", ftos(notvoters)),
            strcat(":", ftos(mincount))));
    }
}

References autocvar_sv_eventlog, bprint(), ftos(), GameLogEcho(), result, strcat(), vote_abstain_count, vote_accept_count, and vote_reject_count.

Referenced by VoteCount().

VoteStop()

void VoteStop	(	entity	stopper,
		bool	show_name )

Definition at line 156 of file vote.qc.

{
    if (canceled) // Code such as NextLevel() stopped it, not a direct action by a human.
        bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
    else if (stopper == vote_caller)
        bprint("\{1}^2* ^3", OriginalCallerName(), "^2 stopped their vote\n");
    else
        bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 
    if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
    // Don't force them to wait for next vote, this way they can e.g. correct their vote.
    if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
    VoteReset(false);
}

References autocvar_sv_eventlog, autocvar_sv_vote_stop, bprint(), entity(), ftos(), GameLogEcho(), GetCallerName(), OriginalCallerName(), strcat(), time, vote_caller, and VoteReset().

Referenced by VoteCommand_no(), VoteCommand_stop(), and VoteReset().

VoteThink()

void VoteThink

(

)

Definition at line 336 of file vote.qc.

{
    if (vote_endtime > 0)        // a vote was called
    {
        if (time > vote_endtime) // time is up
            VoteCount(false);
    }
}

References time, vote_endtime, and VoteCount().

Referenced by CheckRules_World().

VoteTimeout()

void VoteTimeout

(

)

Definition at line 191 of file vote.qc.

{
    bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
    VoteReset(false);
    Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
}

References bprint(), NULL, OriginalCallerName(), Send_Notification(), vote_called_display, and VoteReset().

Referenced by VoteCount().