#include <common/mutators/base.qh>
#include <common/scores.qh>

Include dependency graph for sv_keepaway.qh:

This graph shows which files directly or indirectly include this file:

Functions
void	ka_DamageEvent (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	ka_DropEvent (entity plyr)
void	ka_Handler_CheckBall (entity this)
void	ka_TouchEvent (entity this, entity toucher)
	REGISTER_MUTATOR (ka, false)
	void (entity this) havocbot_role_ka_carrier

Variables
IntrusiveList	g_kaballs

Function Documentation

◆ ka_DamageEvent()

void ka_DamageEvent	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 108 of file sv_keepaway.qc.

{
    if(ITEM_DAMAGE_NEEDKILL(deathtype))
        ka_RespawnBall(this);
}

References entity(), ITEM_DAMAGE_NEEDKILL, ka_RespawnBall(), and vector.

Referenced by ka_DropEvent(), and ka_SpawnBalls().

◆ ka_DropEvent()

void ka_DropEvent ( entity plyr )

Definition at line 191 of file sv_keepaway.qc.

{
    entity ball = player.ballcarried;
 
    if(!ball) { return; }
 
    // reset the ball
    setattachment(ball, NULL, "");
    set_movetype(ball, MOVETYPE_BOUNCE);
    ball.previous_owner = player;
    ball.wait = time + 0.5; // same as for thrown weapons
    setthink(ball, ka_RespawnBall);
    ball.nextthink = time + autocvar_g_keepawayball_respawntime;
    ball.takedamage = DAMAGE_YES;
    ball.event_damage = ka_DamageEvent;
    ball.damagedbycontents = true;
    IL_PUSH(g_damagedbycontents, ball);
    ball.scale = 1; // it's smaller while carried
    ball.alpha = 1; // in case the carrier had an invisibility effect
    ball.solid = SOLID_TRIGGER; // before setorigin to ensure area grid linking
    setorigin(ball, player.origin + ball.origin + '0 0 10'); // include attachment offset to reduce jump
    nudgeoutofsolid_OrFallback(ball); // a ball has a horizontally bigger bbox than a player
    ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
    ball.owner = NULL;
    navigation_dynamicgoal_set(ball, player);
 
    // messages and sounds
    ka_EventLog("dropped", player);
    Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, player.netname);
    Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, player.netname);
    sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 
    // waypoints
    if(autocvar_g_keepawayball_tracking || warmup_stage)
    {
        WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
        WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
        WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
    }
 
    if (ball.ballcarried) // >1 ball was chained, first one was just dropped
    {
        player.ballcarried = ball.ballcarried; // move the next one up
        ball.ballcarried = NULL; // prevent infinite loop
    }
    else // no balls remaining so remove bc status
        ka_PlayerReset(player);
}

References ATTEN_NONE, autocvar_g_keepawayball_respawntime, autocvar_g_keepawayball_tracking, CH_TRIGGER, crandom, DAMAGE_YES, entity(), g_damagedbycontents, IL_PUSH(), ka_DamageEvent(), ka_EventLog(), ka_PlayerReset(), ka_RespawnBall(), MOVETYPE_BOUNCE, navigation_dynamicgoal_set(), NULL, Send_Notification(), set_movetype(), setthink, SOLID_TRIGGER, sound, SPRITERULE_DEFAULT, time, VOL_BASE, warmup_stage, waypointsprite_attachedforcarrier, WaypointSprite_Ping(), WaypointSprite_Spawn(), and WaypointSprite_UpdateRule().

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

◆ ka_Handler_CheckBall()

void ka_Handler_CheckBall ( entity this )

Definition at line 291 of file sv_keepaway.qc.

{
    if(time < game_starttime)
    {
        if (!IL_EMPTY(g_kaballs))
            ka_RemoveBalls();
    }
    else
    {
        if (IL_EMPTY(g_kaballs))
            ka_SpawnBalls(); // ;)
    }
 
    this.nextthink = time;
}

References entity(), g_kaballs, game_starttime, IL_EMPTY, ka_RemoveBalls(), ka_SpawnBalls(), nextthink, and time.

Referenced by REGISTER_MUTATOR().

◆ ka_TouchEvent()

void ka_TouchEvent	(	entity	this,
		entity	toucher )

Definition at line 114 of file sv_keepaway.qc.

{
    if (!this || game_stopped)
        return;
 
    if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
    { // The ball fell off the map, respawn it since players can't get to it
        ka_RespawnBall(this);
        return;
    }
    // TODO: mutator hook to prevent picking up objectives
    if(IS_INDEPENDENT_PLAYER(toucher)) { return; }
    if(IS_DEAD(toucher)) { return; }
    if (!IS_PLAYER(toucher))
    {  // The ball just touched an object, most likely the world
        Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
        sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
        return;
    }
    else if(this.wait > time && this.previous_owner == toucher)
        return;
 
    if (toucher.ballcarried) // multiple balls exist
    {
        if (toucher.ballcarried.cnt >= autocvar_g_keepaway_ballcarrier_maxballs)
            return;
        this.ballcarried = toucher.ballcarried; // new ball will be inserted at start of chain
        this.cnt = toucher.ballcarried.cnt + 1; // for orbit animation offset
    }
    else
        this.cnt = 1;
 
    // attach the ball to the player
    this.owner = toucher;
    toucher.ballcarried = this;
    GameRules_scoring_vip(toucher, true);
    setattachment(this, toucher, "");
    this.solid = SOLID_NOT; // before setorigin to ensure area grid unlinking
    setorigin(this, '0 0 0');
 
    // make the ball unable to do anything, set up time scoring
    this.velocity = '0 0 0';
    set_movetype(this, MOVETYPE_NONE);
    this.scale = 12/16; // somewhat smaller while carried
    setthink(this, ka_BallThink_Carried);
    this.nextthink = time;
    this.takedamage = DAMAGE_NO;
    this.event_damage = func_null;
    this.damagedbycontents = false;
    IL_REMOVE(g_damagedbycontents, this);
    navigation_dynamicgoal_unset(this);
 
    // messages and sounds
    ka_EventLog("pickup", toucher);
    Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
    Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
    Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
    sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 
    // scoring
    GameRules_scoring_add(toucher, KEEPAWAY_PICKUPS, 1);
 
    // waypoints
    WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
    toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
    WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
    WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
    WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
}

References ATTEN_NONE, ATTEN_NORM, autocvar_g_keepaway_ballcarrier_maxballs, ballcarried, CH_TRIGGER, cnt, DAMAGE_NO, damagedbycontents, entity(), func_null(), g_damagedbycontents, game_stopped, GameRules_scoring_add, GameRules_scoring_vip, IL_REMOVE(), IS_DEAD, IS_INDEPENDENT_PLAYER, IS_PLAYER, ka_ballcarrier_waypointsprite_visible_for_player(), ka_BallThink_Carried(), ka_EventLog(), ka_RespawnBall(), MOVETYPE_NONE, navigation_dynamicgoal_unset(), nextthink, NULL, origin, owner, previous_owner, Q3SURFACEFLAG_NOIMPACT, scale, Send_Effect(), Send_Notification(), set_movetype(), setthink, solid, SOLID_NOT, sound, SPRITERULE_DEFAULT, takedamage, time, toucher, trace_dphitq3surfaceflags, velocity, VOL_BASE, wait, WaypointSprite_AttachCarrier(), waypointsprite_attachedforcarrier, WaypointSprite_Kill(), WaypointSprite_Ping(), and WaypointSprite_UpdateRule().

Referenced by ka_SpawnBalls().

◆ REGISTER_MUTATOR()

REGISTER_MUTATOR	(	ka	,
		false	)

Definition at line 9 of file sv_keepaway.qh.

{
    MUTATOR_STATIC();
    MUTATOR_ONADD
    {
        GameRules_scoring(0, SFL_SORT_PRIO_PRIMARY, 0,
        {
            field(SP_KEEPAWAY_PICKUPS, "pickups", 0);
            field(SP_KEEPAWAY_CARRIERKILLS, "bckills", 0);
            field(SP_KEEPAWAY_BCTIME, "bctime", SFL_SORT_PRIO_SECONDARY);
        });
 
        g_kaballs = IL_NEW();
        entity ka_Handler = new_pure(ka_Handler);
        setthink(ka_Handler, ka_Handler_CheckBall);
        InitializeEntity(ka_Handler, ka_Handler_CheckBall, INITPRIO_SETLOCATION);
    }
    return false;
}