This graph shows which files directly or indirectly include this file:

Functions
vector	CSQCModel_ApplyStairSmoothing (entity this, bool isonground, vector v)
float	CSQCPlayer_IsLocalPlayer (entity this)
float	CSQCPlayer_PostUpdate (entity this)
float	CSQCPlayer_PreUpdate (entity this)
void	CSQCPlayer_SetCamera ()
	Called once per CSQC_UpdateView()

Variables
bool	autocvar_cl_movement = true
entity	csqcplayer
float	csqcplayer_status
const int	CSQCPLAYERSTATUS_FROMSERVER = 1
const int	CSQCPLAYERSTATUS_PREDICTED = 2
const int	CSQCPLAYERSTATUS_UNPREDICTED = 0
const int	PMF_JUMP_HELD = 1
int	pmove_flags
bool	use_engine_refdef

Function Documentation

◆ CSQCModel_ApplyStairSmoothing()

vector CSQCModel_ApplyStairSmoothing	(	entity	this,
		bool	isonground,
		vector	v )

Definition at line 248 of file cl_player.qc.

{
    float smoothtime = bound(0, time - this.stairsmooth_prevtime, 0.1);
    this.stairsmooth_prevtime = max(this.stairsmooth_prevtime, this.stairsmooth_drawtime); // stairsmooth_drawtime is the previous frame's time at this point
 
    if(this.csqcmodel_teleported || !isonground || autocvar_cl_stairsmoothspeed <= 0 || this.ground_networkentity)
        this.stairsmooth_offset = v.z;
    else
    {
        if(this.stairsmooth_offset < v.z)
            v.z = this.stairsmooth_offset = bound(v.z - PHYS_STEPHEIGHT(this), this.stairsmooth_offset + smoothtime * autocvar_cl_stairsmoothspeed, v.z);
        else if(this.stairsmooth_offset > v.z)
            v.z = this.stairsmooth_offset = bound(v.z, this.stairsmooth_offset - smoothtime * autocvar_cl_stairsmoothspeed, v.z + PHYS_STEPHEIGHT(this));
    }
 
    this.stairsmooth_prevtime = time;
    this.stairsmooth_drawtime = drawtime;
 
    return v;
}

References autocvar_cl_stairsmoothspeed, bound(), csqcmodel_teleported, drawtime, entity(), ground_networkentity, max(), PHYS_STEPHEIGHT, stairsmooth_drawtime, stairsmooth_offset, stairsmooth_prevtime, time, and vector.

Referenced by CSQCModel_Hook_PreDraw(), and CSQCPlayer_SetCamera().

◆ CSQCPlayer_IsLocalPlayer()

float CSQCPlayer_IsLocalPlayer ( entity this )

Definition at line 210 of file cl_player.qc.

{
    return (this == csqcplayer);
}

References csqcplayer, and entity().

Referenced by CSQCModel_Draw().

◆ CSQCPlayer_PostUpdate()

float CSQCPlayer_PostUpdate ( entity this )

Definition at line 680 of file cl_player.qc.

{
    if (this.entnum != player_localnum + 1) return false;
    csqcplayer = this;
    csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
    if (cvar("cl_movement_replay"))
        cvar_settemp("cl_movement_replay", "0");
    this.entremove = CSQCPlayer_Remove;
    return true;
}

References csqcplayer, CSQCPlayer_Remove(), csqcplayer_status, CSQCPLAYERSTATUS_FROMSERVER, cvar(), cvar_settemp(), entity(), entnum, and player_localnum.

Referenced by NET_HANDLE().

◆ CSQCPlayer_PreUpdate()

float CSQCPlayer_PreUpdate ( entity this )

Definition at line 673 of file cl_player.qc.

{
    if (this != csqcplayer) return false;
    if (csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER) CSQCPlayer_Unpredict(this);
    return true;
}

References csqcplayer, csqcplayer_status, CSQCPlayer_Unpredict(), CSQCPLAYERSTATUS_FROMSERVER, and entity().

Referenced by NET_HANDLE().

◆ CSQCPlayer_SetCamera()

void CSQCPlayer_SetCamera ( )

Called once per CSQC_UpdateView()

Definition at line 573 of file cl_player.qc.

{
    vector v0 = ((intermission && !autocvar_cl_movement_intermissionrunning) ? '0 0 0' : pmove_vel); // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
    float vh = PHYS_VIEWHEIGHT(NULL);
    vector pl_viewofs = PHYS_PL_VIEWOFS(NULL);
    vector pl_viewofs_crouch = PHYS_PL_CROUCH_VIEWOFS(NULL);
    entity e = csqcplayer;
    if (e)
    {
        if (servercommandframe == 0 || clientcommandframe == 0)
        {
            InterpolateOrigin_Do(e);
            e.view_ofs = '0 0 1' * vh;
 
            // get crouch state from the server
            if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
            else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 
            // get onground state from the server
            e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 
            CSQCPlayer_SetMinsMaxs(e);
 
            // override it back just in case
            e.view_ofs = '0 0 1' * vh;
 
            // set velocity
            e.velocity = v0;
        }
        else
        {
            int flg = e.iflags; e.iflags &= ~(IFLAG_ORIGIN | IFLAG_ANGLES);
            InterpolateOrigin_Do(e);
            e.iflags = flg;
 
            if (csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
            {
                vector o = e.origin;
                csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
                CSQCPlayer_PredictTo(e, servercommandframe + 1, false);
                CSQCPlayer_SetPredictionError(e.origin - o, e.velocity - v0, pmove_onground - IS_ONGROUND(e));
                e.origin = o;
                e.velocity = v0;
 
                // get crouch state from the server
                if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
                else if(vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
 
                // get onground state from the server
                e.flags = BITSET(e.flags, FL_ONGROUND, pmove_onground);
 
                CSQCPlayer_SavePrediction(e);
            }
            CSQCPlayer_PredictTo(e, clientcommandframe + 1, true);
 
#ifdef CSQCMODEL_SERVERSIDE_CROUCH
            // get crouch state from the server (LAG)
            if (vh == pl_viewofs.z) e.flags &= ~FL_DUCKED;
            else if (vh == pl_viewofs_crouch.z) e.flags |= FL_DUCKED;
#endif
            CSQCPlayer_SetMinsMaxs(e);
 
            if (!IS_DEAD(e))
                e.angles.y = input_angles.y;
        }
 
        // relink
        e.stairsmooth_drawtime = drawtime; // since drawtime is a frame old at this point, copy it now to avoid using a drawtime 2 frames old!
        e.origin = CSQCModel_ApplyStairSmoothing(e, (e.pmove_flags & PMF_ONGROUND), e.origin);
        setorigin(e, e.origin);
    }
 
    const entity view = CSQCModel_server2csqc(player_localentnum - 1);
    if (view)
    {
        if (view != csqcplayer)
        {
            InterpolateOrigin_Do(view);
            view.view_ofs = '0 0 1' * vh;
        }
        CSQCPlayer_CalcRefdef(view);
    }
    else
    {
        // FIXME by CSQC spec we have to do this:
        // but it breaks chase cam
        /*
        setproperty(VF_ORIGIN, pmove_org + '0 0 1' * vh);
        setproperty(VF_ANGLES, view_angles);
        */
    }
    CSQCPLAYER_HOOK_POSTCAMERASETUP();
}