keys.qc File Reference

#include "keys.qh"

Include dependency graph for keys.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	item_key_touch (entity this, entity toucher)
	Key touch handler.
string	item_keys_keylist (float keylist)
	Returns a string with a comma separated list of key names, as specified in keylist.
bool	item_keys_usekey (entity l, entity p)
	Use keys from p on l.
void	spawn_item_key (entity this)
	Spawn a key with given model, key code and color.
	spawnfunc (item_key)
	spawnfunc (item_key1)
	spawnfunc (item_key2)
	spawnfunc (item_key_gold)
	spawnfunc (item_key_master)
	spawnfunc (item_key_silver)

Function Documentation

item_key_touch()

void item_key_touch	(	entity	this,
		entity	toucher )

Key touch handler.

Definition at line 77 of file keys.qc.

{
    if (!IS_PLAYER(toucher))
        return;
 
    // player already picked up this key
    if (PS(toucher).itemkeys & this.itemkeys)
        return;
 
    PS(toucher).itemkeys |= this.itemkeys;
    play2(toucher, this.noise);
 
    centerprint(toucher, this.message);
 
    string oldmsg = this.message;
    this.message = "";
    SUB_UseTargets(this, toucher, toucher); // TODO: should we be using toucher for the trigger here?
    this.message = oldmsg;
}

References centerprint(), entity(), IS_PLAYER, itemkeys, message, noise, play2(), PS, SUB_UseTargets(), and toucher.

Referenced by spawn_item_key().

item_keys_keylist()

string item_keys_keylist

(

float

keylist

)

Returns a string with a comma separated list of key names, as specified in keylist.

Definition at line 40 of file keys.qc.

{
    // no keys
    if (!keylist)
        return "";
 
    // one key
    if ((keylist & (keylist-1)) == 0)
        return strcat("the ", item_keys_names[lowestbit(keylist)]);
 
    string n = "";
    int base = 0;
    while (keylist)
    {
        int l = lowestbit(keylist);
        if (n)
            n = strcat(n, ", the ", item_keys_names[base + l]);
        else
            n = strcat("the ", item_keys_names[base + l]);
 
        keylist = bitshift(keylist, -(l + 1));
        base += l + 1;
    }
 
    return n;
}

References item_keys_names, lowestbit(), and strcat().

Referenced by door_check_keys(), and trigger_keylock_touch().

item_keys_usekey()

bool item_keys_usekey	(	entity	l,
		entity	p )

Use keys from p on l.

Returns true if any new keys were given, false otherwise.

Definition at line 4 of file keys.qc.

{
    int valid = (l.itemkeys & p.itemkeys); // TODO: itemkeys isn't networked or anything!
    l.itemkeys &= ~valid; // only some of the needed keys were given
    return valid != 0;
}

References entity().

Referenced by trigger_keylock_touch().

spawn_item_key()

void spawn_item_key

(

entity

this

)

Spawn a key with given model, key code and color.

Definition at line 100 of file keys.qc.

{
    precache_model(this.model);
 
    if (this.spawnflags & 1) // FLOATING
        this.noalign = 1;
 
    if (this.noalign)
        set_movetype(this, MOVETYPE_NONE);
    else
        set_movetype(this, MOVETYPE_TOSS);
 
    precache_sound(this.noise);
 
    this.mdl = this.model;
    this.effects = EF_LOWPRECISION;
    _setmodel(this, this.model);
    this.modelflags |= MF_ROTATE;
    this.solid = SOLID_TRIGGER;
 
    // The origin.z was raised within the bbox to support the current model
    //setsize(this, '-16 -16 -24', '16 16 32');
    setorigin(this, this.origin + '0 0 32');
    setsize(this, '-16 -16 -56', '16 16 0');
 
    if (Q3COMPAT_COMMON) // QL compat, Q3 has no keys
        // QL bbox is '-16 -16 -16' '16 16 16' so raise to match QL absmin.z
        setorigin(this, this.origin + '0 0 8');
 
    // NOTE: this isn't an FL_ITEM so it doesn't get the special treatment in DropToFloor_QC()
    if (!this.noalign)
        DropToFloor_QC_DelayedInit(this);
 
    settouch(this, item_key_touch);
}

References DropToFloor_QC_DelayedInit(), EF_LOWPRECISION, effects, entity(), item_key_touch(), mdl, MF_ROTATE, model, modelflags, MOVETYPE_NONE, MOVETYPE_TOSS, noalign, noise, origin, precache_sound(), Q3COMPAT_COMMON, set_movetype(), settouch, solid, SOLID_TRIGGER, and spawnflags.

Referenced by spawnfunc().

spawnfunc() [1/6]

spawnfunc

(

item_key

)

Definition at line 166 of file keys.qc.

{
    string _netname;
    vector _colormod;
    string _model = "models/keys/key.md3";
 
    // reject this entity if more than one key was set!
    if (this.itemkeys>0 && (this.itemkeys & (this.itemkeys-1)) != 0)
    if (this.itemkeys != 0xffffff) // unless it's a master key
    {
        objerror(this, "item_key.itemkeys must contain only 1 bit set specifying the key it represents!");
        delete(this);
        return;
    }
 
    // find default netname and colormod
    switch(this.itemkeys) {
    case BIT(0):
        _netname = "GOLD key";
        _colormod = '1 .9 0';
        break;
 
    case BIT(1):
        _netname = "SILVER key";
        _colormod = '.9 .9 .9';
        break;
 
    case BIT(2):
        _netname = "BRONZE key";
        _colormod = '.6 .25 0';
        break;
 
    case BIT(3):
        _netname = "RED keycard";
        _colormod = '.9 0 0';
        _model = "models/keys/key.md3"; // FIXME: replace it by a keycard model!
        break;
 
    case BIT(4):
        _netname = "BLUE keycard";
        _colormod = '0 0 .9';
        _model = "models/keys/key.md3"; // FIXME: replace it by a keycard model!
        break;
 
    case BIT(5):
        _netname = "GREEN keycard";
        _colormod = '0 .9 0';
        _model = "models/keys/key.md3"; // FIXME: replace it by a keycard model!
        break;
 
    case 0xffffff: // an unlisted key...
        _netname = "MASTER key";
        _colormod = '1 0.25 0.25';
        break;
 
    default:
        _netname = "FLUFFY PINK keycard";
        _colormod = '1 1 1';
 
        if (this.netname == "")
        {
            objerror(this, "item_key doesn't have a default name for this key and a custom one was not specified!");
            delete(this);
            return;
        }
        if (this.model == "")
        {
            objerror(this, "item_key doesn't have a default model for this key and a custom one was not specified!");
            delete(this);
            return;
        }
        break;
    }
 
    // set default netname
    if (this.netname == "")
        this.netname = _netname;
 
    // set default colormod
    if (!this.colormod)
        this.colormod = _colormod;
 
    // set default model
    if (this.model == "")
        this.model = _model;
 
    // set default pickup message
    if (this.message == "")
        this.message = strzone(strcat("You've picked up the ", this.netname, "!"));
 
    if (this.noise == "")
        this.noise = strzone(SND(ITEMPICKUP));
 
    // save the name for later
    item_keys_names[lowestbit(this.itemkeys)] = this.netname;
 
    // put the key on the map
    spawn_item_key(this);
}

References BIT, colormod, item_keys_names, itemkeys, lowestbit(), message, model, netname, noise, objerror, SND, spawn_item_key(), strcat(), strzone(), and vector.

spawnfunc() [2/6]

spawnfunc

(

item_key1

)

Definition at line 278 of file keys.qc.

{
    this.itemkeys = BIT(1);
    spawnfunc_item_key(this);
}

References BIT, and itemkeys.

spawnfunc() [3/6]

spawnfunc

(

item_key2

)

Definition at line 296 of file keys.qc.

{
    this.itemkeys = BIT(0);
    spawnfunc_item_key(this);
}

References BIT, and itemkeys.

spawnfunc() [4/6]

spawnfunc

(

item_key_gold

)

Definition at line 304 of file keys.qc.

{
    this.itemkeys = BIT(0);
    spawnfunc_item_key(this);
}

References BIT, and itemkeys.

spawnfunc() [5/6]

spawnfunc

(

item_key_master

)

Definition at line 331 of file keys.qc.

{
    // We have more key types than QL, may as well open them all.
    this.itemkeys = 0xffffff;
    spawnfunc_item_key(this);
}

References itemkeys.

spawnfunc() [6/6]

spawnfunc

(

item_key_silver

)

Definition at line 310 of file keys.qc.

{
    this.itemkeys = BIT(1);
    spawnfunc_item_key(this);
}

References BIT, and itemkeys.