teleport.qc File Reference

#include "teleport.qh"

Include dependency graph for teleport.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
	spawnfunc (target_teleporter)
	spawnfunc (trigger_teleport)
void	target_teleport_use (entity this, entity actor, entity trigger)
void	target_teleporter_checktarget (entity this)
bool	Teleport_Active (entity this, entity player)
void	Teleport_Touch (entity this, entity toucher)
void	trigger_teleport_link (entity this)
float	trigger_teleport_send (entity this, entity to, float sf)
void	trigger_teleport_use (entity this, entity actor, entity trigger)

Function Documentation

spawnfunc() [1/2]

spawnfunc

(

target_teleporter

)

Definition at line 187 of file teleport.qc.

{
    InitializeEntity(this, target_teleporter_checktarget, INITPRIO_FINDTARGET);
}

References InitializeEntity(), INITPRIO_FINDTARGET, and target_teleporter_checktarget().

spawnfunc() [2/2]

spawnfunc

(

trigger_teleport

)

Definition at line 119 of file teleport.qc.

{
    this.angles = '0 0 0';
 
    this.active = ACTIVE_ACTIVE;
    EXACTTRIGGER_INIT;
    this.use = trigger_teleport_use;
 
    if(this.noise != "")
        FOREACH_WORD(this.noise, true, precache_sound(it));
 
    // this must be called to spawn the teleport waypoints for bots
    InitializeEntity(this, teleport_findtarget, INITPRIO_FINDTARGET);
 
    if (!this.target || this.target == "")
    {
        objerror (this, "Teleporter with no target");
        return;
    }
 
    IL_PUSH(g_teleporters, this);
}

References active, ACTIVE_ACTIVE, angles, EXACTTRIGGER_INIT, FOREACH_WORD, g_teleporters, IL_PUSH(), InitializeEntity(), INITPRIO_FINDTARGET, noise, objerror, precache_sound(), target, teleport_findtarget(), trigger_teleport_use(), and use.

target_teleport_use()

void target_teleport_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 75 of file teleport.qc.

{
    entity player = actor;
 
    if(!Teleport_Active(this, player))
        return;
 
    if(IS_PLAYER(player))
        RemoveGrapplingHooks(player);
 
    entity e = Simple_TeleportPlayer(this, player);
 
    string s = this.target; this.target = string_null;
    SUB_UseTargets(this, player, player); // TODO: should we be using toucher for trigger too?
    if (!this.target)
    {
        this.target = s;
    }
 
    if(e != this) // only activate the target teleporter if target is different
        SUB_UseTargets(e, player, player);
}

References entity(), IS_PLAYER, RemoveGrapplingHooks(), Simple_TeleportPlayer(), string_null, SUB_UseTargets(), target, and Teleport_Active().

Referenced by target_teleporter_checktarget().

target_teleporter_checktarget()

void target_teleporter_checktarget

(

entity

this

)

Definition at line 142 of file teleport.qc.

{
    // target_teleporter is used in many strange ways
    // we must attempt to figure out which way it is being used for in this instance
 
    if(!this.target || this.target == "")
    {
        // this target_teleporter has no target
        // so it must be either a destination for a teleporter or a teleporter itself
        bool is_teleporter_target = false;
        // NOTE: target2, target3, target4 unsupported, this may not be necessary as DeFrag maps have no such targets
        FOREACH_ENTITY_STRING(target, this.targetname,
        {
            if(it.classname == "trigger_teleport" || it.classname == "target_teleporter")
            {
                is_teleporter_target = true;
                break; // no need to keep looping once a valid target is found
            }
        });
 
        if(is_teleporter_target)
        {
            // there were teleporters found targeting this, so it must be a destination!
            spawnfunc_info_teleport_destination(this);
            return;
        }
 
        // set this entity up to be a teleporter, since it can be activated as one
        this.enemy = this;
        this.mangle = this.angles;
        this.angles = '0 0 0';
    }
 
    // seeing as this entity isn't targeted by a teleporter, it must be a teleporter itself
 
    this.active = ACTIVE_ACTIVE;
    this.use = target_teleport_use;
 
    if(this.noise && this.noise != "")
        FOREACH_WORD(this.noise, true, precache_sound(it));
 
    if(this.target && this.target != "") // no need to find a target on this entity, as it does not have one and .enemy is already set as required
        teleport_findtarget(this);
}

References active, ACTIVE_ACTIVE, angles, enemy, entity(), FOREACH_ENTITY_STRING, FOREACH_WORD, mangle, noise, precache_sound(), target, target_teleport_use(), targetname, teleport_findtarget(), and use.

Referenced by spawnfunc().

Teleport_Active()

bool Teleport_Active	(	entity	this,
		entity	player )

Definition at line 15 of file teleport.qc.

{
    if (this.active != ACTIVE_ACTIVE)
        return false;
 
#ifdef SVQC
    if (!player.teleportable)
        return false;
 
    if(player.vehicle)
    if(!player.vehicle.teleportable)
        return false;
 
    if(IS_TURRET(player))
        return false;
#elif defined(CSQC)
    if(!IS_PLAYER(player))
        return false;
#endif
 
    if(IS_DEAD(player))
        return false;
 
    if(this.team)
        if(((this.spawnflags & INVERT_TEAMS) == 0) == (DIFF_TEAM(this, player)))
            return false;
 
    // no need to call IS_OBSERVER(), observers never call use/touch functions which means this is never an observer
    if(this.classname == "trigger_teleport" && (this.spawnflags & TELEPORT_OBSERVERS_ONLY))
        return false;
 
    return true;
}

References active, ACTIVE_ACTIVE, classname, DIFF_TEAM, entity(), INVERT_TEAMS, IS_DEAD, IS_PLAYER, IS_TURRET, spawnflags, team, and TELEPORT_OBSERVERS_ONLY.

Referenced by target_teleport_use(), and Teleport_Touch().

Teleport_Touch()

void Teleport_Touch	(	entity	this,
		entity	toucher )

Definition at line 49 of file teleport.qc.

{
    entity player = toucher;
 
    if(!Teleport_Active(this, player))
        return;
 
    EXACTTRIGGER_TOUCH(this, player);
 
#ifdef SVQC
    if(IS_PLAYER(player))
        RemoveGrapplingHooks(player);
#endif
 
    noref entity e = Simple_TeleportPlayer(this, player);
 
#ifdef SVQC
    string s = this.target; this.target = string_null;
    SUB_UseTargets(this, player, player); // TODO: should we be using toucher for trigger too?
    if (!this.target) this.target = s;
 
    SUB_UseTargets(e, player, player);
#endif
}

References entity(), EXACTTRIGGER_TOUCH, IS_PLAYER, RemoveGrapplingHooks(), Simple_TeleportPlayer(), string_null, SUB_UseTargets(), target, Teleport_Active(), and toucher.

Referenced by teleport_findtarget().

trigger_teleport_link()

void trigger_teleport_link

(

entity

this

)

Definition at line 114 of file teleport.qc.

{
    //trigger_link(this, trigger_teleport_send);
}

References entity().

Referenced by teleport_findtarget().

trigger_teleport_send()

float trigger_teleport_send	(	entity	this,
		entity	to,
		float	sf )

Definition at line 100 of file teleport.qc.

{
    WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_TELEPORT);
 
    WriteByte(MSG_ENTITY, this.team);
    WriteInt24_t(MSG_ENTITY, this.spawnflags);
    WriteByte(MSG_ENTITY, this.active);
    WriteCoord(MSG_ENTITY, this.speed);
 
    trigger_common_write(this, true);
 
    return true;
}

References active, entity(), MSG_ENTITY, spawnflags, speed, team, trigger_common_write(), WriteByte(), WriteCoord(), and WriteHeader.

trigger_teleport_use()

void trigger_teleport_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 5 of file teleport.qc.

{
    if(teamplay)
        this.team = actor.team;
#ifdef SVQC
    this.SendFlags |= SF_TRIGGER_UPDATE;
#endif
}

References entity(), SendFlags, SF_TRIGGER_UPDATE, team, and teamplay.

Referenced by spawnfunc().