button.qc File Reference

#include "button.qh"

Include dependency graph for button.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	button_blocked (entity this, entity blocker)
void	button_damage (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	button_done (entity this)
void	button_fire (entity this)
void	button_reset (entity this)
void	button_return (entity this)
void	button_setactive (entity this, int astate)
void	button_touch (entity this, entity toucher)
void	button_use (entity this, entity actor, entity trigger)
void	button_wait (entity this)
	spawnfunc (func_button)

Variables
float	activation_time
float	wait_remaining

Function Documentation

button_blocked()

void button_blocked	(	entity	this,
		entity	blocker )

Definition at line 78 of file button.qc.

{
    // do nothing, just don't come all the way back out
}

References entity().

Referenced by spawnfunc().

button_damage()

void button_damage	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 142 of file button.qc.

{
    if (this.active != ACTIVE_ACTIVE)
        return;
    if(this.spawnflags & NOSPLASH)
        if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
            return;
    if (this.spawnflags & BUTTON_DONTACCUMULATEDMG)
    {
        if (GetResource(this, RES_HEALTH) <= damage)
        {
            this.enemy = attacker;
            button_fire(this);
        }
    }
    else
    {
        TakeResource(this, RES_HEALTH, damage);
        if (GetResource(this, RES_HEALTH) <= 0)
        {
            this.enemy = attacker;
            button_fire(this);
        }
    }
}

References active, ACTIVE_ACTIVE, BUTTON_DONTACCUMULATEDMG, button_fire(), DEATH_ISSPECIAL, enemy, entity(), GetResource(), HITTYPE_SPLASH, NOSPLASH, spawnflags, TakeResource(), and vector.

Referenced by spawnfunc().

button_done()

void button_done

(

entity

this

)

Definition at line 57 of file button.qc.

{
    this.state = STATE_BOTTOM;
}

References entity(), state, and STATE_BOTTOM.

Referenced by button_return().

button_fire()

void button_fire

(

entity

this

)

Definition at line 84 of file button.qc.

{
    SetResourceExplicit(this, RES_HEALTH, this.max_health);
    this.takedamage = DAMAGE_NO;    // will be reset upon return
 
    if (this.state == STATE_UP || this.state == STATE_TOP)
        return;
 
    this.activation_time = time;
 
    if (this.noise != "")
        _sound (this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 
    this.state = STATE_UP;
    SUB_CalcMove (this, this.pos2, TSPEED_LINEAR, this.speed, button_wait);
}

References _sound, activation_time, ATTEN_NORM, button_wait(), CH_TRIGGER, DAMAGE_NO, entity(), max_health, noise, pos2, SetResourceExplicit(), speed, state, STATE_TOP, STATE_UP, SUB_CalcMove(), takedamage, time, TSPEED_LINEAR, and VOL_BASE.

Referenced by button_damage(), button_touch(), and button_use().

button_reset()

void button_reset

(

entity

this

)

Definition at line 101 of file button.qc.

{
    SetResourceExplicit(this, RES_HEALTH, this.max_health);
    setorigin(this, this.pos1);
    this.frame = 0;            // use normal textures
    this.state = STATE_BOTTOM;
    this.velocity = '0 0 0';
    this.wait_remaining = -1;
    this.activation_time = -1;
    this.active = ACTIVE_ACTIVE;
    setthink(this, func_null);
    this.nextthink = 0;
    if (GetResource(this, RES_HEALTH))
        this.takedamage = DAMAGE_YES;   // can be shot again
}

References activation_time, active, ACTIVE_ACTIVE, DAMAGE_YES, entity(), frame, func_null(), GetResource(), max_health, nextthink, pos1, SetResourceExplicit(), setthink, state, STATE_BOTTOM, takedamage, velocity, and wait_remaining.

Referenced by spawnfunc().

button_return()

void button_return

(

entity

this

)

Definition at line 62 of file button.qc.

{
    if (this.active != ACTIVE_ACTIVE)
    {
        return;
    }
    this.state = STATE_DOWN;
    SUB_CalcMove (this, this.pos1, TSPEED_LINEAR, this.speed, button_done);
    this.frame = 0;            // use normal textures
    if (GetResource(this, RES_HEALTH))
        this.takedamage = DAMAGE_YES;   // can be shot again
    this.wait_remaining = -1;
    this.activation_time = -1;
}

References activation_time, active, ACTIVE_ACTIVE, button_done(), DAMAGE_YES, entity(), frame, GetResource(), pos1, speed, state, STATE_DOWN, SUB_CalcMove(), takedamage, TSPEED_LINEAR, and wait_remaining.

Referenced by button_setactive(), and button_wait().

button_setactive()

void button_setactive	(	entity	this,
		int	astate )

Definition at line 13 of file button.qc.

{
    int oldstate = this.active;
    if (astate == ACTIVE_TOGGLE)
    {
        if (this.active == ACTIVE_ACTIVE)
            this.active = ACTIVE_NOT;
        else
            this.active = ACTIVE_ACTIVE;
    }
    else
        this.active = astate;
 
    if (this.active == ACTIVE_ACTIVE && oldstate == ACTIVE_NOT)
    {
        // button was deactivated while it was pressed
        if (this.wait_remaining >= 0)
        {
            this.nextthink =  this.wait_remaining + this.ltime;
            setthink(this, button_return);
        }
    }
    else if (this.active == ACTIVE_NOT && oldstate == ACTIVE_ACTIVE)
    {
        // check if button is in pressed state
        if (this.activation_time >= 0)
        {
            this.wait_remaining = this.wait - (time - this.activation_time);
        }
    }
}

References activation_time, active, ACTIVE_ACTIVE, ACTIVE_NOT, ACTIVE_TOGGLE, button_return(), entity(), ltime, nextthink, setthink, time, wait, and wait_remaining.

Referenced by spawnfunc().

button_touch()

void button_touch	(	entity	this,
		entity	toucher )

Definition at line 126 of file button.qc.

{
    if (this.active != ACTIVE_ACTIVE)
        return;
    if (!toucher)
        return;
    if (!toucher.iscreature)
        return;
    if(toucher.velocity * this.movedir < 0)
        return;
    this.enemy = toucher;
    if (toucher.owner)
        this.enemy = toucher.owner;
    button_fire (this);
}

References active, ACTIVE_ACTIVE, button_fire(), enemy, entity(), and toucher.

Referenced by spawnfunc().

button_use()

void button_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 117 of file button.qc.

{
    if(this.active != ACTIVE_ACTIVE)
        return;
 
    this.enemy = actor;
    button_fire(this);
}

References active, ACTIVE_ACTIVE, button_fire(), enemy, and entity().

Referenced by spawnfunc().

button_wait()

void button_wait

(

entity

this

)

Definition at line 45 of file button.qc.

{
    this.state = STATE_TOP;
    if(this.wait >= 0)
    {
        this.nextthink = this.ltime + this.wait;
        setthink(this, button_return);
    }
    SUB_UseTargets(this, this.enemy, NULL);
    this.frame = 1;            // use alternate textures
}

References button_return(), enemy, entity(), frame, ltime, nextthink, NULL, setthink, state, STATE_TOP, SUB_UseTargets(), and wait.

Referenced by button_fire().

spawnfunc()

spawnfunc

(

func_button

)

Definition at line 180 of file button.qc.

{
    SetMovedir(this);
 
    if (!InitMovingBrushTrigger(this))
        return;
    this.effects |= EF_LOWPRECISION;
 
    setblocked(this, button_blocked);
    this.use = button_use;
 
//  if (this.health == 0) // all buttons are now shootable
//      this.health = 10;
    if (GetResource(this, RES_HEALTH))
    {
        this.max_health = GetResource(this, RES_HEALTH);
        this.event_damage = button_damage;
        this.takedamage = DAMAGE_YES;
    }
    else
        settouch(this, button_touch);
 
    if (!this.speed)
        this.speed = 40;
    if (!this.wait)
        this.wait = 1;
    if (!this.lip)
        this.lip = 4;
 
    if(this.wait < 0 && q3compat)
        this.wait = 0.1; // compatibility for q3: -1 = return immediately
 
    if(this.noise != "")
        precache_sound(this.noise);
 
    this.draggable = drag_undraggable;
 
    this.setactive = button_setactive;
 
    this.pos1 = this.origin;
    this.pos2 = this.pos1 + this.movedir*(fabs(this.movedir*this.size) - this.lip);
    this.flags |= FL_NOTARGET;
 
    this.reset = button_reset;
 
    button_reset(this);
}

References button_blocked(), button_damage(), button_reset(), button_setactive(), button_touch(), button_use(), DAMAGE_YES, drag_undraggable(), EF_LOWPRECISION, effects, fabs(), FL_NOTARGET, flags, GetResource(), InitMovingBrushTrigger(), lip, max_health, movedir, noise, origin, pos1, pos2, precache_sound(), q3compat, setblocked, SetMovedir(), settouch, size, speed, takedamage, use, and wait.

Variable Documentation

activation_time

float activation_time

Definition at line 11 of file button.qc.

Referenced by button_fire(), button_reset(), button_return(), and button_setactive().

wait_remaining

float wait_remaining

Definition at line 10 of file button.qc.

Referenced by button_reset(), button_return(), and button_setactive().