This graph shows which files directly or indirectly include this file:

Functions
void	ClientKill (entity this)
void	ClientKill_Now (entity this)
void	ClientKill_Now_TeamChange (entity this)
void	ClientKill_Silent (entity this, float _delay)
void	ClientKill_TeamChange (entity this, float targetteam)
void	KillIndicator_Think (entity this)

Variables
float	autocvar_g_balance_kill_antispam
float	autocvar_g_balance_kill_delay
entity	killindicator
int	killindicator_teamchange

Function Documentation

◆ ClientKill()

void ClientKill ( entity this )

Definition at line 227 of file clientkill.qc.

{
    if (game_stopped || this.player_blocked)
        return;
 
    ClientKill_TeamChange(this, 0);
}

References ClientKill_TeamChange(), entity(), game_stopped, and player_blocked.

◆ ClientKill_Now()

void ClientKill_Now ( entity this )

Definition at line 37 of file clientkill.qc.

{
    if (this.vehicle)
    {
        vehicles_exit(this.vehicle, VHEF_RELEASE);
        if (!this.killindicator_teamchange)
        {
            this.vehicle_health = -1;
            Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
        }
    }
 
    if (this.killindicator && !wasfreed(this.killindicator))
        delete(this.killindicator);
 
    this.killindicator = NULL;
 
    if (this.killindicator_teamchange)
        ClientKill_Now_TeamChange(this);
    // SetPlayerTeam() already killed if team changed, auto-selecting the current team shouldn't kill.
    else if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
        Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 
    // now I am sure the player IS dead
}

References ClientKill_Now(), ClientKill_Now_TeamChange(), Damage(), DMG_NOWEP, entity(), IS_OBSERVER, IS_SPEC, killindicator, killindicator_teamchange, MUTATOR_CALLHOOK, NULL, vehicle, vehicle_health, vehicles_exit(), and VHEF_RELEASE.

Referenced by ClientKill_Now(), ClientKill_TeamChange(), KillIndicator_Think(), and MUTATOR_HOOKABLE().

◆ ClientKill_Now_TeamChange()

void ClientKill_Now_TeamChange ( entity this )

Definition at line 18 of file clientkill.qc.

{
    if (this.killindicator_teamchange == -2)
    {
        if (!autocvar_sv_spectate)
            // shouldn't get here because of condition in ClientCommand_spectate()
            Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 
        PutObserverInServer(this, false, true);
        if (!TeamBalance_QueuedPlayersTagIn(this))
        if (autocvar_g_balance_teams_remove)
            TeamBalance_RemoveExcessPlayers(this);
    }
    else
        SetPlayerTeam(this, Team_TeamToIndex(this.killindicator_teamchange), TEAM_CHANGE_MANUAL);
 
    this.killindicator_teamchange = 0;
}

References autocvar_g_balance_teams_remove, autocvar_g_maxplayers_spectator_blocktime, autocvar_sv_spectate, entity(), killindicator_teamchange, PutObserverInServer(), Send_Notification(), SetPlayerTeam(), TEAM_CHANGE_MANUAL, Team_TeamToIndex(), TeamBalance_QueuedPlayersTagIn(), and TeamBalance_RemoveExcessPlayers().

Referenced by ClientKill_Now(), and PlayerDamage().

◆ ClientKill_Silent()

void ClientKill_Silent	(	entity	this,
		float	_delay )

Definition at line 213 of file clientkill.qc.

{
    // overrides queued silent killindicators
    if (!this.killindicator || this.killindicator.count != 1)
        this.killindicator = new(killindicator);
    this.killindicator.owner = this;
    setthink(this.killindicator, KillIndicator_Think);
    this.killindicator.nextthink = time + (this.lip) * 0.05;
    this.killindicator.cnt = ceil(_delay);
    this.killindicator.count = 1; // this is used to indicate that it should be silent
    this.lip = 0;
}

References ceil(), entity(), killindicator, KillIndicator_Think(), lip, setthink, and time.

Referenced by MUTATOR_HOOKFUNCTION().

◆ ClientKill_TeamChange()

void ClientKill_TeamChange	(	entity	this,
		float	targetteam )

Definition at line 95 of file clientkill.qc.

{
    if (game_stopped)
        return;
 
    float killtime = autocvar_g_balance_kill_delay;
 
    if (MUTATOR_CALLHOOK(ClientKill, this, killtime))
        return;
    killtime = M_ARGV(1, float);
 
    if(round_handler_IsActive() && !round_handler_IsRoundStarted())
        killtime = min(killtime, 1);
 
    if (targetteam == -1)
    {
        if (this.team <= 0)
        {
            // Defer autoselect to Join(), after any queued players were joined, to avoid 2 players on same team
            // when the first player(s) chose specific teams and the last player chose autoselect (they skip the queue).
            this.team_selected = -1; // don't stop at ShowTeamSelection()
            return;
        }
 
        /* Decide the team now because the "best" team could change during g_balance_kill_delay.
         * This lets balancing code consider this player to be on the team they're about to change to,
         * so we won't need to cancel the change after informing the player it's happening,
         * and so we don't need to handle that in other code such as TeamBalance_QueuedPlayersTagIn().
         * Also so we can notify immediately when already on a best team instead of counting down for nothing.
         */
        entity balance = TeamBalance_CheckAllowedTeams(this);
        targetteam = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, this, true));
        TeamBalance_Destroy(balance);
        if (targetteam == this.team)
        {
            Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_ALREADYBEST);
            return;
        }
    }
    this.killindicator_teamchange = targetteam;
 
    // this.killindicator.count == 1 means that the kill indicator was spawned by ClientKill_Silent
    if(killtime <= 0 && this.killindicator && this.killindicator.count == 1)
    {
        ClientKill_Now(this); // allow instant kill in this case
        return;
    }
 
    if (!this.killindicator)
    {
        if (!IS_DEAD(this))
        {
            killtime = max(killtime, this.clientkill_nexttime - time);
            float antispam_delay = autocvar_g_balance_kill_antispam;
            if(round_handler_IsActive() && !round_handler_IsRoundStarted())
                antispam_delay = min(antispam_delay, 2);
            this.clientkill_nexttime = time + killtime + antispam_delay;
        }
 
        if (killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
        {
            ClientKill_Now(this);
        }
        else
        {
            float starttime = max(time, clientkilltime);
 
            this.killindicator = new(killindicator);
            this.killindicator.owner = this;
            this.killindicator.scale = 0.5;
            setattachment(this.killindicator, this, "");
            setorigin(this.killindicator, '0 0 52');
            setthink(this.killindicator, KillIndicator_Think);
            this.killindicator.nextthink = starttime + (this.lip) * 0.05;
            clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
            this.killindicator.cnt = ceil(killtime);
            this.killindicator.count = bound(0, ceil(killtime), 10);
            //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 
            IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST) && !it.killindicator,
            {
                it.killindicator = new(killindicator);
                it.killindicator.owner = it;
                it.killindicator.scale = 0.5;
                setattachment(it.killindicator, it, "");
                setorigin(it.killindicator, '0 0 52');
                setthink(it.killindicator, KillIndicator_Think);
                it.killindicator.nextthink = starttime + (it.lip) * 0.05;
                //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
                it.killindicator.cnt = ceil(killtime);
            });
            this.lip = 0;
        }
    }
    if (this.killindicator)
    {
        Notification notif;
        if (targetteam == 0) // just die
        {
            this.killindicator.colormod = '0 0 0';
            notif = CENTER_TEAMCHANGE_SUICIDE;
        }
        else if (targetteam == -2) // spectate
        {
            this.killindicator.colormod = '0.5 0.5 0.5';
            notif = CENTER_TEAMCHANGE_SPECTATE;
        }
        else
        {
            this.killindicator.colormod = Team_ColorRGB(targetteam);
            notif = APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE);
        }
        if (IS_REAL_CLIENT(this) && this.killindicator.cnt > 0)
            Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, notif, this.killindicator.cnt);
    }
 
}

References APP_TEAM_NUM, autocvar_g_balance_kill_antispam, autocvar_g_balance_kill_delay, bound(), ceil(), ClientKill, clientkill_nexttime, ClientKill_Now(), clientkilltime, CSQCMODEL_EF_RESPAWNGHOST, entity(), g_clones, game_stopped, IL_EACH, IS_DEAD, IS_PLAYER, IS_REAL_CLIENT, killindicator, killindicator_teamchange, KillIndicator_Think(), lip, M_ARGV, max(), min(), MUTATOR_CALLHOOK, round_handler_IsActive, round_handler_IsRoundStarted, Send_Notification(), setthink, team, Team_ColorRGB(), Team_IndexToTeam(), team_selected, TeamBalance_CheckAllowedTeams(), TeamBalance_Destroy(), TeamBalance_FindBestTeam(), and time.

Referenced by ClientCommand_clientversion(), ClientCommand_selectteam(), ClientCommand_spectate(), and ClientKill().

◆ KillIndicator_Think()

void KillIndicator_Think ( entity this )

Definition at line 62 of file clientkill.qc.

{
    if (game_stopped || (this.owner.alpha < 0 && !this.owner.vehicle))
    {
        this.owner.killindicator = NULL;
        delete(this);
        return;
    }
 
    if (this.cnt <= 0)
    {
        ClientKill_Now(this.owner);
        return;
    }
 
    // count == 1 means that it's silent
    if (this.count != 1)
    {
        if (this.cnt <= 10)
            setmodel(this, MDL_NUM(this.cnt));
        if (IS_REAL_CLIENT(this.owner))
        {
            if (this.cnt <= 10)
                Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt));
        }
    }
    this.nextthink = time + 1;
    this.cnt -= 1;
}