sv_lms.qc File Reference

#include "sv_lms.qh"
#include <common/mutators/mutator/instagib/items.qh>
#include <server/campaign.qh>
#include <server/command/_mod.qh>
#include <server/world.qh>
#include <server/items/items.qh>

Include dependency graph for sv_lms.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	ClearWinners ()
bool	lms_AddPlayer (entity player)
void	lms_Initialize ()
int	LMS_NewPlayerLives ()
void	lms_RemovePlayer (entity player)
void	lms_replace_with_extralife (entity this)
void	lms_UpdateLeaders ()
bool	lms_waypointsprite_visible_for_player (entity this, entity player, entity view)
	MUTATOR_HOOKFUNCTION (lms, AddPlayerScore)
	MUTATOR_HOOKFUNCTION (lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
	MUTATOR_HOOKFUNCTION (lms, CalculateRespawnTime)
	MUTATOR_HOOKFUNCTION (lms, CheckRules_World)
	MUTATOR_HOOKFUNCTION (lms, ClientCommand_Spectate)
	MUTATOR_HOOKFUNCTION (lms, ClientDisconnect)
	MUTATOR_HOOKFUNCTION (lms, Damage_Calculate)
	MUTATOR_HOOKFUNCTION (lms, FilterItem)
	MUTATOR_HOOKFUNCTION (lms, FilterItemDefinition)
	MUTATOR_HOOKFUNCTION (lms, ForbidSpawn)
	MUTATOR_HOOKFUNCTION (lms, ForbidThrowCurrentWeapon)
	MUTATOR_HOOKFUNCTION (lms, GiveFragsForKill)
	MUTATOR_HOOKFUNCTION (lms, ItemTouch)
	MUTATOR_HOOKFUNCTION (lms, MakePlayerObserver)
	MUTATOR_HOOKFUNCTION (lms, PlayerDied)
	MUTATOR_HOOKFUNCTION (lms, PlayerPowerups)
	MUTATOR_HOOKFUNCTION (lms, PlayerPreThink)
	MUTATOR_HOOKFUNCTION (lms, PlayerRegen)
	MUTATOR_HOOKFUNCTION (lms, PlayerSpawn)
	MUTATOR_HOOKFUNCTION (lms, PutClientInServer)
	MUTATOR_HOOKFUNCTION (lms, ReadLevelCvars)
	MUTATOR_HOOKFUNCTION (lms, reset_map_global)
	MUTATOR_HOOKFUNCTION (lms, reset_map_players)
	MUTATOR_HOOKFUNCTION (lms, SetStartItems)
	MUTATOR_HOOKFUNCTION (lms, SetWeaponArena)
	MUTATOR_HOOKFUNCTION (lms, SV_StartFrame)
int	WinningCondition_LMS ()

Variables
float	autocvar_g_lms_dynamic_respawn_delay = 1
float	autocvar_g_lms_dynamic_respawn_delay_base = 2
float	autocvar_g_lms_dynamic_respawn_delay_increase = 3
float	autocvar_g_lms_dynamic_respawn_delay_max = 20
bool	autocvar_g_lms_dynamic_vampire = 1
float	autocvar_g_lms_dynamic_vampire_factor_base = 0.1
float	autocvar_g_lms_dynamic_vampire_factor_increase = 0.1
float	autocvar_g_lms_dynamic_vampire_factor_max = 0.5
int	autocvar_g_lms_dynamic_vampire_min_lives_diff = 2
int	autocvar_g_lms_extra_lives
float	autocvar_g_lms_forfeit_min_match_time
bool	autocvar_g_lms_items
bool	autocvar_g_lms_join_anytime
int	autocvar_g_lms_last_join
int	autocvar_g_lms_leader_lives_diff = 2
float	autocvar_g_lms_leader_minpercent = 0.5
float	autocvar_g_lms_leader_wp_interval = 25
float	autocvar_g_lms_leader_wp_interval_jitter = 10
float	autocvar_g_lms_leader_wp_time = 5
bool	autocvar_g_lms_regenerate
bool	autocvar_g_lms_rot
float	last_forfeiter_armorvalue
float	last_forfeiter_health
int	last_forfeiter_lives
float	lms_leader
int	lms_leaders
int	lms_leaders_lives_diff
bool	lms_visible_leaders = true
bool	lms_visible_leaders_prev
float	lms_visible_leaders_time

Function Documentation

ClearWinners()

void ClearWinners

(

)

Definition at line 1552 of file world.qc.

{
    FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
}

Referenced by CheckRules_World(), WinningCondition_LMS(), WinningCondition_RanOutOfSpawns(), and WinningCondition_Scores().

lms_AddPlayer()

bool lms_AddPlayer

(

entity

player

)

Definition at line 254 of file sv_lms.qc.

{
    if (!INGAME(player))
    {
        int lives = GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives());
        if(lives <= 0)
            return false;
        if (time < game_starttime)
            INGAME_STATUS_SET(player, INGAME_STATUS_JOINED);
        else
            INGAME_STATUS_SET(player, INGAME_STATUS_JOINING); // this is just to delay setting health and armor that can't be done here
    }
    if (warmup_stage || time <= game_starttime)
    {
        player.lms_spectate = false;
        GameRules_scoring_add(player, LMS_RANK, -GameRules_scoring_add(player, LMS_RANK, 0));
        int lives = GameRules_scoring_add(player, LMS_LIVES, 0);
        if(lives <= 0)
            GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives());
    }
    else if (GameRules_scoring_add(player, LMS_LIVES, 0) <= 0)
        return false;
    return true;
}

References entity(), game_starttime, GameRules_scoring_add, INGAME, INGAME_STATUS_JOINED, INGAME_STATUS_JOINING, INGAME_STATUS_SET, LMS_NewPlayerLives(), time, and warmup_stage.

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

lms_Initialize()

void lms_Initialize

(

)

Definition at line 718 of file sv_lms.qc.

{
    lms_lowest_lives = 999;
}

References lms_lowest_lives.

Referenced by REGISTER_MUTATOR().

LMS_NewPlayerLives()

int LMS_NewPlayerLives

(

)

Definition at line 38 of file sv_lms.qc.

{
    int fl = floor(autocvar_fraglimit);
    if(fl == 0 || fl > 999)
        fl = 999;
 
    // first player has left the game for dying too much? Nobody else can get in.
    if(lms_lowest_lives < 1)
        return 0;
 
    if(!autocvar_g_lms_join_anytime)
        if(lms_lowest_lives < fl - max(0, floor(autocvar_g_lms_last_join)))
            return 0;
 
    return bound(1, lms_lowest_lives, fl);
}

References autocvar_fraglimit, autocvar_g_lms_join_anytime, autocvar_g_lms_last_join, bound(), floor(), lms_lowest_lives, and max().

Referenced by lms_AddPlayer(), and WinningCondition_LMS().

lms_RemovePlayer()

void lms_RemovePlayer

(

entity

player

)

Definition at line 338 of file sv_lms.qc.

{
    if (warmup_stage || time < game_starttime)
        return;
 
    float player_rank = GameRules_scoring_add(player, LMS_RANK, 0);
    if (!player_rank)
    {
        if (!player.lms_spectate)
        {
            player.frags = FRAGS_PLAYER_OUT_OF_GAME;
            int pl_cnt = 0;
            FOREACH_CLIENT(IS_PLAYER(it) && it.frags == FRAGS_PLAYER, {
                ++pl_cnt;
            });
            GameRules_scoring_add(player, LMS_RANK, pl_cnt + 1);
        }
        else if (INGAME(player))
        {
            FOREACH_CLIENT(it != player, {
                // update rank of other players
                if (it.frags == FRAGS_PLAYER_OUT_OF_GAME)
                    GameRules_scoring_add(it, LMS_RANK, -1);
            });
            int rank = GameRules_scoring_add(player, LMS_RANK, 0);
            GameRules_scoring_add(player, LMS_RANK, -rank);
            if(!warmup_stage)
            {
                int pl_lives = GameRules_scoring_add(player, LMS_LIVES, 0);
                float pl_health = IS_DEAD(player) ? start_health : GetResource(player, RES_HEALTH);
                float pl_armor = IS_DEAD(player) ? start_armorvalue : GetResource(player, RES_ARMOR);
                if (!last_forfeiter_lives || pl_lives < last_forfeiter_lives)
                {
                    last_forfeiter_lives = pl_lives;
                    last_forfeiter_health = pl_health;
                    last_forfeiter_armorvalue = pl_armor;
                }
                else if (pl_lives == last_forfeiter_lives)
                {
                    // these values actually can belong to a different forfeiter
                    last_forfeiter_health = min(last_forfeiter_health, pl_health);
                    last_forfeiter_armorvalue = min(last_forfeiter_armorvalue, pl_armor);
                }
                GameRules_scoring_add(player, LMS_LIVES, -pl_lives);
            }
            INGAME_STATUS_CLEAR(player);
            player.lms_spectate = false;
            CS(player).killcount = FRAGS_SPECTATOR;
        }
        if (autocvar_g_lms_leader_lives_diff > 0)
            lms_UpdateLeaders();
    }
}

References autocvar_g_lms_leader_lives_diff, CS(), entity(), FOREACH_CLIENT, FRAGS_PLAYER, FRAGS_PLAYER_OUT_OF_GAME, FRAGS_SPECTATOR, game_starttime, GameRules_scoring_add, GetResource(), INGAME, INGAME_STATUS_CLEAR, IS_DEAD, IS_PLAYER, last_forfeiter_armorvalue, last_forfeiter_health, last_forfeiter_lives, lms_UpdateLeaders(), min(), RES_ARMOR, start_armorvalue, start_health, time, and warmup_stage.

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

lms_replace_with_extralife()

void lms_replace_with_extralife

(

entity

this

)

Definition at line 639 of file sv_lms.qc.

{
    entity e = new(item_extralife);
    Item_CopyFields(this, e);
 
    StartItem(e, ITEM_ExtraLife);
}

References entity(), Item_CopyFields(), and StartItem().

Referenced by MUTATOR_HOOKFUNCTION().

lms_UpdateLeaders()

void lms_UpdateLeaders

(

)

Definition at line 171 of file sv_lms.qc.

{
    int max_lives = 0;
    int pl_cnt = 0;
    FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
        int lives = GameRules_scoring_add(it, LMS_LIVES, 0);
        if (lives > max_lives)
            max_lives = lives;
        ++pl_cnt;
    });
 
    int second_max_lives = 0;
    int pl_cnt_with_max_lives = 0;
    FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
        int lives = GameRules_scoring_add(it, LMS_LIVES, 0);
        if (lives == max_lives)
            ++pl_cnt_with_max_lives;
        else if (lives > second_max_lives)
            second_max_lives = lives;
    });
 
    lms_leaders_lives_diff = max_lives - second_max_lives;
 
    int lives_diff = autocvar_g_lms_leader_lives_diff;
    if (lms_leaders_lives_diff >= lives_diff && pl_cnt_with_max_lives <= pl_cnt * autocvar_g_lms_leader_minpercent)
        FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
            int lives = GameRules_scoring_add(it, LMS_LIVES, 0);
            if (lives == max_lives)
            {
                if (!it.lms_leader)
                    it.lms_leader = true;
            }
            else
            {
                it.lms_leader = false;
            }
        });
    else
        FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
            if (it.waypointsprite_attachedforcarrier)
                WaypointSprite_Kill(it.waypointsprite_attachedforcarrier);
            it.lms_leader = false;
        });
}

References autocvar_g_lms_leader_lives_diff, autocvar_g_lms_leader_minpercent, FOREACH_CLIENT, FRAGS_PLAYER_OUT_OF_GAME, IS_PLAYER, and lms_leaders_lives_diff.

Referenced by lms_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

lms_waypointsprite_visible_for_player()

bool lms_waypointsprite_visible_for_player	(	entity	this,
		entity	player,
		entity	view )

Definition at line 158 of file sv_lms.qc.

{
    if(view.lms_leader)
        if(IS_SPEC(player))
            return false; // we don't want spectators of leaders to see the attached waypoint on the top of their screen
 
    if (!lms_visible_leaders)
        return false;
 
    return true;
}

References entity(), IS_SPEC, and lms_visible_leaders.

Referenced by MUTATOR_HOOKFUNCTION().

MUTATOR_HOOKFUNCTION() [1/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		AddPlayerScore	)

Definition at line 711 of file sv_lms.qc.

{
    if(game_stopped)
    if(M_ARGV(0, entity) == SP_LMS_RANK) // score field
        return true; // allow writing to this field in intermission as it is needed for newly joining players
}

References entity(), game_stopped, and M_ARGV.

MUTATOR_HOOKFUNCTION() [2/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		Bot_FixCount	,
		CBC_ORDER_EXCLUSIVE	)

Definition at line 679 of file sv_lms.qc.

{
    FOREACH_CLIENT(IS_REAL_CLIENT(it), {
        if (INGAME(it))
            ++M_ARGV(0, int); // activerealplayers
        ++M_ARGV(1, int); // realplayers
    });
 
    return true;
}

References CBC_ORDER_EXCLUSIVE, FOREACH_CLIENT, INGAME, IS_REAL_CLIENT, and M_ARGV.

MUTATOR_HOOKFUNCTION() [3/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		CalculateRespawnTime	)

Definition at line 550 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
    player.respawn_flags |= RESPAWN_FORCE;
 
    int pl_lives = GameRules_scoring_add(player, LMS_LIVES, 0);
    if (pl_lives <= 0)
    {
        player.respawn_flags = RESPAWN_SILENT;
        // prevent unwanted sudden rejoin as spectator and movement of spectator camera
        player.respawn_time = time + 2;
        return true;
    }
 
    if (autocvar_g_lms_dynamic_respawn_delay <= 0)
        return false;
 
    int max_lives = 0;
    int pl_cnt = 0;
    FOREACH_CLIENT(it != player && IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
        int lives = GameRules_scoring_add(it, LMS_LIVES, 0);
        if (lives > max_lives)
            max_lives = lives;
        ++pl_cnt;
    });
 
    // min delay with only 2 players
    if (pl_cnt == 1) // player wasn't counted
        max_lives = 0;
 
    float dlay = autocvar_g_lms_dynamic_respawn_delay_base +
        autocvar_g_lms_dynamic_respawn_delay_increase * max(0, max_lives - pl_lives);
    player.respawn_time = time + min(autocvar_g_lms_dynamic_respawn_delay_max, dlay);
    return true;
}

References autocvar_g_lms_dynamic_respawn_delay, autocvar_g_lms_dynamic_respawn_delay_base, autocvar_g_lms_dynamic_respawn_delay_increase, autocvar_g_lms_dynamic_respawn_delay_max, entity(), FOREACH_CLIENT, FRAGS_PLAYER_OUT_OF_GAME, GameRules_scoring_add, IS_PLAYER, M_ARGV, max(), min(), RESPAWN_FORCE, RESPAWN_SILENT, and time.

MUTATOR_HOOKFUNCTION() [4/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		CheckRules_World	)

Definition at line 699 of file sv_lms.qc.

{
    M_ARGV(0, float) = WinningCondition_LMS();
    return true;
}

References CheckRules_World(), M_ARGV, and WinningCondition_LMS().

MUTATOR_HOOKFUNCTION() [5/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ClientCommand_Spectate	)

Definition at line 690 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
    if(player.frags != FRAGS_SPECTATOR && player.frags != FRAGS_PLAYER_OUT_OF_GAME)
        return MUT_SPECCMD_CONTINUE;
    // ranked players (out of game) can no longer become real spectators
    return MUT_SPECCMD_RETURN;
}

References entity(), FRAGS_PLAYER_OUT_OF_GAME, FRAGS_SPECTATOR, M_ARGV, MUT_SPECCMD_CONTINUE, and MUT_SPECCMD_RETURN.

MUTATOR_HOOKFUNCTION() [6/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ClientDisconnect	)

Definition at line 392 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
 
    player.lms_spectate = true;
 
    lms_RemovePlayer(player);
    INGAME_STATUS_CLEAR(player);
}

References ClientDisconnect, entity(), INGAME_STATUS_CLEAR, lms_RemovePlayer(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [7/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		Damage_Calculate	)

Definition at line 515 of file sv_lms.qc.

{
    if (!autocvar_g_lms_dynamic_vampire)
        return;
 
    entity frag_attacker = M_ARGV(1, entity);
    entity frag_target = M_ARGV(2, entity);
    float frag_damage = M_ARGV(4, float);
 
    if (IS_PLAYER(frag_attacker) && !IS_DEAD(frag_attacker)
        && IS_PLAYER(frag_target) && !IS_DEAD(frag_target) && frag_attacker != frag_target)
    {
        float vampire_factor = 0;
 
        int frag_attacker_lives = GameRules_scoring_add(frag_attacker, LMS_LIVES, 0);
        int frag_target_lives = GameRules_scoring_add(frag_target, LMS_LIVES, 0);
        int diff = frag_target_lives - frag_attacker_lives - autocvar_g_lms_dynamic_vampire_min_lives_diff;
 
        if (diff >= 0)
            vampire_factor = autocvar_g_lms_dynamic_vampire_factor_base + diff * autocvar_g_lms_dynamic_vampire_factor_increase;
        if (vampire_factor > 0)
        {
            vampire_factor = min(vampire_factor, autocvar_g_lms_dynamic_vampire_factor_max);
            SetResourceExplicit(frag_attacker, RES_HEALTH,
                min(GetResource(frag_attacker, RES_HEALTH) + frag_damage * vampire_factor, start_health));
        }
    }
}

References autocvar_g_lms_dynamic_vampire, autocvar_g_lms_dynamic_vampire_factor_base, autocvar_g_lms_dynamic_vampire_factor_increase, autocvar_g_lms_dynamic_vampire_factor_max, autocvar_g_lms_dynamic_vampire_min_lives_diff, entity(), frag_damage, frag_target, GameRules_scoring_add, GetResource(), IS_DEAD, IS_PLAYER, M_ARGV, min(), SetResourceExplicit(), and start_health.

MUTATOR_HOOKFUNCTION() [8/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		FilterItem	)

Definition at line 647 of file sv_lms.qc.

{
    entity item = M_ARGV(0, entity);
    entity def = item.itemdef;
    if(def == ITEM_HealthMega && !(autocvar_g_lms_items || autocvar_g_pickup_items > 0))
    {
        if(autocvar_g_powerups && autocvar_g_lms_extra_lives)
            lms_replace_with_extralife(item);
        return true;
    }
 
    return false;
}

References autocvar_g_lms_extra_lives, autocvar_g_lms_items, autocvar_g_pickup_items, autocvar_g_powerups, entity(), lms_replace_with_extralife(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [9/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		FilterItemDefinition	)

Definition at line 627 of file sv_lms.qc.

{
    if (autocvar_g_lms_items || autocvar_g_pickup_items > 0)
        return false;
 
    entity def = M_ARGV(0, entity);
    if (autocvar_g_powerups && autocvar_g_lms_extra_lives && (def == ITEM_ExtraLife || def == ITEM_HealthMega))
        return false;
 
    return true;
}

References autocvar_g_lms_extra_lives, autocvar_g_lms_items, autocvar_g_pickup_items, autocvar_g_powerups, entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [10/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ForbidSpawn	)

Definition at line 328 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
 
    if (warmup_stage || lms_AddPlayer(player))
        return false;
 
    return true;
}

References entity(), lms_AddPlayer(), M_ARGV, and warmup_stage.

MUTATOR_HOOKFUNCTION() [11/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ForbidThrowCurrentWeapon	)

Definition at line 509 of file sv_lms.qc.

{
    // forbode!
    return true;
}

MUTATOR_HOOKFUNCTION() [12/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		GiveFragsForKill	)

Definition at line 586 of file sv_lms.qc.

{
    entity frag_target = M_ARGV(1, entity);
 
    if (!warmup_stage && time > game_starttime)
    {
        // remove a life
        int tl = GameRules_scoring_add(frag_target, LMS_LIVES, -1);
        if(tl < lms_lowest_lives)
            lms_lowest_lives = tl;
        if(tl <= 0)
        {
            int pl_cnt = 0;
            FOREACH_CLIENT(IS_PLAYER(it) && it.frags == FRAGS_PLAYER, {
                ++pl_cnt;
            });
            frag_target.frags = FRAGS_PLAYER_OUT_OF_GAME;
            GameRules_scoring_add(frag_target, LMS_RANK, pl_cnt);
            Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, frag_target.netname);
        }
    }
    M_ARGV(2, float) = 0; // frag score
 
    return true;
}

References entity(), FOREACH_CLIENT, frag_target, FRAGS_PLAYER, FRAGS_PLAYER_OUT_OF_GAME, game_starttime, GameRules_scoring_add, IS_PLAYER, lms_lowest_lives, M_ARGV, NULL, Send_Notification(), time, and warmup_stage.

MUTATOR_HOOKFUNCTION() [13/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ItemTouch	)

Definition at line 661 of file sv_lms.qc.

{
    if(MUTATOR_RETURNVALUE) return false;
 
    entity item = M_ARGV(0, entity);
    entity toucher = M_ARGV(1, entity);
 
    if(item.itemdef == ITEM_ExtraLife)
    {
        Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES, autocvar_g_lms_extra_lives);
        GameRules_scoring_add(toucher, LMS_LIVES, autocvar_g_lms_extra_lives);
        Inventory_pickupitem(item.itemdef, toucher);
        return MUT_ITEMTOUCH_PICKUP;
    }
 
    return MUT_ITEMTOUCH_CONTINUE;
}

References autocvar_g_lms_extra_lives, entity(), GameRules_scoring_add, Inventory_pickupitem(), M_ARGV, MUT_ITEMTOUCH_CONTINUE, MUT_ITEMTOUCH_PICKUP, MUTATOR_RETURNVALUE, Send_Notification(), and toucher.

MUTATOR_HOOKFUNCTION() [14/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		MakePlayerObserver	)

Definition at line 402 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
    bool is_forced = M_ARGV(1, bool);
 
    if (!player.frags) // init
    {
        player.frags = FRAGS_SPECTATOR; // don't be on the scoreboard yet
        return true; // resetting at init can end match before it starts
    }
    if (player.frags == FRAGS_PLAYER_OUT_OF_GAME) // eliminated
        return true; // prevent team reset (and spec notification)
 
    if (warmup_stage || time <= game_starttime)
    {
        GameRules_scoring_add(player, LMS_LIVES, -GameRules_scoring_add(player, LMS_LIVES, 0));
        INGAME_STATUS_CLEAR(player);
    }
    else
    {
        if (is_forced || player.killindicator_teamchange == -2) // player is forced or wants to spectate
            player.lms_spectate = true;
        if (!GameRules_scoring_add(player, LMS_RANK, 0))
            lms_RemovePlayer(player);
    }
}

References entity(), FRAGS_PLAYER_OUT_OF_GAME, FRAGS_SPECTATOR, game_starttime, GameRules_scoring_add, INGAME_STATUS_CLEAR, lms_RemovePlayer(), M_ARGV, time, and warmup_stage.

MUTATOR_HOOKFUNCTION() [15/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PlayerDied	)

Definition at line 544 of file sv_lms.qc.

{
    if (!warmup_stage && autocvar_g_lms_leader_lives_diff > 0)
        lms_UpdateLeaders();
}

References autocvar_g_lms_leader_lives_diff, lms_UpdateLeaders(), and warmup_stage.

MUTATOR_HOOKFUNCTION() [16/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PlayerPowerups	)

Definition at line 500 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
    if (player.waypointsprite_attachedforcarrier)
        player.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
    else
        player.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
}

References EF_ADDITIVE, EF_FULLBRIGHT, entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [17/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PlayerPreThink	)

Definition at line 429 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
 
    // recycled REDALIVE and BLUEALIVE to avoid adding a dedicated stat
    STAT(REDALIVE, player) = lms_leaders;
    STAT(BLUEALIVE, player) = lms_leaders_lives_diff;
 
    if(player.deadflag == DEAD_DYING)
        player.deadflag = DEAD_RESPAWNING;
}

References DEAD_DYING, DEAD_RESPAWNING, entity(), lms_leaders, lms_leaders_lives_diff, M_ARGV, PlayerPreThink, and STAT.

MUTATOR_HOOKFUNCTION() [18/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PlayerRegen	)

Definition at line 491 of file sv_lms.qc.

{
    if(!autocvar_g_lms_regenerate)
        M_ARGV(2, float) = 0;
    if(!autocvar_g_lms_rot)
        M_ARGV(3, float) = 0;
    return (!autocvar_g_lms_regenerate && !autocvar_g_lms_rot);
}

References autocvar_g_lms_regenerate, autocvar_g_lms_rot, and M_ARGV.

MUTATOR_HOOKFUNCTION() [19/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PlayerSpawn	)

Definition at line 295 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
 
    if (warmup_stage || time < game_starttime)
        return true;
 
    if (INGAME_JOINING(player))
    {
        // spawn player with the same amount of health / armor
        // as the least healthy player with the least number of lives
        int pl_lives = GameRules_scoring_add(player, LMS_LIVES, 0);
        float min_health = start_health;
        float min_armorvalue = start_armorvalue;
        if (last_forfeiter_lives == pl_lives)
        {
            min_health = last_forfeiter_health;
            min_armorvalue = last_forfeiter_armorvalue;
        }
        FOREACH_CLIENT(it != player && IS_PLAYER(it) && !IS_DEAD(it) && GameRules_scoring_add(it, LMS_LIVES, 0) == pl_lives, {
            if (GetResource(it, RES_HEALTH) < min_health)
                min_health = GetResource(it, RES_HEALTH);
            if (GetResource(it, RES_ARMOR) < min_armorvalue)
                min_armorvalue = GetResource(it, RES_ARMOR);
        });
        if (min_health != start_health)
            SetResource(player, RES_HEALTH, max(1, min_health));
        if (min_armorvalue != start_armorvalue)
            SetResource(player, RES_ARMOR, min_armorvalue);
        INGAME_STATUS_SET(player, INGAME_STATUS_JOINED);
    }
}

References entity(), FOREACH_CLIENT, game_starttime, GameRules_scoring_add, GetResource(), INGAME_JOINING, INGAME_STATUS_JOINED, INGAME_STATUS_SET, IS_DEAD, IS_PLAYER, last_forfeiter_armorvalue, last_forfeiter_health, last_forfeiter_lives, M_ARGV, max(), RES_ARMOR, SetResource(), start_armorvalue, start_health, time, and warmup_stage.

MUTATOR_HOOKFUNCTION() [20/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		PutClientInServer	)

Definition at line 279 of file sv_lms.qc.

{
    entity player = M_ARGV(0, entity);
    if (!warmup_stage && (IS_BOT_CLIENT(player) || CS(player).jointime != time))
    {
        if (GameRules_scoring_add(player, LMS_RANK, 0) || !lms_AddPlayer(player))
        {
            TRANSMUTE(Observer, player);
            Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
        }
    }
}

References CS(), entity(), GameRules_scoring_add, IS_BOT_CLIENT, jointime, lms_AddPlayer(), M_ARGV, PutClientInServer, Send_Notification(), time, TRANSMUTE, and warmup_stage.

MUTATOR_HOOKFUNCTION() [21/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		ReadLevelCvars	)

Definition at line 247 of file sv_lms.qc.

{
    // incompatible
    sv_ready_restart_after_countdown = 0;
}

References sv_ready_restart_after_countdown.

MUTATOR_HOOKFUNCTION() [22/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		reset_map_global	)

Definition at line 217 of file sv_lms.qc.

{
    lms_lowest_lives = 999;
}

References lms_lowest_lives.

MUTATOR_HOOKFUNCTION() [23/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		reset_map_players	)

Definition at line 222 of file sv_lms.qc.

{
    FOREACH_CLIENT(true, {
        if (it.frags == FRAGS_PLAYER_OUT_OF_GAME)
            it.frags = FRAGS_PLAYER;
 
        CS(it).killcount = 0;
        INGAME_STATUS_CLEAR(it);
        it.lms_spectate = false;
        GameRules_scoring_add(it, LMS_RANK, -GameRules_scoring_add(it, LMS_RANK, 0));
        GameRules_scoring_add(it, LMS_LIVES, -GameRules_scoring_add(it, LMS_LIVES, 0));
 
        if (it.frags != FRAGS_PLAYER)
            continue;
 
        TRANSMUTE(Player, it);
        PutClientInServer(it);
        it.lms_leader = false;
        if (it.waypointsprite_attachedforcarrier)
            WaypointSprite_Kill(it.waypointsprite_attachedforcarrier);
    });
}

References CS(), FOREACH_CLIENT, FRAGS_PLAYER, FRAGS_PLAYER_OUT_OF_GAME, GameRules_scoring_add, INGAME_STATUS_CLEAR, PutClientInServer, TRANSMUTE, and WaypointSprite_Kill().

MUTATOR_HOOKFUNCTION() [24/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		SetStartItems	)

Definition at line 612 of file sv_lms.qc.

{
    start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
    if(!cvar("g_use_ammunition"))
        start_items |= IT_UNLIMITED_AMMO;
 
    start_health       = warmup_start_health       = cvar("g_lms_start_health");
    start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
    start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
    start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
    start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
    start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
    start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
}

References cvar(), IT_UNLIMITED_AMMO, IT_UNLIMITED_SUPERWEAPONS, start_ammo_cells, start_ammo_fuel, start_ammo_nails, start_ammo_rockets, start_ammo_shells, start_armorvalue, start_health, start_items, warmup_start_ammo_cells, warmup_start_ammo_fuel, warmup_start_ammo_nails, warmup_start_ammo_rockets, warmup_start_ammo_shells, warmup_start_armorvalue, and warmup_start_health.

MUTATOR_HOOKFUNCTION() [25/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		SetWeaponArena	)

Definition at line 705 of file sv_lms.qc.

{
    if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
        M_ARGV(0, string) = autocvar_g_lms_weaponarena;
}

References autocvar_g_lms_weaponarena, and M_ARGV.

MUTATOR_HOOKFUNCTION() [26/26]

MUTATOR_HOOKFUNCTION	(	lms	,
		SV_StartFrame	)

Definition at line 441 of file sv_lms.qc.

{
    if (intermission_running)
        return;
 
    lms_leaders = 0;
    FOREACH_CLIENT(true, {
        if (IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME && it.lms_leader)
            ++lms_leaders;
    });
 
    float leader_time = autocvar_g_lms_leader_wp_time;
    float leader_interval = leader_time + autocvar_g_lms_leader_wp_interval;
    lms_visible_leaders_prev = lms_visible_leaders;
    lms_visible_leaders = (lms_leaders && time > lms_visible_leaders_time && time < lms_visible_leaders_time + leader_time);
    if (!lms_leaders || (lms_visible_leaders_prev && !lms_visible_leaders))
        lms_visible_leaders_time = time + leader_interval + random() * autocvar_g_lms_leader_wp_interval_jitter;
 
    FOREACH_CLIENT(true, {
        STAT(OBJECTIVE_STATUS, it) = lms_visible_leaders;
        if (IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME)
        {
            if (it.lms_leader)
            {
                if (!it.waypointsprite_attachedforcarrier)
                {
                    WaypointSprite_AttachCarrier(WP_LmsLeader, it, RADARICON_FLAGCARRIER);
                    it.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = lms_waypointsprite_visible_for_player;
                    WaypointSprite_UpdateRule(it.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
                    vector pl_color = colormapPaletteColor(it.clientcolors & 0x0F, false);
                    WaypointSprite_UpdateTeamRadar(it.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, pl_color);
                    WaypointSprite_Ping(it.waypointsprite_attachedforcarrier);
                }
                if (!lms_visible_leaders_prev && lms_visible_leaders && IS_REAL_CLIENT(it))
                    Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_LMS_VISIBLE_LEADER);
            }
            else // if (!it.lms_leader)
            {
                if (IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME)
                {
                    if (!lms_visible_leaders_prev && lms_visible_leaders && IS_REAL_CLIENT(it))
                        Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_LMS_VISIBLE_OTHER);
                }
                if (it.waypointsprite_attachedforcarrier)
                    WaypointSprite_Kill(it.waypointsprite_attachedforcarrier);
            }
        }
    });
}

References autocvar_g_lms_leader_wp_interval, autocvar_g_lms_leader_wp_interval_jitter, autocvar_g_lms_leader_wp_time, colormapPaletteColor, FOREACH_CLIENT, FRAGS_PLAYER_OUT_OF_GAME, intermission_running, IS_PLAYER, IS_REAL_CLIENT, lms_leaders, lms_visible_leaders, lms_visible_leaders_prev, lms_visible_leaders_time, lms_waypointsprite_visible_for_player(), random(), Send_Notification(), SPRITERULE_DEFAULT, STAT, time, vector, WaypointSprite_AttachCarrier(), WaypointSprite_Kill(), WaypointSprite_Ping(), WaypointSprite_UpdateRule(), and WaypointSprite_UpdateTeamRadar().

WinningCondition_LMS()

int WinningCondition_LMS

(

)

Definition at line 60 of file sv_lms.qc.

{
    if (warmup_stage || time <= game_starttime)
        return WINNING_NO;
 
    entity first_player = NULL;
    int totalplayers = 0;
    int totalplayed = 0;
    FOREACH_CLIENT(true, {
        if (IS_PLAYER(it) && it.frags == FRAGS_PLAYER)
        {
            if (!totalplayers)
                first_player = it;
            ++totalplayers;
        }
        else if (GameRules_scoring_add(it, LMS_RANK, 0))
            ++totalplayed;
    });
 
    if (totalplayers)
    {
        if (totalplayers > 1)
        {
            // two or more active players - continue with the game
 
            if (autocvar_g_campaign && campaign_bots_may_start)
            {
                FOREACH_CLIENT(IS_REAL_CLIENT(it), {
                    float pl_lives = GameRules_scoring_add(it, LMS_LIVES, 0);
                    if (!pl_lives)
                        return WINNING_YES; // human player lost, game over
                    break;
                });
            }
        }
        else
        {
            // exactly one player?
 
            ClearWinners();
 
            if (LMS_NewPlayerLives())
            {
                if (totalplayed && game_starttime > 0 && time > game_starttime + autocvar_g_lms_forfeit_min_match_time) // give players time to join
                {
                    GameRules_scoring_add(first_player, LMS_RANK, 1);
                    first_player.winning = 1;
                    return WINNING_YES;
                }
                // game still running (that is, nobody got removed from the game by a frag yet)? then continue
                return WINNING_NO;
            }
            else
            {
                // a winner!
                // and assign them their first place
                GameRules_scoring_add(first_player, LMS_RANK, 1);
                first_player.winning = 1;
                return WINNING_YES;
            }
        }
    }
    else
    {
        // nobody is playing at all...
        if (LMS_NewPlayerLives())
        {
            if (totalplayed && game_starttime > 0 && time > game_starttime + autocvar_g_lms_forfeit_min_match_time) // give players time to join
            {
                ClearWinners();
                return WINNING_YES;
            }
            // wait for players...
        }
        else
        {
            // SNAFU (maybe a draw game?)
            ClearWinners();
            LOG_TRACE("No players, ending game.");
            return WINNING_YES;
        }
    }
 
    // When we get here, we have at least two players who are actually LIVING,
    // now check if the top two players have equal score.
    WinningConditionHelper(NULL);
 
    ClearWinners();
    if(WinningConditionHelper_winner)
        WinningConditionHelper_winner.winning = true;
    if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
        return WINNING_NEVER;
 
    // Top two have different scores? Way to go for our beloved TIMELIMIT!
    return WINNING_NO;
}

References autocvar_g_campaign, autocvar_g_lms_forfeit_min_match_time, campaign_bots_may_start, ClearWinners(), entity(), FOREACH_CLIENT, FRAGS_PLAYER, game_starttime, GameRules_scoring_add, IS_PLAYER, IS_REAL_CLIENT, LMS_NewPlayerLives(), LOG_TRACE, NULL, time, warmup_stage, WINNING_NEVER, WINNING_NO, WINNING_YES, WinningConditionHelper(), WinningConditionHelper_secondscore, WinningConditionHelper_topscore, and WinningConditionHelper_winner.

Referenced by MUTATOR_HOOKFUNCTION().

Variable Documentation

autocvar_g_lms_dynamic_respawn_delay

float autocvar_g_lms_dynamic_respawn_delay = 1

Definition at line 20 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_respawn_delay_base

float autocvar_g_lms_dynamic_respawn_delay_base = 2

Definition at line 21 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_respawn_delay_increase

float autocvar_g_lms_dynamic_respawn_delay_increase = 3

Definition at line 22 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_respawn_delay_max

float autocvar_g_lms_dynamic_respawn_delay_max = 20

Definition at line 23 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_vampire

bool autocvar_g_lms_dynamic_vampire = 1

Definition at line 24 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_vampire_factor_base

float autocvar_g_lms_dynamic_vampire_factor_base = 0.1

Definition at line 25 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_vampire_factor_increase

float autocvar_g_lms_dynamic_vampire_factor_increase = 0.1

Definition at line 26 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_vampire_factor_max

float autocvar_g_lms_dynamic_vampire_factor_max = 0.5

Definition at line 27 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_dynamic_vampire_min_lives_diff

int autocvar_g_lms_dynamic_vampire_min_lives_diff = 2

Definition at line 28 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_extra_lives

int autocvar_g_lms_extra_lives

Definition at line 9 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

autocvar_g_lms_forfeit_min_match_time

float autocvar_g_lms_forfeit_min_match_time

Definition at line 10 of file sv_lms.qc.

Referenced by WinningCondition_LMS().

autocvar_g_lms_items

bool autocvar_g_lms_items

Definition at line 13 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

autocvar_g_lms_join_anytime

bool autocvar_g_lms_join_anytime

Definition at line 11 of file sv_lms.qc.

Referenced by LMS_NewPlayerLives().

autocvar_g_lms_last_join

int autocvar_g_lms_last_join

Definition at line 12 of file sv_lms.qc.

Referenced by LMS_NewPlayerLives().

autocvar_g_lms_leader_lives_diff

int autocvar_g_lms_leader_lives_diff = 2

Definition at line 15 of file sv_lms.qc.

Referenced by lms_RemovePlayer(), lms_UpdateLeaders(), and MUTATOR_HOOKFUNCTION().

autocvar_g_lms_leader_minpercent

float autocvar_g_lms_leader_minpercent = 0.5

Definition at line 16 of file sv_lms.qc.

Referenced by lms_UpdateLeaders().

autocvar_g_lms_leader_wp_interval

float autocvar_g_lms_leader_wp_interval = 25

Definition at line 17 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_leader_wp_interval_jitter

float autocvar_g_lms_leader_wp_interval_jitter = 10

Definition at line 18 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_leader_wp_time

float autocvar_g_lms_leader_wp_time = 5

Definition at line 19 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_regenerate

bool autocvar_g_lms_regenerate

Definition at line 14 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_lms_rot

bool autocvar_g_lms_rot

Definition at line 35 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

last_forfeiter_armorvalue

float last_forfeiter_armorvalue

Definition at line 294 of file sv_lms.qc.

Referenced by lms_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

last_forfeiter_health

float last_forfeiter_health

Definition at line 293 of file sv_lms.qc.

Referenced by lms_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

last_forfeiter_lives

int last_forfeiter_lives

Definition at line 292 of file sv_lms.qc.

Referenced by lms_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

lms_leader

float lms_leader

Definition at line 30 of file sv_lms.qc.

lms_leaders

int lms_leaders

Definition at line 31 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

lms_leaders_lives_diff

int lms_leaders_lives_diff

Definition at line 170 of file sv_lms.qc.

Referenced by lms_UpdateLeaders(), and MUTATOR_HOOKFUNCTION().

lms_visible_leaders

bool lms_visible_leaders = true

Definition at line 33 of file sv_lms.qc.

Referenced by lms_waypointsprite_visible_for_player(), and MUTATOR_HOOKFUNCTION().

lms_visible_leaders_prev

bool lms_visible_leaders_prev

Definition at line 34 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().

lms_visible_leaders_time

float lms_visible_leaders_time

Definition at line 32 of file sv_lms.qc.

Referenced by MUTATOR_HOOKFUNCTION().