sv_cts.qc File Reference

#include "sv_cts.qh"
#include <server/client.qh>
#include <server/race.qh>
#include <server/world.qh>
#include <server/gamelog.qh>
#include <server/intermission.qh>
#include <server/items/spawning.qh>
#include <server/weapons/common.qh>
#include <common/mapobjects/triggers.qh>

Include dependency graph for sv_cts.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	cts_EventLog (string mode, entity actor)
void	cts_Initialize ()
void	cts_ScoreRules ()
void	havocbot_role_cts (entity this)
	MUTATOR_HOOKFUNCTION (cts, AbortSpeedrun)
	MUTATOR_HOOKFUNCTION (cts, ClientConnect)
	MUTATOR_HOOKFUNCTION (cts, ClientKill)
	MUTATOR_HOOKFUNCTION (cts, Damage_Calculate)
	MUTATOR_HOOKFUNCTION (cts, FilterItem)
	MUTATOR_HOOKFUNCTION (cts, FixClientCvars)
	MUTATOR_HOOKFUNCTION (cts, ForbidDropCurrentWeapon)
	MUTATOR_HOOKFUNCTION (cts, ForbidPlayerScore_Clear)
	MUTATOR_HOOKFUNCTION (cts, ForbidThrowCurrentWeapon)
	MUTATOR_HOOKFUNCTION (cts, GetPressedKeys)
	MUTATOR_HOOKFUNCTION (cts, GetRecords)
	MUTATOR_HOOKFUNCTION (cts, HavocBot_ChooseRole)
	MUTATOR_HOOKFUNCTION (cts, MakePlayerObserver)
	MUTATOR_HOOKFUNCTION (cts, MonsterDropItem)
	MUTATOR_HOOKFUNCTION (cts, PlayerDamaged)
	MUTATOR_HOOKFUNCTION (cts, PlayerDies)
	MUTATOR_HOOKFUNCTION (cts, PlayerPhysics)
	MUTATOR_HOOKFUNCTION (cts, PlayerSpawn)
	MUTATOR_HOOKFUNCTION (cts, PutClientInServer)
	MUTATOR_HOOKFUNCTION (cts, Race_FinalCheckpoint)
	MUTATOR_HOOKFUNCTION (cts, reset_map_global)
	MUTATOR_HOOKFUNCTION (cts, WantWeapon)

Variables
bool	autocvar_g_cts_drop_monster_items
float	autocvar_g_cts_finish_kill_delay
bool	autocvar_g_cts_removeprojectiles
bool	autocvar_g_cts_selfdamage
float	race_checkpoint

Function Documentation

cts_EventLog()

void cts_EventLog	(	string	mode,
		entity	actor )

Definition at line 69 of file sv_cts.qc.

{
    if(autocvar_sv_eventlog)
        GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
}

References autocvar_sv_eventlog, entity(), ftos(), GameLogEcho(), NULL, and strcat().

Referenced by MUTATOR_HOOKFUNCTION().

cts_Initialize()

void cts_Initialize

(

)

Definition at line 375 of file sv_cts.qc.

{
    record_type = CTS_RECORD;
    cts_ScoreRules();
}

References CTS_RECORD, cts_ScoreRules(), and record_type.

Referenced by REGISTER_MUTATOR().

cts_ScoreRules()

void cts_ScoreRules

(

)

Definition at line 55 of file sv_cts.qc.

{
    GameRules_score_enabled(false);
    GameRules_scoring(0, 0, 0, {
        if (g_race_qualifying) {
            field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
        } else {
            field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
            field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
            field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
        }
    });
}

References g_race_qualifying, GameRules_score_enabled, GameRules_scoring, SFL_LOWER_IS_BETTER, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_SECONDARY, and SFL_TIME.

Referenced by cts_Initialize(), and MUTATOR_HOOKFUNCTION().

havocbot_role_cts()

void havocbot_role_cts

(

entity

this

)

Definition at line 19 of file sv_cts.qc.

{
    if(IS_DEAD(this))
        return;
 
    if (navigation_goalrating_timeout(this))
    {
        navigation_goalrating_start(this);
 
        bool raw_touch_check = true;
        int cp = this.race_checkpoint;
 
        LABEL(search_racecheckpoints)
        IL_EACH(g_racecheckpoints, true,
        {
            if(it.cnt == cp || cp == -1)
            {
                // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
                // e.g. checkpoint in front of Stormkeep's warpzone
                // the same workaround is applied in Race gametype
                if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
                {
                    cp = race_NextCheckpoint(cp);
                    raw_touch_check = false;
                    goto search_racecheckpoints;
                }
                navigation_routerating(this, it, 1000000, 5000);
            }
        });
 
        navigation_goalrating_end(this);
 
        navigation_goalrating_timeout_set(this);
    }
}

References entity(), g_racecheckpoints, IL_EACH, IS_DEAD, LABEL, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), navigation_routerating(), origin, race_checkpoint, race_NextCheckpoint(), and vdist.

Referenced by MUTATOR_HOOKFUNCTION().

MUTATOR_HOOKFUNCTION() [1/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		AbortSpeedrun	)

Definition at line 186 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    if(autocvar_g_allow_checkpoints)
        race_PreparePlayer(player); // nice try
}

References autocvar_g_allow_checkpoints, entity(), M_ARGV, and race_PreparePlayer().

MUTATOR_HOOKFUNCTION() [2/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		ClientConnect	)

Definition at line 176 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    race_PreparePlayer(player);
    player.race_checkpoint = -1;
 
    race_SendAll(player, false);
}

References ClientConnect, entity(), M_ARGV, race_PreparePlayer(), and race_SendAll().

MUTATOR_HOOKFUNCTION() [3/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		ClientKill	)

Definition at line 342 of file sv_cts.qc.

{
    M_ARGV(1, float) = 0; // kill delay
}

References ClientKill, and M_ARGV.

MUTATOR_HOOKFUNCTION() [4/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		Damage_Calculate	)

Definition at line 300 of file sv_cts.qc.

{
    entity frag_attacker = M_ARGV(1, entity);
    entity frag_target = M_ARGV(2, entity);
    float frag_deathtype = M_ARGV(3, float);
    float frag_damage = M_ARGV(4, float);
 
    if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
    if(!autocvar_g_cts_selfdamage)
    {
        frag_damage = 0;
        M_ARGV(4, float) = frag_damage;
    }
}

References autocvar_g_cts_selfdamage, entity(), frag_damage, frag_target, and M_ARGV.

MUTATOR_HOOKFUNCTION() [5/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		FilterItem	)

Definition at line 282 of file sv_cts.qc.

{
    entity item = M_ARGV(0, entity);
 
    if (ITEM_IS_LOOT(item))
    {
        if(item.monster_item && autocvar_g_cts_drop_monster_items)
            return false;
        return true;
    }
}

References autocvar_g_cts_drop_monster_items, entity(), ITEM_IS_LOOT, and M_ARGV.

MUTATOR_HOOKFUNCTION() [6/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		FixClientCvars	)

Definition at line 356 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
}

References entity(), FixClientCvars(), M_ARGV, and stuffcmd.

MUTATOR_HOOKFUNCTION() [7/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		ForbidDropCurrentWeapon	)

Definition at line 370 of file sv_cts.qc.

{
    return true;
}

MUTATOR_HOOKFUNCTION() [8/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		ForbidPlayerScore_Clear	)

Definition at line 315 of file sv_cts.qc.

{
    return true; // in CTS, you don't lose score by observing
}

MUTATOR_HOOKFUNCTION() [9/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		ForbidThrowCurrentWeapon	)

Definition at line 276 of file sv_cts.qc.

{
    // no weapon dropping in CTS
    return true;
}

MUTATOR_HOOKFUNCTION() [10/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		GetPressedKeys	)

Definition at line 268 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    race_checkAndWriteName(player);
    race_SpeedAwardFrame(player);
}

References entity(), GetPressedKeys(), M_ARGV, race_checkAndWriteName(), and race_SpeedAwardFrame().

MUTATOR_HOOKFUNCTION() [11/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		GetRecords	)

Definition at line 320 of file sv_cts.qc.

{
    int record_page = M_ARGV(0, int);
    string ret_string = M_ARGV(1, string);
 
    for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
    {
        if(MapInfo_Get_ByID(i))
        {
            float r = race_readTime(MapInfo_Map_bspname, 1);
 
            if(!r)
                continue;
 
            string h = race_readName(MapInfo_Map_bspname, 1);
            ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r, false)), " ", h, "\n");
        }
    }
 
    M_ARGV(1, string) = ret_string;
}

References M_ARGV, MapInfo_count, MapInfo_Get_ByID(), MapInfo_Map_bspname, race_readName(), race_readTime(), strcat(), and TIME_ENCODED_TOSTRING.

MUTATOR_HOOKFUNCTION() [12/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		HavocBot_ChooseRole	)

Definition at line 260 of file sv_cts.qc.

{
    entity bot = M_ARGV(0, entity);
 
    bot.havocbot_role = havocbot_role_cts;
    return true;
}

References entity(), havocbot_role_cts(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [13/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		MakePlayerObserver	)

Definition at line 194 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    if(GameRules_scoring_add(player, RACE_FASTEST, 0))
        player.frags = FRAGS_PLAYER_OUT_OF_GAME;
    else
        player.frags = FRAGS_SPECTATOR;
 
    race_PreparePlayer(player);
    player.race_checkpoint = -1;
}

References entity(), FRAGS_PLAYER_OUT_OF_GAME, FRAGS_SPECTATOR, GameRules_scoring_add, M_ARGV, and race_PreparePlayer().

MUTATOR_HOOKFUNCTION() [14/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		MonsterDropItem	)

Definition at line 294 of file sv_cts.qc.

{
    if(!autocvar_g_cts_drop_monster_items)
        M_ARGV(1, string) = "";
}

References autocvar_g_cts_drop_monster_items, and M_ARGV.

MUTATOR_HOOKFUNCTION() [15/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		PlayerDamaged	)

Definition at line 239 of file sv_cts.qc.

{
    return true; // forbid logging damage
}

MUTATOR_HOOKFUNCTION() [16/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		PlayerDies	)

Definition at line 244 of file sv_cts.qc.

{
    entity frag_target = M_ARGV(2, entity);
 
    frag_target.respawn_flags |= RESPAWN_FORCE;
    race_AbandonRaceCheck(frag_target);
 
    if(autocvar_g_cts_removeprojectiles)
    {
        IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
        {
            delete(it);
        });
    }
}

References autocvar_g_cts_removeprojectiles, entity(), FL_PROJECTILE, frag_target, g_projectiles, IL_EACH, M_ARGV, race_AbandonRaceCheck(), and RESPAWN_FORCE.

MUTATOR_HOOKFUNCTION() [17/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		PlayerPhysics	)

Definition at line 75 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
    float dt = M_ARGV(1, float);
 
    player.race_movetime_frac += dt;
    float f = floor(player.race_movetime_frac);
    player.race_movetime_frac -= f;
    player.race_movetime_count += f;
    player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
 
    if(IS_PLAYER(player))
    {
        if (player.race_penalty)
            if (time > player.race_penalty)
                player.race_penalty = 0;
        if(player.race_penalty)
        {
            player.velocity = '0 0 0';
            set_movetype(player, MOVETYPE_NONE);
            player.disableclientprediction = 2;
        }
    }
 
    // force kbd movement for fairness
    float wishspeed;
    vector wishvel;
 
    // if record times matter
    // ensure nothing EVIL is being done (i.e. div0_evade)
    // this hinders joystick users though
    // but it still gives SOME analog control
    wishvel.x = fabs(CS(player).movement.x);
    wishvel.y = fabs(CS(player).movement.y);
    if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
    {
        wishvel.z = 0;
        wishspeed = vlen(wishvel);
        if(wishvel.x >= 2 * wishvel.y)
        {
            // pure X motion
            if(CS(player).movement.x > 0)
                CS(player).movement_x = wishspeed;
            else
                CS(player).movement_x = -wishspeed;
            CS(player).movement_y = 0;
        }
        else if(wishvel.y >= 2 * wishvel.x)
        {
            // pure Y motion
            CS(player).movement_x = 0;
            if(CS(player).movement.y > 0)
                CS(player).movement_y = wishspeed;
            else
                CS(player).movement_y = -wishspeed;
        }
        else
        {
            // diagonal
            if(CS(player).movement.x > 0)
                CS(player).movement_x = M_SQRT1_2 * wishspeed;
            else
                CS(player).movement_x = -M_SQRT1_2 * wishspeed;
            if(CS(player).movement.y > 0)
                CS(player).movement_y = M_SQRT1_2 * wishspeed;
            else
                CS(player).movement_y = -M_SQRT1_2 * wishspeed;
        }
    }
}

References CS(), entity(), fabs(), floor(), IS_PLAYER, M_ARGV, M_SQRT1_2, movement, MOVETYPE_NONE, set_movetype(), time, vector, and vlen().

MUTATOR_HOOKFUNCTION() [18/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		PlayerSpawn	)

Definition at line 207 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
    entity spawn_spot = M_ARGV(1, entity);
 
    if(spawn_spot.target == "")
        // Emergency: this wasn't a real spawnpoint. Can this ever happen?
        race_PreparePlayer(player);
 
    // if we need to respawn, do it right
    player.race_respawn_checkpoint = player.race_checkpoint;
    player.race_respawn_spotref = spawn_spot;
 
    player.race_place = 0;
}

References entity(), M_ARGV, and race_PreparePlayer().

MUTATOR_HOOKFUNCTION() [19/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		PutClientInServer	)

Definition at line 223 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    if(IS_PLAYER(player))
    if(!game_stopped)
    {
        if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
            race_PreparePlayer(player);
        else // respawn
            race_RetractPlayer(player);
 
        race_AbandonRaceCheck(player);
    }
}

References CS(), entity(), FRAGS_SPECTATOR, g_race_qualifying, game_stopped, IS_PLAYER, killcount, M_ARGV, PutClientInServer, race_AbandonRaceCheck(), race_PreparePlayer(), and race_RetractPlayer().

MUTATOR_HOOKFUNCTION() [20/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		Race_FinalCheckpoint	)

Definition at line 347 of file sv_cts.qc.

{
    entity player = M_ARGV(0, entity);
 
    // useful to prevent cheating by running back to the start line and starting out with more speed
    if(autocvar_g_cts_finish_kill_delay)
        ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
}

References autocvar_g_cts_finish_kill_delay, ClientKill_Silent(), entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [21/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		reset_map_global	)

Definition at line 146 of file sv_cts.qc.

{
    float s;
 
    Score_NicePrint(NULL);
 
    race_ClearRecords();
    PlayerScore_Sort(race_place, 0, true, false);
 
    FOREACH_CLIENT(true, {
        if(it.race_place)
        {
            s = GameRules_scoring_add(it, RACE_FASTEST, 0);
            if(!s)
                it.race_place = 0;
        }
        cts_EventLog(ftos(it.race_place), it);
    });
 
    if(g_race_qualifying == 2)
    {
        g_race_qualifying = 0;
        independent_players = 0;
        cvar_set("fraglimit", ftos(race_fraglimit));
        cvar_set("leadlimit", ftos(race_leadlimit));
        cvar_set("timelimit", ftos(race_timelimit));
        cts_ScoreRules();
    }
}

References cts_EventLog(), cts_ScoreRules(), cvar_set(), FOREACH_CLIENT, ftos(), g_race_qualifying, GameRules_scoring_add, independent_players, NULL, PlayerScore_Sort(), race_ClearRecords(), race_fraglimit, race_leadlimit, race_place, race_timelimit, and Score_NicePrint().

MUTATOR_HOOKFUNCTION() [22/22]

MUTATOR_HOOKFUNCTION	(	cts	,
		WantWeapon	)

Definition at line 363 of file sv_cts.qc.

{
    M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
    M_ARGV(3, bool) = true; // want mutator blocked
    return true;
}

References entity(), and M_ARGV.

Variable Documentation

autocvar_g_cts_drop_monster_items

bool autocvar_g_cts_drop_monster_items

Definition at line 15 of file sv_cts.qc.

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

autocvar_g_cts_finish_kill_delay

float autocvar_g_cts_finish_kill_delay

Definition at line 12 of file sv_cts.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_cts_removeprojectiles

bool autocvar_g_cts_removeprojectiles

Definition at line 14 of file sv_cts.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_cts_selfdamage

bool autocvar_g_cts_selfdamage

Definition at line 13 of file sv_cts.qc.

Referenced by MUTATOR_HOOKFUNCTION().

race_checkpoint

float race_checkpoint

Definition at line 18 of file sv_cts.qc.