seeker.qc File Reference

#include "seeker.qh"
#include <common/items/item/ammo.qh>

Include dependency graph for seeker.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	W_Seeker_Attack (Weapon thiswep, entity actor,.entity weaponentity)
void	W_Seeker_Fire_Flac (Weapon thiswep, entity actor,.entity weaponentity)
void	W_Seeker_Fire_Missile (Weapon thiswep, entity actor,.entity weaponentity, entity m_target, int bullet_count)
void	W_Seeker_Fire_Tag (Weapon thiswep, entity actor,.entity weaponentity)
void	W_Seeker_Flac_Explode (entity this, entity directhitentity)
void	W_Seeker_Flac_Explode_use (entity this, entity actor, entity trigger)
void	W_Seeker_Flac_Touch (entity this, entity toucher)
void	W_Seeker_Missile_Damage (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	W_Seeker_Missile_Explode (entity this, entity directhitentity)
void	W_Seeker_Missile_Explode_think (entity this)
void	W_Seeker_Missile_Think (entity this)
void	W_Seeker_Missile_Touch (entity this, entity toucher)
void	W_Seeker_Tag_Damage (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	W_Seeker_Tag_Delete (entity this)
void	W_Seeker_Tag_Explode (entity this)
void	W_Seeker_Tag_Think (entity this)
	Think function, only for guided tags.
void	W_Seeker_Tag_Touch (entity this, entity toucher)
entity	W_Seeker_Tagged_Info (entity isowner,.entity weaponentity, entity istarget)
void	W_Seeker_Tracker_Think (entity this)
void	W_Seeker_Vollycontroller_Think (entity this)

Variables
entity	lasttag

Function Documentation

W_Seeker_Attack()

void W_Seeker_Attack	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity )

Definition at line 284 of file seeker.qc.

{
    entity closest = NULL;
    vector it_trans_org;
    float it_dist2, closest_dist2 = 0;
    IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == actor,
    {
        // First check line of sight
        it_trans_org = WarpZone_RefSys_TransformOrigin(it.tag_target, actor, it.tag_target.origin);
        WarpZone_TraceLine(actor.origin + actor.view_ofs, it_trans_org, MOVE_NOMONSTERS, actor);
        if (trace_fraction < 1 && trace_ent != it)
            continue;
 
        it_dist2 = vlen2(actor.origin - it_trans_org);
        if (!closest || it_dist2 < closest_dist2) // new closest
        {
            closest_dist2 = it_dist2;
            closest = it.tag_target;
        }
    });
 
    W_Seeker_Fire_Missile(thiswep, actor, weaponentity, closest, -1);
}

References entity(), g_seeker_trackers, IL_EACH, NULL, and vector.

W_Seeker_Fire_Flac()

void W_Seeker_Fire_Flac	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity )

Definition at line 227 of file seeker.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR(WEP_SEEKER, flac_ammo), weaponentity);
 
    vector old_movedir = actor.(weaponentity).movedir;
    actor.(weaponentity).movedir += W_SetupShot_GetAlternatingOffset(actor.(weaponentity).bulletcounter);
    W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(WEP_SEEKER, flac_damage), thiswep.m_id | HITTYPE_SECONDARY);
    actor.(weaponentity).movedir = old_movedir;
 
    // uses hagar effects!
    W_MuzzleFlash(WEP_HAGAR, actor, weaponentity, w_shotorg, w_shotdir);
 
    entity missile;
    missile = new(missile);
    missile.owner = missile.realowner = actor;
    missile.bot_dodge = true;
    missile.bot_dodgerating = WEP_CVAR(WEP_SEEKER, flac_damage);
    settouch(missile, W_Seeker_Flac_Touch);
    missile.use = W_Seeker_Flac_Explode_use;
    setthink(missile, adaptor_think2use_hittype_splash);
    missile.nextthink = time + WEP_CVAR(WEP_SEEKER, flac_lifetime) + WEP_CVAR(WEP_SEEKER, flac_lifetime_rand);
    set_movetype(missile, MOVETYPE_FLY);
    missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
    missile.weaponentity_fld = weaponentity;
    missile.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, missile);
    IL_PUSH(g_bot_dodge, missile);
    missile.missile_flags = MIF_SPLASH;
 
    // csqc projectiles
    //missile.angles = vectoangles(missile.velocity);
    //missile.scale = 0.4; // BUG: the model is too big
 
    PROJECTILE_MAKETRIGGER(missile);
    setorigin(missile, w_shotorg);
    setsize(missile, '-2 -2 -2', '2 2 2');
 
    W_SetupProjVelocity_UP_PRE(missile, WEP_SEEKER, flac_);
    CSQCProjectile(missile, true, PROJECTILE_SEEKER_FLAC, true);
 
    MUTATOR_CALLHOOK(EditProjectile, actor, missile);
}

References adaptor_think2use_hittype_splash(), CH_WEAPON_A, CSQCProjectile(), entity(), FL_PROJECTILE, g_bot_dodge, g_projectiles, HITTYPE_SECONDARY, IL_PUSH(), Weapon::m_id, MIF_SPLASH, movedir, MOVETYPE_FLY, MUTATOR_CALLHOOK, PROJECTILE_MAKETRIGGER, PROJECTILE_SEEKER_FLAC, set_movetype(), setthink, settouch, time, vector, W_DecreaseAmmo(), W_MuzzleFlash(), W_Seeker_Flac_Explode_use(), W_Seeker_Flac_Touch(), W_SetupProjVelocity_UP_PRE, W_SetupShot_GetAlternatingOffset(), W_SetupShot_ProjectileSize, w_shotdir, w_shotorg, and WEP_CVAR.

W_Seeker_Fire_Missile()

void W_Seeker_Fire_Missile	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		entity	m_target,
		int	bullet_count )

Definition at line 135 of file seeker.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR(WEP_SEEKER, missile_ammo), weaponentity);
 
    makevectors(actor.v_angle);
    vector old_movedir = actor.(weaponentity).movedir;
    if (bullet_count > 0)
        actor.(weaponentity).movedir += W_SetupShot_GetAlternatingOffset(bullet_count);
    W_SetupShot_ProjectileSize(actor, weaponentity, '-4 -4 -4', '4 4 4', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0, ((m_target != NULL) ? thiswep.m_id | HITTYPE_SECONDARY : thiswep.m_id));
    actor.(weaponentity).movedir = old_movedir;
    W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 
    //actor.detornator = false;
 
    entity missile = new(seeker_missile);
    WarpZone_RefSys_Copy(missile, actor);
    missile.owner = missile.realowner = actor;
    missile.bot_dodge = true;
    missile.bot_dodgerating = WEP_CVAR(WEP_SEEKER, missile_damage);
 
    setthink(missile, W_Seeker_Missile_Think);
    settouch(missile, W_Seeker_Missile_Touch);
    missile.event_damage = W_Seeker_Missile_Damage;
    missile.nextthink = time; // + 0.2; // + cvar("g_balance_seeker_missile_activate_delay");
    missile.cnt = time + WEP_CVAR(WEP_SEEKER, missile_lifetime);
    missile.enemy = m_target;
    missile.scale = 2;
    missile.takedamage = DAMAGE_YES;
    missile.weaponentity_fld = weaponentity;
    SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(WEP_SEEKER, missile_health));
    missile.damageforcescale = WEP_CVAR(WEP_SEEKER, missile_damageforcescale);
    missile.damagedbycontents = true;
    IL_PUSH(g_damagedbycontents, missile);
    //missile.think = W_Seeker_Missile_Animate; // csqc projectiles.
 
    if (missile.enemy != NULL)
        missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
    else
        missile.projectiledeathtype = thiswep.m_id;
 
    PROJECTILE_MAKETRIGGER(missile);
    setorigin(missile, w_shotorg);
    setsize(missile, '-4 -4 -4', '4 4 4');
    set_movetype(missile, MOVETYPE_FLYMISSILE);
    missile.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, missile);
    IL_PUSH(g_bot_dodge, missile);
    missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 
    W_SetupProjVelocity_UP_PRE(missile, WEP_SEEKER, missile_);
 
    missile.angles = vectoangles(missile.velocity);
 
    CSQCProjectile(missile, false, PROJECTILE_SEEKER_MISSILE, true);
 
    MUTATOR_CALLHOOK(EditProjectile, actor, missile);
}

References CH_WEAPON_A, CSQCProjectile(), DAMAGE_YES, entity(), FL_PROJECTILE, g_bot_dodge, g_damagedbycontents, g_projectiles, HITTYPE_SECONDARY, IL_PUSH(), Weapon::m_id, makevectors, MIF_GUIDED_TAG, MIF_SPLASH, movedir, MOVETYPE_FLYMISSILE, MUTATOR_CALLHOOK, NULL, PROJECTILE_MAKETRIGGER, PROJECTILE_SEEKER_MISSILE, set_movetype(), SetResourceExplicit(), setthink, settouch, time, vectoangles(), vector, W_DecreaseAmmo(), W_MuzzleFlash(), W_Seeker_Missile_Damage(), W_Seeker_Missile_Think(), W_Seeker_Missile_Touch(), W_SetupProjVelocity_UP_PRE, W_SetupShot_GetAlternatingOffset(), W_SetupShot_ProjectileSize, w_shotdir, w_shotorg, WarpZone_RefSys_Copy(), and WEP_CVAR.

Referenced by W_Seeker_Vollycontroller_Think().

W_Seeker_Fire_Tag()

void W_Seeker_Fire_Tag	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity )

Definition at line 477 of file seeker.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR(WEP_SEEKER, tag_ammo), weaponentity);
 
    W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(WEP_SEEKER, missile_damage) * WEP_CVAR(WEP_SEEKER, missile_count), thiswep.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY);
 
    entity missile = new(seeker_tag);
    WarpZone_RefSys_Copy(missile, actor);
    if (WEP_CVAR(WEP_SEEKER, tag_guiderate) > 0)
    {
        actor.(weaponentity).lasttag = missile;
        missile.pushltime = time + WEP_CVAR(WEP_SEEKER, tag_guidedelay);
        missile.ltime = time + WEP_CVAR(WEP_SEEKER, tag_lifetime);
        missile.nextthink = time;
        setthink(missile, W_Seeker_Tag_Think);
    }
    else
    {
        missile.nextthink = time + WEP_CVAR(WEP_SEEKER, tag_lifetime);
        setthink(missile, SUB_Remove);
    }
 
    missile.owner = missile.realowner = actor;
    missile.bot_dodge = true;
    missile.bot_dodgerating = 50;
    settouch(missile, W_Seeker_Tag_Touch);
    set_movetype(missile, MOVETYPE_FLY);
    missile.projectiledeathtype = thiswep.m_id;
    missile.weaponentity_fld = weaponentity;
 
    missile.takedamage = DAMAGE_YES;
    missile.event_damage = W_Seeker_Tag_Damage;
    SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(WEP_SEEKER, tag_health));
    missile.damageforcescale = WEP_CVAR(WEP_SEEKER, tag_damageforcescale);
 
    PROJECTILE_MAKETRIGGER(missile);
    setorigin(missile, w_shotorg);
    setsize(missile, '-2 -2 -2', '2 2 2');
 
    missile.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, missile);
    IL_PUSH(g_bot_dodge, missile);
    //missile.missile_flags = MIF_..?;
 
    set_movetype(missile, MOVETYPE_FLY);
    W_SetupProjVelocity_PRE(missile, WEP_SEEKER, tag_);
    missile.angles = vectoangles(missile.velocity);
 
    CSQCProjectile(missile, fabs(WEP_CVAR(WEP_SEEKER, tag_guiderate)) <= 30, PROJECTILE_SEEKER_TAG, false); // has sound
    // Network velocity for the trail only if the guiding isn't strong,
    // or else the trail clearly goes off path (backwards)
 
    MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 
    if (time >= missile.nextthink)
        getthink(missile)(missile);
}

References CH_WEAPON_A, CSQCProjectile(), DAMAGE_YES, entity(), fabs(), FL_PROJECTILE, g_bot_dodge, g_projectiles, getthink, HITTYPE_BOUNCE, HITTYPE_SECONDARY, IL_PUSH(), lasttag, Weapon::m_id, MOVETYPE_FLY, MUTATOR_CALLHOOK, PROJECTILE_MAKETRIGGER, PROJECTILE_SEEKER_TAG, set_movetype(), SetResourceExplicit(), setthink, settouch, SUB_Remove(), time, vectoangles(), W_DecreaseAmmo(), W_Seeker_Tag_Damage(), W_Seeker_Tag_Think(), W_Seeker_Tag_Touch(), W_SetupProjVelocity_PRE, W_SetupShot_ProjectileSize, w_shotorg, WarpZone_RefSys_Copy(), and WEP_CVAR.

W_Seeker_Flac_Explode()

void W_Seeker_Flac_Explode	(	entity	this,
		entity	directhitentity )

Definition at line 196 of file seeker.qc.

{
    this.event_damage = func_null;
 
    RadiusDamage(this, this.realowner,
        WEP_CVAR(WEP_SEEKER, flac_damage),
        WEP_CVAR(WEP_SEEKER, flac_edgedamage),
        WEP_CVAR(WEP_SEEKER, flac_radius),
        NULL,
        NULL,
        WEP_CVAR(WEP_SEEKER, flac_force),
        this.projectiledeathtype,
        this.weaponentity_fld,
        directhitentity
    );
 
    delete(this);
}

References entity(), func_null(), NULL, projectiledeathtype, RadiusDamage(), realowner, weaponentity_fld, and WEP_CVAR.

Referenced by W_Seeker_Flac_Explode_use(), and W_Seeker_Flac_Touch().

W_Seeker_Flac_Explode_use()

void W_Seeker_Flac_Explode_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 222 of file seeker.qc.

{
    W_Seeker_Flac_Explode(this, trigger);
}

References entity(), and W_Seeker_Flac_Explode().

Referenced by W_Seeker_Fire_Flac().

W_Seeker_Flac_Touch()

void W_Seeker_Flac_Touch	(	entity	this,
		entity	toucher )

Definition at line 215 of file seeker.qc.

{
    PROJECTILE_TOUCH(this, toucher);
 
    W_Seeker_Flac_Explode(this, toucher);
}

References entity(), PROJECTILE_TOUCH, toucher, and W_Seeker_Flac_Explode().

Referenced by W_Seeker_Fire_Flac().

W_Seeker_Missile_Damage()

void W_Seeker_Missile_Damage	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 96 of file seeker.qc.

{
    if (GetResource(this, RES_HEALTH) <= 0)
        return;
    if (!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
        return; // g_projectiles_damage says to halt
 
    if (this.realowner == attacker)
        TakeResource(this, RES_HEALTH, (damage * 0.25));
    else
        TakeResource(this, RES_HEALTH, damage);
 
    if (GetResource(this, RES_HEALTH) <= 0)
        W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
}

References entity(), GetResource(), realowner, TakeResource(), vector, W_CheckProjectileDamage(), W_PrepareExplosionByDamage(), and W_Seeker_Missile_Explode_think().

Referenced by W_Seeker_Fire_Missile().

W_Seeker_Missile_Explode()

void W_Seeker_Missile_Explode	(	entity	this,
		entity	directhitentity )

Definition at line 8 of file seeker.qc.

{
    this.event_damage = func_null;
    RadiusDamage(this, this.realowner,
        WEP_CVAR(WEP_SEEKER, missile_damage),
        WEP_CVAR(WEP_SEEKER, missile_edgedamage),
        WEP_CVAR(WEP_SEEKER, missile_radius),
        NULL,
        NULL,
        WEP_CVAR(WEP_SEEKER, missile_force),
        this.projectiledeathtype,
        this.weaponentity_fld,
        directhitentity
    );
 
    delete(this);
}

References entity(), func_null(), NULL, projectiledeathtype, RadiusDamage(), realowner, weaponentity_fld, and WEP_CVAR.

Referenced by W_Seeker_Missile_Explode_think(), W_Seeker_Missile_Think(), and W_Seeker_Missile_Touch().

W_Seeker_Missile_Explode_think()

void W_Seeker_Missile_Explode_think

(

entity

this

)

Definition at line 26 of file seeker.qc.

{
    W_Seeker_Missile_Explode(this, NULL);
}

References entity(), NULL, and W_Seeker_Missile_Explode().

Referenced by W_Seeker_Missile_Damage().

W_Seeker_Missile_Think()

void W_Seeker_Missile_Think

(

entity

this

)

Definition at line 38 of file seeker.qc.

{
    if (time >= this.cnt)
    {
        this.projectiledeathtype |= HITTYPE_SPLASH;
        W_Seeker_Missile_Explode(this, NULL);
        return;
    }
 
    float dist = W_SeekOutEnemy(this,
        WEP_CVAR(WEP_SEEKER, missile_decel),
        WEP_CVAR(WEP_SEEKER, missile_accel),
        WEP_CVAR(WEP_SEEKER, missile_speed_max),
        WEP_CVAR(WEP_SEEKER, missile_turnrate),
        WEP_CVAR(WEP_SEEKER, missile_smart),
        WEP_CVAR(WEP_SEEKER, missile_smart_mindist),
        WEP_CVAR(WEP_SEEKER, missile_smart_trace_min),
        WEP_CVAR(WEP_SEEKER, missile_smart_trace_max));
 
    // Proxy
    if (WEP_CVAR(WEP_SEEKER, missile_proxy))
    {
        if (dist <= WEP_CVAR(WEP_SEEKER, missile_proxy_maxrange))
        {
            if (this.cvar_cl_autoswitch == 0)
                this.cvar_cl_autoswitch = time + WEP_CVAR(WEP_SEEKER, missile_proxy_delay);
            else
            {
                if (this.cvar_cl_autoswitch <= time)
                {
                    W_Seeker_Missile_Explode(this, NULL);
                    this.cvar_cl_autoswitch = 0;
                }
            }
        }
        else
        {
            if (this.cvar_cl_autoswitch != 0)
                this.cvar_cl_autoswitch = 0;
        }
    }
 
    if (IS_DEAD(this.enemy))
    {
        this.enemy = NULL;
        this.cnt = time + 1 + (random() * 4);
        this.nextthink = this.cnt;
        return;
    }
 
    //this.angles = vectoangles(this.velocity); // turn model in the new flight direction
    this.nextthink = time;// + 0.05; // csqc projectiles
    UpdateCSQCProjectile(this);
}

References cnt, enemy, entity(), HITTYPE_SPLASH, IS_DEAD, nextthink, NULL, projectiledeathtype, random(), time, UpdateCSQCProjectile(), W_Seeker_Missile_Explode(), W_SeekOutEnemy(), and WEP_CVAR.

Referenced by W_Seeker_Fire_Missile().

W_Seeker_Missile_Touch()

void W_Seeker_Missile_Touch	(	entity	this,
		entity	toucher )

Definition at line 31 of file seeker.qc.

{
    PROJECTILE_TOUCH(this, toucher);
 
    W_Seeker_Missile_Explode(this, toucher);
}

References entity(), PROJECTILE_TOUCH, toucher, and W_Seeker_Missile_Explode().

Referenced by W_Seeker_Fire_Missile().

W_Seeker_Tag_Damage()

void W_Seeker_Tag_Damage	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 375 of file seeker.qc.

{
    if (GetResource(this, RES_HEALTH) <= 0)
        return;
    TakeResource(this, RES_HEALTH, damage);
    if (GetResource(this, RES_HEALTH) <= 0)
        W_Seeker_Tag_Explode(this);
}

References entity(), GetResource(), TakeResource(), vector, and W_Seeker_Tag_Explode().

Referenced by W_Seeker_Fire_Tag().

W_Seeker_Tag_Delete()

void W_Seeker_Tag_Delete

(

entity

this

)

Definition at line 355 of file seeker.qc.

{
    for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if (this.realowner.(weaponentity).lasttag == this)
            this.realowner.(weaponentity).lasttag = NULL;
    }
    delete(this);
}

References entity(), lasttag, MAX_WEAPONSLOTS, NULL, realowner, and weaponentities.

Referenced by W_Seeker_Tag_Explode(), W_Seeker_Tag_Think(), and W_Seeker_Tag_Touch().

W_Seeker_Tag_Explode()

void W_Seeker_Tag_Explode

(

entity

this

)

Definition at line 366 of file seeker.qc.

{
    //if (other == this.realowner)
    //  return;
    Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 
    W_Seeker_Tag_Delete(this);
}

References Damage_DamageInfo(), entity(), HITTYPE_BOUNCE, origin, velocity, and W_Seeker_Tag_Delete().

Referenced by W_Seeker_Tag_Damage().

W_Seeker_Tag_Think()

void W_Seeker_Tag_Think

(

entity

this

)

Think function, only for guided tags.

Definition at line 448 of file seeker.qc.

{
    if (time >= this.ltime)
    {
        W_Seeker_Tag_Delete(this);
        return;
    }
    this.nextthink = time;
 
    // laser guided
    .entity weaponentity = this.weaponentity_fld;
    if (this.realowner.(weaponentity).m_weapon == WEP_SEEKER
    && this == this.realowner.(weaponentity).lasttag
    && !this.realowner.(weaponentity).tag_release
    && WEP_CVAR(WEP_SEEKER, tag_guiderate)
    && time > this.pushltime
    && !IS_DEAD(this.realowner))
    {
        makevectors(vec2(-this.angles.x, this.angles.y));
        W_GuideProjectile(this, weaponentity, this.pushltime,
            WEP_CVAR(WEP_SEEKER, tag_guiderate),
            WEP_CVAR(WEP_SEEKER, tag_guideratedelay),
            WEP_CVAR(WEP_SEEKER, tag_guidegoal),
            WEP_CVAR(WEP_SEEKER, tag_guidedelay),
            NULL, SND_DEVASTATOR_MODE, VOL_BASE * 0.5); // TODO: add a better sound here
        UpdateCSQCProjectile(this);
    }
}

References angles, entity(), IS_DEAD, ltime, makevectors, nextthink, NULL, pushltime, realowner, time, UpdateCSQCProjectile(), vec2, VOL_BASE, W_GuideProjectile(), W_Seeker_Tag_Delete(), weaponentity_fld, and WEP_CVAR.

Referenced by W_Seeker_Fire_Tag().

W_Seeker_Tag_Touch()

void W_Seeker_Tag_Touch	(	entity	this,
		entity	toucher )

Definition at line 384 of file seeker.qc.

{
    PROJECTILE_TOUCH(this, toucher);
 
    this.event_damage = func_null;
    Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 
    if (toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
    {
        Damage(toucher, this, this.realowner,
            WEP_CVAR(WEP_SEEKER, tag_damage),
            this.projectiledeathtype | HITTYPE_BOUNCE | HITTYPE_SECONDARY,
            this.weaponentity_fld,
            this.origin,
            '0 0 0'
        );
 
        // check to see if this person is already tagged by me
        .entity weaponentity = this.weaponentity_fld;
        entity tag = W_Seeker_Tagged_Info(this.realowner, weaponentity, toucher);
 
        if (tag != NULL)
        {
            if (toucher.wps_tag_tracker && WEP_CVAR(WEP_SEEKER, type) == 1) // don't attach another waypointsprite without killing the old one first
                WaypointSprite_Kill(toucher.wps_tag_tracker);
            tag.tag_time = time;
        }
        else
        {
            //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
            entity tracker = new(tag_tracker);
            WarpZone_RefSys_Copy(toucher, this); // toucher is in the same reference as the tag, since the tag hit the toucher
            tracker.weaponentity_fld = this.weaponentity_fld;
            tracker.cnt = WEP_CVAR(WEP_SEEKER, missile_count);
            tracker.owner = this.owner;
            tracker.realowner = this.realowner;
            IL_PUSH(g_seeker_trackers, tracker);
 
            if (WEP_CVAR(WEP_SEEKER, type) == 1)
            {
                tracker.tag_target = toucher;
                tracker.tag_time = time;
                setthink(tracker, W_Seeker_Tracker_Think);
            }
            else
            {
                tracker.enemy = toucher;
                setthink(tracker, W_Seeker_Vollycontroller_Think);
            }
 
            tracker.nextthink = time;
        }
 
        if (WEP_CVAR(WEP_SEEKER, type) == 1)
        {
            WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(WEP_SEEKER, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
            WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
        }
    }
 
    W_Seeker_Tag_Delete(this);
}

References Damage(), DAMAGE_AIM, Damage_DamageInfo(), entity(), func_null(), g_seeker_trackers, HITTYPE_BOUNCE, HITTYPE_SECONDARY, IL_PUSH(), IS_DEAD, NULL, origin, owner, PROJECTILE_TOUCH, projectiledeathtype, realowner, setthink, SPRITERULE_DEFAULT, time, toucher, velocity, W_Seeker_Tag_Delete(), W_Seeker_Tagged_Info(), W_Seeker_Tracker_Think(), W_Seeker_Vollycontroller_Think(), WarpZone_RefSys_Copy(), WaypointSprite_Kill(), WaypointSprite_Spawn(), WaypointSprite_UpdateRule(), weaponentity_fld, WEP_CVAR, and wps_tag_tracker.

Referenced by W_Seeker_Fire_Tag().

W_Seeker_Tagged_Info()

entity W_Seeker_Tagged_Info	(	entity	isowner,
		.entity	weaponentity,
		entity	istarget )

Definition at line 273 of file seeker.qc.

{
    IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == isowner,
    {
        if (it.tag_target == istarget && it.weaponentity_fld == weaponentity)
            return it;
    });
 
    return NULL;
}

References entity(), g_seeker_trackers, IL_EACH, and NULL.

Referenced by W_Seeker_Tag_Touch().

W_Seeker_Tracker_Think()

void W_Seeker_Tracker_Think

(

entity

this

)

Definition at line 331 of file seeker.qc.

{
    .entity weaponentity = this.weaponentity_fld;
    // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
    if (IS_DEAD(this.realowner) || IS_DEAD(this.tag_target) || this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER
    || (time > this.tag_time + WEP_CVAR(WEP_SEEKER, tag_tracker_lifetime)))
    {
        if (this)
        {
            WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
            delete(this);
        }
        return;
    }
 
    // Update the think method information
    this.nextthink = time;
}

References entity(), IS_DEAD, nextthink, realowner, tag_target, time, WaypointSprite_Kill(), weaponentity_fld, and WEP_CVAR.

Referenced by W_Seeker_Tag_Touch().

W_Seeker_Vollycontroller_Think()

void W_Seeker_Vollycontroller_Think

(

entity

this

)

Definition at line 308 of file seeker.qc.

{
    --this.cnt;
 
    Weapon thiswep = WEP_SEEKER;
    .entity weaponentity = this.weaponentity_fld;
    if ((!(this.realowner.items & IT_UNLIMITED_AMMO) && GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(WEP_SEEKER, missile_ammo))
    || this.cnt <= -1 || IS_DEAD(this.realowner) || this.realowner.(weaponentity).m_switchweapon != thiswep)
    {
        delete(this);
        return;
    }
 
    this.nextthink = time + WEP_CVAR(WEP_SEEKER, missile_delay) * W_WeaponRateFactor(this.realowner);
 
    entity own = this.realowner;
 
    entity oldenemy = own.enemy;
    own.enemy = this.enemy;
    W_Seeker_Fire_Missile(thiswep, own, weaponentity, own.enemy, own.cnt);
    own.enemy = oldenemy;
}

References Weapon::ammo_type, cnt, enemy, entity(), GetResource(), IS_DEAD, IT_UNLIMITED_AMMO, nextthink, realowner, time, W_Seeker_Fire_Missile(), W_WeaponRateFactor(), weaponentity_fld, and WEP_CVAR.

Referenced by W_Seeker_Tag_Touch().

Variable Documentation

lasttag

entity lasttag

Definition at line 353 of file seeker.qc.

Referenced by W_Seeker_Fire_Tag(), and W_Seeker_Tag_Delete().