vortex.qc File Reference

#include "vortex.qh"
#include <common/items/item/ammo.qh>
#include "rifle.qh"

Include dependency graph for vortex.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
	MUTATOR_HOOKFUNCTION (vortex_charge, GetPressedKeys)
	NET_HANDLE (TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
	REGISTER_MUTATOR (vortex_charge, true)
void	SendCSQCVortexBeamParticle (entity player, float charge)
vector	vortex_glowcolor (int actor_colors, float charge)
void	W_Vortex_Attack (Weapon thiswep, entity actor,.entity weaponentity, bool is_secondary)
void	W_Vortex_Charge (entity actor,.entity weaponentity, float dt)

Variables
float	vortex_chargepool_pauseregen_finished

Function Documentation

MUTATOR_HOOKFUNCTION()

MUTATOR_HOOKFUNCTION	(	vortex_charge	,
		GetPressedKeys	)

Definition at line 89 of file vortex.qc.

{
    entity player = M_ARGV(0, entity);
 
    // WEAPONTODO
    if (!WEP_CVAR(WEP_VORTEX, charge) || !WEP_CVAR(WEP_VORTEX, charge_velocity_rate))
        return;
 
    for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
 
        if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(WEP_VORTEX, charge) && WEP_CVAR(WEP_VORTEX, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(WEP_VORTEX, charge_minspeed)))
        {
            float xyspeed = vlen(vec2(player.velocity));
            // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
            xyspeed = min(xyspeed, WEP_CVAR(WEP_VORTEX, charge_maxspeed));
            float f = (xyspeed - WEP_CVAR(WEP_VORTEX, charge_minspeed)) / (WEP_CVAR(WEP_VORTEX, charge_maxspeed) - WEP_CVAR(WEP_VORTEX, charge_minspeed));
            // add the extra charge
            player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(WEP_VORTEX, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
        }
    }
}

References entity(), GetPressedKeys(), M_ARGV, MAX_WEAPONSLOTS, min(), PHYS_INPUT_TIMELENGTH, vdist, vec2, vlen(), vortex_charge, weaponentities, and WEP_CVAR.

NET_HANDLE()

NET_HANDLE	(	TE_CSQC_VORTEXBEAMPARTICLE	,
		bool	isNew )

Definition at line 50 of file vortex.qc.

{
    vector shotorg = ReadVector();
    vector endpos = ReadVector();
    float charge = ReadByte() / 255.0;
    int myowner = ReadByte();
 
    int eff_flags = PARTICLES_USEALPHA | PARTICLES_USEFADE;
 
    //pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
 
    charge = sqrt(charge); // divide evenly among trail spacing and alpha
    particles_alphamin = particles_alphamax = particles_fade = charge;
    if ((teamplay && autocvar_cl_tracers_teamcolor == 1) || autocvar_cl_tracers_teamcolor == 2)
    {
        float mycolors = entcs_GetClientColors(myowner - 1);
        vector rgb = vortex_glowcolor(mycolors, max(0.25, charge));
        // in the event of charging being turned off, fall back to player colours
        if (rgb == '0 0 0')
            rgb = colormapPaletteColor(mycolors & 0x0F, true);
        particles_colormin = particles_colormax = rgb;
        eff_flags |= PARTICLES_USECOLOR;
    }
 
    if (!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
    {
        if (autocvar_cl_particles_oldvortexbeam)
            WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, eff_flags);
        else
            WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, eff_flags);
    }
    return true;
}

References autocvar_cl_particles_oldvortexbeam, autocvar_cl_tracers_teamcolor, colormapPaletteColor, entcs_GetClientColors(), max(), MUTATOR_CALLHOOK, NULL, particleeffectnum, particles_alphamax, particles_alphamin, particles_colormax, particles_colormin, particles_fade, PARTICLES_USEALPHA, PARTICLES_USECOLOR, PARTICLES_USEFADE, ReadByte(), ReadVector, shotorg, sqrt(), teamplay, vector, vortex_glowcolor(), and WarpZone_TrailParticles_WithMultiplier().

REGISTER_MUTATOR()

REGISTER_MUTATOR	(	vortex_charge	,
		true	)

References vortex_charge.

SendCSQCVortexBeamParticle()

void SendCSQCVortexBeamParticle	(	entity	player,
		float	charge )

Definition at line 37 of file vortex.qc.

{
    vector v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
    WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
    WriteVector(MSG_BROADCAST, w_shotorg);
    WriteVector(MSG_BROADCAST, v);
    WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
    WriteByte(MSG_BROADCAST, etof(player));
}

References bound(), entity(), etof, MSG_BROADCAST, trace_endpos, vector, w_shotorg, WarpZone_trace_transform, WarpZone_UnTransformOrigin(), WriteByte(), and WriteHeader.

Referenced by W_OverkillNex_Attack(), and W_Vortex_Attack().

vortex_glowcolor()

vector vortex_glowcolor	(	int	actor_colors,
		float	charge )

Definition at line 7 of file vortex.qc.

{
    if (!WEP_CVAR(WEP_VORTEX, charge))
        return '0 0 0';
 
    float animlimit = WEP_CVAR(WEP_VORTEX, charge_animlimit);
    float f = min(1, charge / animlimit);
    vector mycolors = colormapPaletteColor(actor_colors & 0x0F, true);
    vector g = f * (mycolors * 0.3);
    if (charge > animlimit)
    {
        f = (charge - animlimit) / (1 - animlimit);
        g += f * (mycolors * 0.7);
    }
    // transition color can't be '0 0 0' as it defaults to player model glow color
    if (g == '0 0 0')
        g = '0 0 0.000001';
 
    return g;
}

References colormapPaletteColor, min(), vector, and WEP_CVAR.

Referenced by NET_HANDLE().

W_Vortex_Attack()

void W_Vortex_Attack	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		bool	is_secondary )

Definition at line 113 of file vortex.qc.

{
    float mydmg = WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, damage);
    float myforce = WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, force);
 
    float dtype = thiswep.m_id;
    if (WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, armorpierce))
        dtype |= HITTYPE_ARMORPIERCE;
 
    float flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 
    float charge;
    if (WEP_CVAR(WEP_VORTEX, charge))
    {
        charge = WEP_CVAR(WEP_VORTEX, charge_mindmg) / mydmg + (1 - WEP_CVAR(WEP_VORTEX, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
        actor.(weaponentity).vortex_charge *= WEP_CVAR(WEP_VORTEX, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
        // O RLY? -- divVerent
        // YA RLY -- FruitieX
    }
    else
        charge = 1;
    mydmg *= charge;
    myforce *= charge;
 
    W_SetupShot(actor, weaponentity, true, 5, SND_VORTEX_FIRE, CH_WEAPON_A, mydmg, dtype);
    if (WEP_CVAR(WEP_VORTEX, charge_animlimit) && charge > WEP_CVAR(WEP_VORTEX, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
        sound(actor, CH_WEAPON_B, SND_VORTEX_CHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(WEP_VORTEX, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(WEP_VORTEX, charge_animlimit)), ATTN_NORM);
 
    yoda = 0;
    impressive_hits = 0;
    FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance,
        mydmg,
        false,
        myforce,
        WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, damagefalloff_mindist),
        WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, damagefalloff_maxdist),
        WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, damagefalloff_halflife),
        WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, damagefalloff_forcehalflife),
        dtype
    );
 
    if (yoda && flying)
        Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
    if (impressive_hits && actor.vortex_lasthit)
    {
        Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
        impressive_hits = 0; // only every second time
    }
 
    actor.vortex_lasthit = impressive_hits;
 
    //beam done on client
    vector v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
    W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, normalize(v - w_shotorg));
    SendCSQCVortexBeamParticle(actor, charge);
 
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR_BOTH(WEP_VORTEX, !is_secondary, ammo), weaponentity);
}

References ammo, ATTN_NORM, CH_WEAPON_A, CH_WEAPON_B, entity(), FireRailgunBullet(), HITTYPE_ARMORPIERCE, impressive_hits, IsFlying(), Weapon::m_id, max_shot_distance, normalize(), Send_Notification(), SendCSQCVortexBeamParticle(), sound, trace_endpos, vector, VOL_BASE, vortex_charge, W_DecreaseAmmo(), W_MuzzleFlash(), W_SetupShot, w_shotdir, w_shotorg, WarpZone_trace_transform, WarpZone_UnTransformOrigin(), WEP_CVAR, WEP_CVAR_BOTH, and yoda.

W_Vortex_Charge()

void W_Vortex_Charge	(	entity	actor,
		.entity	weaponentity,
		float	dt )

Definition at line 174 of file vortex.qc.

{
    if (WEP_CVAR(WEP_VORTEX, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(WEP_VORTEX, charge_limit))
        actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(WEP_VORTEX, charge_rate) * dt);
}

References entity(), min(), vortex_charge, and WEP_CVAR.

Referenced by PlayerThink().

Variable Documentation

vortex_chargepool_pauseregen_finished

float vortex_chargepool_pauseregen_finished

Definition at line 172 of file vortex.qc.