#include "campaign.qh"
#include <common/campaign_common.qh>
#include <common/mapinfo.qh>
#include <common/stats.qh>
#include <common/weapons/_all.qh>
#include <server/cheats.qh>
#include <server/intermission.qh>
#include <server/world.qh>

Include dependency graph for campaign.qc:

This graph shows which files directly or indirectly include this file:

Functions
int	Campaign_GetLevelNum ()
float	Campaign_Invalid ()
float	CampaignBailout (string s)
void	CampaignLevelWarp (float n)
void	CampaignPostInit ()
void	CampaignPostIntermission ()
void	CampaignPreInit ()
void	CampaignPreIntermission ()
void	CampaignSaveCvar (string cvarname, float value)

Variables
string	campaign_index_var
float	campaign_level
float	campaign_won

Function Documentation

◆ Campaign_GetLevelNum()

int Campaign_GetLevelNum ( )

Definition at line 44 of file campaign.qc.

{
    return campaign_level + 1;
}

References campaign_level.

Referenced by SendWelcomeMessage().

◆ Campaign_Invalid()

float Campaign_Invalid ( )

Definition at line 31 of file campaign.qc.

{
    string thismapname, wantedmapname;
    thismapname = GetMapname();
    wantedmapname = campaign_gametype[0];
    if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname, false, false))
        return CampaignBailout("wrong gametype!");
    wantedmapname = campaign_mapname[0];
    if(wantedmapname != thismapname)
        return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
    return 0;
}

References campaign_gametype, campaign_mapname, CampaignBailout(), GetMapname(), MapInfo_CurrentGametype(), MapInfo_Type_FromString(), and strcat().

Referenced by CampaignPostInit(), and CampaignPreInit().

◆ CampaignBailout()

float CampaignBailout ( string s )

Definition at line 22 of file campaign.qc.

{
    cvar_set("g_campaign", "0");
    LOG_INFO("^4campaign initialization failed: ", s);
    if(autocvar__campaign_testrun)
        error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
    return 1;
}

References autocvar__campaign_testrun, cvar_set(), error, and LOG_INFO.

Referenced by Campaign_Invalid(), and CampaignPreInit().

◆ CampaignLevelWarp()

void CampaignLevelWarp ( float n )

Definition at line 262 of file campaign.qc.

{
    if(n < 0)
        n = campaign_level + 1;
    CampaignFile_Unload();
    CampaignFile_Load(n, 1);
    if(campaign_entries)
        CampaignSetup(0);
    else
        error("Sorry, cheater. You are NOT WELCOME.");
    CampaignFile_Unload();
}

References campaign_entries, campaign_level, CampaignFile_Load(), CampaignFile_Unload(), CampaignSetup(), and error.

Referenced by GameCommand_warp(), and target_levelwarp_use().

◆ CampaignPostInit()

void CampaignPostInit ( )

Definition at line 101 of file campaign.qc.

{
    // now some sanity checks
    if(Campaign_Invalid())
        return;
    if(autocvar__campaign_testrun)
    {
        cvar_set("fraglimit", "0");
        cvar_set("leadlimit", "0");
        cvar_set("timelimit", "0.01");
    }
    else
    {
        // "default" uses implicit values, "" or "0" means no limit
        tokenizebyseparator(campaign_fraglimit[0], "+");
        if(argv(0) != "default") {
            cvar_set("fraglimit", argv(0));
        }
        if(argv(1) != "default") {
            cvar_set("leadlimit", argv(1));
        }
        if(campaign_timelimit[0] != "default") {
            cvar_set("timelimit", campaign_timelimit[0]);
        }
    }
}

References argv(), autocvar__campaign_testrun, campaign_fraglimit, Campaign_Invalid(), campaign_timelimit, cvar_set(), and tokenizebyseparator.

Referenced by spawnfunc().

◆ CampaignPostIntermission()

void CampaignPostIntermission ( )

Definition at line 240 of file campaign.qc.

{
    // NOTE: campaign_won is 0 or 1, that is, points to the next level
 
    if(campaign_won && campaign_entries < 2)
    {
        // last map won!
        LOG_DEBUG("^2test run: campaign looks GOOD");
        localcmd("togglemenu 1\n");
        CampaignFile_Unload();
        return;
    }
 
    CampaignSetup(campaign_won);
    CampaignFile_Unload();
    strunzone(campaign_index_var);
    strunzone(campaign_name);
    campaign_name = "";
}

References campaign_entries, campaign_index_var, campaign_name, campaign_won, CampaignFile_Unload(), CampaignSetup(), localcmd(), LOG_DEBUG, and strunzone().

Referenced by DoNextMapOverride().

◆ CampaignPreInit()

void CampaignPreInit ( )

Definition at line 49 of file campaign.qc.

{
    float baseskill;
    campaign_level = autocvar__campaign_index;
    campaign_name = strzone(autocvar__campaign_name);
    campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
    CampaignFile_Load(campaign_level, 2);
 
    if(campaign_entries < 1)
    {
        CampaignBailout("unknown map");
        return;
    }
 
    if(autocvar_sv_cheats)
    {
        MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false, false));
        CampaignFile_Unload();
        CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
        return;
    }
 
    baseskill = max(0, autocvar_g_campaign_skill + campaign_botskill[0]);
    campaign_forcewin = false;
 
    cvar_set("sv_public", "0");
    cvar_set("pausable", "1");
 
    string cvar_campaignwrapper_list = strcat("; ", campaign_mutators[0], "; ");
    int argc = tokenizebyseparator(cvar_campaignwrapper_list, "; ");
    if(argc > 0)
    {
        for(int j = 0; j < argc; ++j)
        {
            string arg = argv(j);
            if(arg == "") continue;
            _MapInfo_Parse_Settemp(mapname, MAPINFO_SETTEMP_ACL_USER, 0, arg, 1);
        }
    }
 
    cvar_settemp("g_campaign", "1");
    cvar_settemp("g_dm", "0");
    cvar_settemp("skill", ftos(baseskill));
    cvar_settemp("bot_number", ftos(campaign_bots[0]));
    cvar_settemp("bot_vs_human", "0");
 
    MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false, false));
 
    if(Campaign_Invalid())
        return;
}

References _MapInfo_Parse_Settemp(), argv(), autocvar__campaign_index, autocvar__campaign_name, autocvar_g_campaign_skill, autocvar_sv_cheats, campaign_bots, campaign_botskill, campaign_entries, campaign_forcewin, campaign_gametype, campaign_index_var, Campaign_Invalid(), campaign_level, campaign_mutators, campaign_name, CampaignBailout(), CampaignFile_Load(), CampaignFile_Unload(), cvar_set(), cvar_settemp(), ftos(), MAPINFO_SETTEMP_ACL_USER, MapInfo_SwitchGameType(), MapInfo_Type_FromString(), mapname, max(), strcat(), strzone(), and tokenizebyseparator.

Referenced by spawnfunc().

◆ CampaignPreIntermission()

void CampaignPreIntermission ( )

Definition at line 168 of file campaign.qc.

{
    int won = 0;
    int lost = 0;
    string savevar;
 
    FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
        if(it.winning)
            ++won;
        else
            ++lost;
    });
 
    if(autocvar__campaign_testrun)
    {
        campaign_won = 1;
        bprint("Campaign test run, advancing level.\n");
    }
    else if(campaign_forcewin)
    {
        campaign_won = 1;
        bprint("The current level has been WON.\n");
    }
    else if(won == 1 && lost == 0 && checkrules_equality == 0)
    {
        if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
        {
            campaign_won = 0;
            bprint("Time's up! The current level has been LOST.\n");
            // sound!
        }
        else
        {
            campaign_won = 1;
            bprint("The current level has been WON.\n");
            // sound!
        }
    }
    else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
    {
        campaign_won = 0;
        bprint("Time's up! The current level has been LOST.\n");
        // sound!
    }
    else
    {
        campaign_won = 0;
        bprint("The current level has been LOST.\n");
        // sound!
    }
 
    if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
    {
        if(campaign_level == cvar(campaign_index_var))
        {
            if(campaign_entries < 2)
            {
                // I have won
                savevar = strcat("g_campaign", campaign_name, "_won");
                CampaignSaveCvar(savevar, 1);
                // advance level (for menu to show it right)
                CampaignSaveCvar(campaign_index_var, campaign_level + 1);
            }
            else
            {
                // advance level
                CampaignSaveCvar(campaign_index_var, campaign_level + 1);
            }
        }
    }
}

References autocvar__campaign_testrun, autocvar_fraglimit, autocvar_timelimit, bprint(), campaign_entries, campaign_forcewin, campaign_index_var, campaign_level, campaign_name, campaign_won, CampaignSaveCvar(), cheatcount_total, checkrules_equality, cvar(), FOREACH_CLIENT, IS_PLAYER, IS_REAL_CLIENT, strcat(), and time.

Referenced by NextLevel().

◆ CampaignSaveCvar()

void CampaignSaveCvar	(	string	cvarname,
		float	value )

Definition at line 128 of file campaign.qc.

{
    float fh;
    float len;
    string contents;
    string l;
 
    registercvar(cvarname, ftos(value));
    cvar_set(cvarname, ftos(value));
    // note: cvarname must be remembered
 
    fh = fopen("campaign.cfg", FILE_READ);
    contents = "";
    if(fh >= 0)
    {
        while((l = fgets(fh)))
        {
            len = tokenize_console(l);
            if(len != 3)
                continue;
            if(argv(0) != "set")
                continue;
            if(argv(1) == cvarname)
                continue;
            contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
        }
        fclose(fh);
    }
    contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
    fh = fopen("campaign.cfg", FILE_WRITE);
    if(fh >= 0)
    {
        fputs(fh, contents);
    }
    else
    {
        error("Cannot write to campaign file");
    }
}