getreplies.qc File Reference

#include "getreplies.qh"
#include <common/command/_mod.qh>
#include <common/constants.qh>
#include <common/gametypes/_mod.qh>
#include <common/monsters/_mod.qh>
#include <common/net_linked.qh>
#include <common/notifications/all.qh>
#include <common/playerstats.qh>
#include <common/stats.qh>
#include <common/util.qh>
#include <common/weapons/_all.qh>
#include <common/wepent.qh>
#include <server/intermission.qh>
#include <server/main.qh>
#include <server/mapvoting.qh>
#include <server/mutators/_mod.qh>
#include <server/race.qh>
#include <server/weapons/selection.qh>
#include <server/world.qh>

Include dependency graph for getreplies.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	GetCvars (entity this, entity store, int f)
void	GetCvars_handleFloat (entity this, entity store, string thisname, float f,.float field, string name)
void	GetCvars_handleFloatOnce (entity this, entity store, string thisname, float f,.float field, string name)
void	GetCvars_handleString (entity this, entity store, string thisname, float f,.string field, string name)
void	GetCvars_handleString_Fixup (entity this, entity store, string thisname, float f,.string field, string name, string(entity, string) func)
string	getladder ()
string	getlsmaps ()
string	getmaplist ()
string	getmonsterlist ()
string	getrankings ()
string	getrecords (int page)

Variables
const int	LSMAPS_MAX = 250

Function Documentation

GetCvars()

void GetCvars	(	entity	this,
		entity	store,
		int	f )

Parameters

f	-1: cleanup, 0: request, 1: receive

Definition at line 387 of file getreplies.qc.

{
    string s = string_null;
 
    if (f == 0)
        LOG_INFO("Warning: requesting cvar values is deprecated. Client should send them automatically using REPLICATE.\n");
 
    if (f > 0)
        s = strcat(argv(f));
 
    get_cvars_f = f;
    get_cvars_s = s;
    MUTATOR_CALLHOOK(GetCvars);
 
    Notification_GetCvars(this, store);
 
    ReplicateVars(this, store, s, f);
    if (f > 0)
        ReplicateVars_ApplyChange(this, store, s, f);
}

References argv(), entity(), get_cvars_f, get_cvars_s, GetCvars(), LOG_INFO, MUTATOR_CALLHOOK, Notification_GetCvars(), ReplicateVars(), ReplicateVars_ApplyChange(), strcat(), and string_null.

Referenced by ClientCommand_sentcvar(), ClientState_detach(), GetCvars(), and MUTATOR_HOOKABLE().

GetCvars_handleFloat()

void GetCvars_handleFloat	(	entity	this,
		entity	store,
		string	thisname,
		float	f,
		.float	field,
		string	name )

Definition at line 347 of file getreplies.qc.

{
    if (f < 0)
    {
    }
    else if (f > 0)
    {
        if (thisname == name)
            store.(field) = stof(argv(f + 1));
    }
    else
        stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
}

References argv(), entity(), name, stof(), strcat(), and stuffcmd.

Referenced by Notification_GetCvars().

GetCvars_handleFloatOnce()

void GetCvars_handleFloatOnce	(	entity	this,
		entity	store,
		string	thisname,
		float	f,
		.float	field,
		string	name )

Definition at line 360 of file getreplies.qc.

{
    if (f < 0)
    {
    }
    else if (f > 0)
    {
        if (thisname == name)
        {
            if (!store.(field))
            {
                store.(field) = stof(argv(f + 1));
                if (!store.(field))
                    store.(field) = -1;
            }
        }
    }
    else
    {
        if (!store.(field))
            stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
    }
}

References argv(), entity(), name, stof(), strcat(), and stuffcmd.

GetCvars_handleString()

void GetCvars_handleString	(	entity	this,
		entity	store,
		string	thisname,
		float	f,
		.string	field,
		string	name )

Definition at line 318 of file getreplies.qc.

{
    if (f < 0)
    {
        strfree(store.(field));
    }
    else if (f > 0)
    {
        if (thisname == name)
        {
            strcpy(store.(field), argv(f + 1));
        }
    }
    else
        stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
}

References argv(), entity(), name, strcat(), strcpy, strfree, and stuffcmd.

Referenced by GetCvars_handleString_Fixup().

GetCvars_handleString_Fixup()

void GetCvars_handleString_Fixup	(	entity	this,
		entity	store,
		string	thisname,
		float	f,
		.string	field,
		string	name,
		string(entity, string)	func )

Definition at line 334 of file getreplies.qc.

{
    GetCvars_handleString(this, store, thisname, f, field, name);
    if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
        if (thisname == name)
        {
            string s = func(this, strcat(store.(field)));
            if (s != store.(field))
            {
                strcpy(store.(field), s);
            }
        }
}

References entity(), GetCvars_handleString(), name, strcat(), and strcpy.

getladder()

string getladder

(

)

Definition at line 71 of file getreplies.qc.

{
    int i, j, k, uidcnt = 0, thiscnt;
    string s, temp_s, rr, myuid, thisuid;
 
    rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
 
    for (k = 0; k < MapInfo_count; ++k)
    {
        if (MapInfo_Get_ByID(k))
        {
            for (i = 0; i <= LADDER_CNT; ++i) // i = 0 because it is the speed award
            {
                if (i == 0)                   // speed award
                {
                    if (stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0) continue;
 
                    myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
                }
                else  // normal record, if it exists (else break)
                {
                    if (race_readTime(MapInfo_Map_bspname, i) == 0) continue;
 
                    myuid = race_readUID(MapInfo_Map_bspname, i);
                }
 
                // string s contains:
                // arg 0 = # of speed recs
                // arg 1 = # of 1st place recs
                // arg 2 = # of 2nd place recs
                // ... etc
                // LADDER_CNT+1 = total points
 
                temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
 
                if (temp_s == "")
                {
                    db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
                    ++uidcnt;
 
                    for (j = 0; j <= LADDER_CNT + 1; ++j)
                    {
                        if (j != LADDER_CNT + 1) temp_s = strcat(temp_s, "0 ");
                        else temp_s = strcat(temp_s, "0");
                    }
                }
 
                tokenize_console(temp_s);
                s = "";
 
                if (i == 0)                                         // speed award
                {
                    for (j = 0; j <= LADDER_CNT; ++j)               // loop over each arg in the string
                    {
                        if (j == 0)                                 // speed award
                            s = strcat(s, ftos(stof(argv(j)) + 1)); // add 1 to speed rec count and write
                        else s = strcat(s, " ", argv(j));           // just copy over everything else
                    }
                }
                else  // record
                {
                    for (j = 0; j <= LADDER_CNT; ++j)                    // loop over each arg in the string
                    {
                        if (j == 0) s = strcat(s, argv(j));              // speed award, dont prefix with " "
                        else if (j == i)                                 // wanted rec!
                            s = strcat(s, " ", ftos(stof(argv(j)) + 1)); // update argv(j)
                        else s = strcat(s, " ", argv(j));                // just copy over everything else
                    }
                }
 
                // total points are (by default) calculated like this:
                // speedrec = floor(100 / 10) = 10 points
                // 1st place = floor(100 / 1) = 100 points
                // 2nd place = floor(100 / 2) = 50 points
                // 3rd place = floor(100 / 3) = 33 points
                // 4th place = floor(100 / 4) = 25 points
                // 5th place = floor(100 / 5) = 20 points
                // ... etc
 
                if (i == 0) s = strcat(s, " ", ftos(stof(argv(LADDER_CNT + 1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
                else s = strcat(s, " ", ftos(stof(argv(LADDER_CNT + 1)) + floor(LADDER_FIRSTPOINT / i)));  // record, add LADDER_FIRSTPOINT / i points
 
                db_put(TemporaryDB, strcat("ladder", myuid), s);
            }
        }
    }
 
    for (i = 0; i <= uidcnt; ++i)  // for each known uid
    {
        thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
        temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
        tokenize_console(temp_s);
        thiscnt = stof(argv(LADDER_CNT + 1));
 
        if (thiscnt > top_scores[LADDER_SIZE - 1])
        {
            for (j = 0; j < LADDER_SIZE; ++j)  // for each place in ladder
            {
                if (thiscnt > top_scores[j])
                {
                    for (k = LADDER_SIZE - 1; k >= j; --k)
                    {
                        top_uids[k] = top_uids[k - 1];
                        top_scores[k] = top_scores[k - 1];
                    }
 
                    top_uids[j] = thisuid;
                    top_scores[j] = thiscnt;
                    break;
                }
            }
        }
    }
 
    s = "^3-----------------------\n\n";
 
    s = strcat(s, "Pos ^3|");
    s = strcat(s, " ^7Total  ^3|");
 
    for (i = 1; i <= LADDER_CNT; ++i)
        s = strcat(s, " ^7", count_ordinal(i), " ^3|");
    s = strcat(s, " ^7Speed awards ^3| ^7Name");
    s = strcat(s, "\n^3----+--------");
 
    for (i = 1; i <= min(9, LADDER_CNT); ++i)
        s = strcat(s, "+-----");
#if LADDER_CNT > 9
        for (i = 1; i <= LADDER_CNT - 9; ++i)
            s = strcat(s, "+------");
#endif
 
    s = strcat(s, "+--------------+--------------------\n");
 
    for (i = 0; i < LADDER_SIZE; ++i)
    {
        temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
        tokenize_console(temp_s);
 
        if (argv(LADDER_CNT + 1) == "")                           // total is 0, skip
            continue;
 
        s = strcat(s, strpad(4, count_ordinal(i + 1)), "^3| ^7"); // pos
        s = strcat(s, strpad(7, argv(LADDER_CNT + 1)), "^3| ^7"); // total
 
        for (j = 1; j <= min(9, LADDER_CNT); ++j)
            s = strcat(s, strpad(4, argv(j)), "^3| ^7");          // 1st, 2nd, 3rd etc cnt
 
#if LADDER_CNT > 9
            for (j = 10; j <= LADDER_CNT; ++j)
                s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
#endif
 
        s = strcat(s, strpad(13, argv(0)), "^3| ^7");         // speed award cnt
        s = strcat(s, uid2name(top_uids[i]), "\n");           // name
    }
 
    MapInfo_ClearTemps();
 
    if (s == "") return "No ladder on this server!\n";
    else return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
}

References argv(), count_ordinal(), CTS_RECORD, db_get(), db_put(), floor(), ftos(), g_cts, LADDER_CNT, LADDER_FIRSTPOINT, LADDER_SIZE, MapInfo_ClearTemps(), MapInfo_count, MapInfo_Get_ByID(), MapInfo_Map_bspname, min(), race_readTime(), race_readUID(), RACE_RECORD, ServerProgsDB, stof(), strcat(), TemporaryDB, tokenize_console, top_scores, top_uids, and uid2name().

Referenced by spawnfunc().

getlsmaps()

string getlsmaps

(

)

Definition at line 252 of file getreplies.qc.

{
    string lsmaps = "", col;
    bool newmaps = false;
    int added = 0;
 
    for (int i = 0; i < MapInfo_count; ++i)
    {
        if ((MapInfo_Get_ByID(i)) && !(MapInfo_Map_flags & MapInfo_ForbiddenFlags()))
        {
            ++added;
 
            if(added > LSMAPS_MAX)
                continue; // we still get the added count, but skip the actual processing
 
            // todo: Check by play count of maps for other gametypes?
            // TODO: standardized system for adding new map clause
            bool isnewmap = false;
            if((g_race || g_cts) && !race_readTime(MapInfo_Map_bspname, 1))
                isnewmap = true;
            else if(g_ctf && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time"))))
                isnewmap = true;
 
            if(isnewmap)
            {
                newmaps = true;
                if (i % 2) col = "^4*"; else col = "^5*";
            }
            else
            {
                if (i % 2) col = "^2"; else col = "^3";
            }
 
            lsmaps = cons(lsmaps, strcat(col, MapInfo_Map_bspname));
        }
    }
 
    if(added > LSMAPS_MAX)
        lsmaps = sprintf("%s ^7(%d not listed)", lsmaps, added - LSMAPS_MAX);
 
    MapInfo_ClearTemps();
    return sprintf("^7Maps available (%d)%s: %s\n", added, (newmaps ? " (New maps have asterisks marked in blue)" : ""), lsmaps);
}

References cons(), db_get(), g_ctf, g_cts, g_race, LSMAPS_MAX, MapInfo_ClearTemps(), MapInfo_count, MapInfo_ForbiddenFlags(), MapInfo_Get_ByID(), MapInfo_Map_bspname, MapInfo_Map_flags, race_readTime(), ServerProgsDB, stof(), and strcat().

Referenced by GameTypeVote_SetGametype(), and spawnfunc().

getmaplist()

string getmaplist

(

)

Definition at line 233 of file getreplies.qc.

{
    if(autocvar_g_maplist == "")
        return "^7Map list is empty";
 
    string maplist = "";
    int mapcount = 0;
    FOREACH_WORD(autocvar_g_maplist, MapInfo_CheckMap(it),
    {
        string col = (i % 2) ? "^2" : "^3";
        maplist = cons(maplist, strcat(col, it));
        ++mapcount;
    });
 
    MapInfo_ClearTemps();
    return sprintf("^7Maps in list (%d): %s\n", mapcount, maplist);
}

References autocvar_g_maplist, cons(), FOREACH_WORD, MapInfo_CheckMap(), MapInfo_ClearTemps(), and strcat().

Referenced by spawnfunc().

getmonsterlist()

string getmonsterlist

(

)

Definition at line 296 of file getreplies.qc.

{
    string monsterlist = "";
 
    FOREACH(Monsters, it != MON_Null && !(it.spawnflags & MON_FLAG_HIDDEN),
    {
        string col = ((i % 2) ? "^2" : "^3");
        monsterlist = sprintf("%s%s%s ", monsterlist, col, it.netname);
    });
 
    return sprintf("^7Monsters available: %s\n", monsterlist);
}

References FOREACH, and MON_FLAG_HIDDEN.

Referenced by spawnfunc().

getrankings()

string getrankings

(

)

Definition at line 46 of file getreplies.qc.

{
    float t, i;
    string n, s, p, map;
 
    map = GetMapname();
 
    s = "";
    for (i = 1; i <= RANKINGS_CNT; ++i)
    {
        t = race_readTime(map, i);
 
        if (t == 0) continue;
 
        n = race_readName(map, i);
        p = count_ordinal(i);
        s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t, false)), " ", n, "\n");
    }
 
    MapInfo_ClearTemps();
 
    if (s == "") return strcat("No records are available for the map: ", map, "\n");
    else return strcat("Records for ", map, ":\n", s);
}

References count_ordinal(), GetMapname(), MapInfo_ClearTemps(), race_readName(), race_readTime(), RANKINGS_CNT, strcat(), and TIME_ENCODED_TOSTRING.

Referenced by race_deleteTime(), race_setTime(), and spawnfunc().

getrecords()

string getrecords

(

int

page

)

Definition at line 35 of file getreplies.qc.

{
    string s = "";
 
    MUTATOR_CALLHOOK(GetRecords, page, s);
    s = M_ARGV(1, string);
 
    MapInfo_ClearTemps();
    return s;
}

References M_ARGV, MapInfo_ClearTemps(), and MUTATOR_CALLHOOK.

Referenced by spawnfunc().

Variable Documentation

LSMAPS_MAX

const int LSMAPS_MAX = 250

Definition at line 251 of file getreplies.qc.

Referenced by getlsmaps().