racer.qc File Reference

#include "racer.qh"
#include <common/gametypes/gametype/ctf/sv_ctf.qh>
#include <common/mapobjects/trigger/impulse.qh>

Include dependency graph for racer.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	racer_align4point (entity this, entity player, float _delta)
void	racer_blowup (entity this)
void	racer_blowup_think (entity this)
void	racer_deadtouch (entity this, entity toucher)
void	racer_exit (entity this, int eject)
void	racer_fire_rocket_aim (entity this, entity player, string tagname, entity trg)
bool	racer_frame (entity this, float dt)
void	racer_think (entity this)
	spawnfunc (vehicle_racer)
var	vector (entity this, string tag_name, float spring_length, float max_power) racer_force_from_tag

Variables
bool	autocvar_g_vehicle_racer = true
float	autocvar_g_vehicle_racer_afterburn_cost = 130
float	autocvar_g_vehicle_racer_anglestabilizer = 1.75
float	autocvar_g_vehicle_racer_blowup_coredamage = 250
float	autocvar_g_vehicle_racer_blowup_edgedamage = 15
float	autocvar_g_vehicle_racer_blowup_forceintensity = 250
float	autocvar_g_vehicle_racer_blowup_radius = 250
float	autocvar_g_vehicle_racer_bouncefactor = 0.25
vector	autocvar_g_vehicle_racer_bouncepain = '200 0.15 150'
float	autocvar_g_vehicle_racer_bouncestop = 0
float	autocvar_g_vehicle_racer_downforce = 0.01
float	autocvar_g_vehicle_racer_energy = 100
float	autocvar_g_vehicle_racer_energy_regen = 90
float	autocvar_g_vehicle_racer_energy_regen_pause = 0.35
float	autocvar_g_vehicle_racer_friction = 0.45
float	autocvar_g_vehicle_racer_health = 200
float	autocvar_g_vehicle_racer_health_regen = 0
float	autocvar_g_vehicle_racer_health_regen_pause = 0
float	autocvar_g_vehicle_racer_hoverpower = 8000
int	autocvar_g_vehicle_racer_hovertype = 0
float	autocvar_g_vehicle_racer_pitchlimit = 30
float	autocvar_g_vehicle_racer_pitchspeed = 125
float	autocvar_g_vehicle_racer_respawntime = 35
float	autocvar_g_vehicle_racer_rocket_locked_time = 4
float	autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5
float	autocvar_g_vehicle_racer_rocket_locking_time = 0.35
bool	autocvar_g_vehicle_racer_rocket_locktarget = true
float	autocvar_g_vehicle_racer_shield = 100
float	autocvar_g_vehicle_racer_shield_regen = 30
float	autocvar_g_vehicle_racer_shield_regen_pause = 1
float	autocvar_g_vehicle_racer_speed_afterburn = 3000
float	autocvar_g_vehicle_racer_speed_forward = 650
float	autocvar_g_vehicle_racer_speed_strafe = 650
float	autocvar_g_vehicle_racer_springlength = 90
float	autocvar_g_vehicle_racer_thinkrate = 0.05
float	autocvar_g_vehicle_racer_turnroll = 30
float	autocvar_g_vehicle_racer_turnspeed = 220
float	autocvar_g_vehicle_racer_upforcedamper = 2
float	autocvar_g_vehicle_racer_water_downforce = 0.03
float	autocvar_g_vehicle_racer_water_speed_forward = 600
float	autocvar_g_vehicle_racer_water_speed_strafe = 600
float	autocvar_g_vehicle_racer_water_time = 5
float	autocvar_g_vehicle_racer_water_upforcedamper = 15
float	autocvar_g_vehicle_racer_waterburn_cost = 5
float	autocvar_g_vehicle_racer_waterburn_speed = 750
float	racer_air_finished
float	racer_watertime

Function Documentation

racer_align4point()

void racer_align4point	(	entity	this,
		entity	player,
		float	_delta )

Definition at line 88 of file racer.qc.

{
    vector push_vector;
    float fl_push, fr_push, bl_push, br_push;
 
    push_vector  = this.racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    fr_push = force_fromtag_normpower;
    //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 
    push_vector += this.racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    fl_push = force_fromtag_normpower;
    //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 
    push_vector += this.racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    br_push = force_fromtag_normpower;
    //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 
    push_vector += this.racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    bl_push = force_fromtag_normpower;
    //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 
    this.velocity += push_vector * _delta;
 
    float uforce = autocvar_g_vehicle_racer_upforcedamper;
 
    int cont = pointcontents(this.origin - '0 0 64');
    if (cont == CONTENT_WATER
    ||  cont == CONTENT_LAVA
    ||  cont == CONTENT_SLIME)
    {
        uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 
        if (PHYS_INPUT_BUTTON_CROUCH(player) && time < this.racer_air_finished)
            this.velocity.z += 30;
        else
            this.velocity.z += 200;
    }
 
 
    // Anti ocilation
    if (this.velocity.z > 0)
        this.velocity.z *= 1 - uforce * _delta;
 
    push_vector.x  = fl_push - bl_push;
    push_vector.x += fr_push - br_push;
    push_vector.x *= 360;
 
    push_vector.z  = fr_push - fl_push;
    push_vector.z += br_push - bl_push;
    push_vector.z *= 360;
 
    // Apply angle diffrance
    this.angles.z += push_vector.z * _delta;
    this.angles.x += push_vector.x * _delta;
 
    // Apply stabilizer
    this.angles.x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
    this.angles.z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
}

References angles, autocvar_g_vehicle_racer_anglestabilizer, autocvar_g_vehicle_racer_hoverpower, autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_upforcedamper, autocvar_g_vehicle_racer_water_upforcedamper, CONTENT_LAVA, CONTENT_SLIME, CONTENT_WATER, entity(), force_fromtag_normpower, origin, PHYS_INPUT_BUTTON_CROUCH, racer_air_finished, time, vector, and velocity.

Referenced by racer_frame().

racer_blowup()

void racer_blowup

(

entity

this

)

Definition at line 472 of file racer.qc.

{
    this.deadflag = DEAD_DEAD;
    this.vehicle_exit(this, VHEF_NORMAL);
 
    RadiusDamage(this, this.enemy,
        autocvar_g_vehicle_racer_blowup_coredamage,
        autocvar_g_vehicle_racer_blowup_edgedamage,
        autocvar_g_vehicle_racer_blowup_radius,
        NULL,
        NULL,
        autocvar_g_vehicle_racer_blowup_forceintensity,
        DEATH_VH_WAKI_DEATH.m_id,
        DMG_NOWEP,
        NULL
    );
 
    this.nextthink = time + autocvar_g_vehicle_racer_respawntime;
    setthink(this, vehicles_spawn);
    set_movetype(this, MOVETYPE_NONE);
    this.effects = EF_NODRAW;
    this.solid = SOLID_NOT;
 
    this.colormod   = '0 0 0';
    this.avelocity  = '0 0 0';
    this.velocity   = '0 0 0';
 
    setorigin(this, this.pos1);
}

References autocvar_g_vehicle_racer_blowup_coredamage, autocvar_g_vehicle_racer_blowup_edgedamage, autocvar_g_vehicle_racer_blowup_forceintensity, autocvar_g_vehicle_racer_blowup_radius, autocvar_g_vehicle_racer_respawntime, avelocity, colormod, DEAD_DEAD, deadflag, DMG_NOWEP, EF_NODRAW, effects, enemy, entity(), MOVETYPE_NONE, nextthink, NULL, pos1, RadiusDamage(), set_movetype(), setthink, solid, SOLID_NOT, time, vehicles_spawn(), velocity, and VHEF_NORMAL.

Referenced by racer_blowup_think(), and racer_deadtouch().

racer_blowup_think()

void racer_blowup_think

(

entity

this

)

Definition at line 502 of file racer.qc.

{
    this.nextthink = time;
 
    if (time >= this.delay)
        racer_blowup(this);
 
    //CSQCMODEL_AUTOUPDATE(this);
}

References delay, entity(), nextthink, racer_blowup(), and time.

racer_deadtouch()

void racer_deadtouch	(	entity	this,
		entity	toucher )

Definition at line 512 of file racer.qc.

{
    this.avelocity.x *= 0.7;
    --this.cnt;
    if (this.cnt <= 0)
        racer_blowup(this);
}

References avelocity, cnt, entity(), racer_blowup(), and toucher.

racer_exit()

void racer_exit	(	entity	this,
		int	eject )

Definition at line 429 of file racer.qc.

{
    setthink(this, racer_think);
    this.nextthink  = time;
    set_movetype(this, MOVETYPE_BOUNCE);
    sound(this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 
    if (!this.owner)
        return;
 
    makevectors(this.angles);
    vector spot;
    if (eject)
    {
        spot = this.origin + v_forward * 100 + '0 0 64';
        spot = vehicles_findgoodexit(this, this.owner, spot);
        setorigin(this.owner, spot);
        this.owner.velocity = (v_up + v_forward * 0.25) * 750;
        this.owner.oldvelocity = this.owner.velocity;
    }
    else
    {
        if (vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
        {
            this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
            this.owner.velocity.z += 200;
            spot = this.origin + v_forward * 32 + '0 0 32';
            spot = vehicles_findgoodexit(this, this.owner, spot);
        }
        else
        {
            this.owner.velocity = this.velocity * 0.5;
            this.owner.velocity.z += 10;
            spot = this.origin - v_forward * 200 + '0 0 32';
            spot = vehicles_findgoodexit(this, this.owner, spot);
        }
        this.owner.oldvelocity = this.owner.velocity;
        setorigin(this.owner, spot);
    }
    antilag_clear(this.owner, CS(this.owner));
    this.owner = NULL;
}

References angles, antilag_clear(), ATTEN_NORM, autocvar_sv_maxairspeed, CH_TRIGGER_SINGLE, CS(), entity(), makevectors, MOVETYPE_BOUNCE, nextthink, normalize(), NULL, origin, owner, racer_think(), set_movetype(), setthink, sound, time, tur_head, v_forward, v_up, vdist, vector, vehicles_findgoodexit(), velocity, and VOL_VEHICLEENGINE.

racer_fire_rocket_aim()

void racer_fire_rocket_aim	(	entity	this,
		entity	player,
		string	tagname,
		entity	trg )

Definition at line 148 of file racer.qc.

{
    vector v = gettaginfo(this, gettagindex(this, tagname));
    racer_fire_rocket(this, player, v, v_forward, trg);
}

References entity(), gettagindex, gettaginfo, racer_fire_rocket(), v_forward, and vector.

Referenced by racer_frame().

racer_frame()

bool racer_frame	(	entity	this,
		float	dt )

Definition at line 154 of file racer.qc.

{
    entity player = this;
    entity vehic = player.vehicle;
    return = true;
 
#ifdef SVQC
    if (game_stopped)
    {
        vehic.solid = SOLID_NOT;
        vehic.takedamage = DAMAGE_NO;
        set_movetype(vehic, MOVETYPE_NONE);
        return;
    }
#endif
 
    vehicles_frame(vehic, player);
 
    int cont = Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(vehic.origin));
    if (!(cont & DPCONTENTS_WATER))
        vehic.racer_air_finished = 0;
    else if (!vehic.racer_air_finished)
        vehic.racer_air_finished = time + autocvar_g_vehicle_racer_water_time;
 
#ifdef SVQC
    if (IS_DEAD(vehic))
    {
        PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
        return;
    }
#endif
 
    racer_align4point(vehic, player, dt);
 
#ifdef SVQC
    PHYS_INPUT_BUTTON_ZOOM(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
#endif
 
    vehic.angles.x = -vehic.angles.x;
 
    // Yaw
    float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
    ftmp = bound(-ftmp, shortangle_f(player.v_angle.y - vehic.angles.y, vehic.angles.y), ftmp);
    vehic.angles.y = anglemods(vehic.angles.y + ftmp);
 
    // Roll
    vehic.angles.z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 
    // Pitch
    ftmp = autocvar_g_vehicle_racer_pitchspeed * dt;
    ftmp = bound(-ftmp, shortangle_f(player.v_angle.x - vehic.angles.x, vehic.angles.x), ftmp);
    vehic.angles.x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles.x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 
    makevectors(vehic.angles);
    vehic.angles.x = -vehic.angles.x;
 
    //ftmp = vehic.velocity.z;
    vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
    //vehic.velocity.z = ftmp;
 
    if (PHYS_CS(player).movement)
    {
        if (cont & DPCONTENTS_LIQUIDSMASK)
        {
            if (PHYS_CS(player).movement.x)
                df += v_forward * (PHYS_CS(player).movement.x > 0 ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward);
            if (PHYS_CS(player).movement.y)
                df += v_right   * (PHYS_CS(player).movement.y > 0 ? autocvar_g_vehicle_racer_water_speed_strafe  : -autocvar_g_vehicle_racer_water_speed_strafe);
        }
        else
        {
            if (PHYS_CS(player).movement.x)
                df += v_forward * (PHYS_CS(player).movement.x > 0 ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward);
            if (PHYS_CS(player).movement.y)
                df += v_right * (PHYS_CS(player).movement.y > 0 ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe);
        }
 
#ifdef SVQC
        if (vehic.sound_nexttime < time || vehic.sounds != 1)
        {
            vehic.sounds = 1;
            vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
            sound(vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
        }
#endif
    }
#ifdef SVQC
    else
    {
        if (vehic.sound_nexttime < time || vehic.sounds != 0)
        {
            vehic.sounds = 0;
            vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
            sound(vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
        }
    }
#endif
 
    // Afterburn
    if (PHYS_INPUT_BUTTON_JUMP(player) && vehic.vehicle_energy >= autocvar_g_vehicle_racer_afterburn_cost * dt)
    {
#ifdef SVQC
        if (time - vehic.wait > 0.2)
            pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
#endif
 
        vehic.wait = time;
 
        if (cont & DPCONTENTS_LIQUIDSMASK)
        {
            vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
            df += v_forward * autocvar_g_vehicle_racer_waterburn_speed;
        }
        else
        {
            vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
            df += v_forward * autocvar_g_vehicle_racer_speed_afterburn;
        }
 
#ifdef SVQC
        // TODO: move these to the client side where they belong
        // NOTE: reusing .invincible_finished here as delay counter for the smoke effect
        if (vehic.invincible_finished < time)
        {
            traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
            if (trace_fraction != 1.0)
                pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 
            vehic.invincible_finished = time + 0.1 + (random() * 0.1);
        }
 
        // NOTE: reusing .strength_finished here as a sound delay counter
        if (vehic.strength_finished < time)
        {
            vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
            sound(vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
        }
#endif
    }
    else
    {
        vehic.strength_finished = 0;
        sound(vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
    }
 
    if (cont & DPCONTENTS_LIQUIDSMASK)
        vehic.racer_watertime = time;
 
    float dforce = autocvar_g_vehicle_racer_downforce;
    if (time - vehic.racer_watertime <= 3)
        dforce = autocvar_g_vehicle_racer_water_downforce;
 
    df -= v_up * (vlen(vehic.velocity) * dforce);
    PHYS_CS(player).movement = vehic.velocity += df * dt;
 
#ifdef SVQC
 
    Weapon wep1 = WEP_RACER;
    .entity weaponentity = weaponentities[0]; // TODO: unhardcode
    if (!weaponLocked(player) && !weaponUseForbidden(player)
    && PHYS_INPUT_BUTTON_ATCK(player)
    &&  wep1.wr_checkammo1(wep1, vehic, weaponentity))
        wep1.wr_think(wep1, vehic, weaponentity, 1);
 
    if (autocvar_g_vehicle_racer_rocket_locktarget)
    {
        if (time >= vehic.vehicle_last_trace)
        {
            crosshair_trace(player);
 
            vehicles_locktarget(vehic, dt / autocvar_g_vehicle_racer_rocket_locking_time,
                dt / autocvar_g_vehicle_racer_rocket_locking_releasetime,
                autocvar_g_vehicle_racer_rocket_locked_time);
 
            vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
        }
 
        if (vehic.lock_target)
        {
            if (vehic.lock_strength == 1)
                UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '1 0 0', 0);
            else if (vehic.lock_strength > 0.5)
                UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 1 0', 0);
            else if (vehic.lock_strength < 0.5)
                UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 0 1', 0);
        }
    }
 
    if (!weaponLocked(player) && !weaponUseForbidden(player)
    && time > vehic.delay
    && PHYS_INPUT_BUTTON_ATCK2(player))
    {
        ++vehic.misc_bulletcounter;
        vehic.delay = time + 0.3;
 
        if (vehic.misc_bulletcounter == 1)
        {
            racer_fire_rocket_aim(vehic, player, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
            player.vehicle_ammo2 = 50;
        }
        else if (vehic.misc_bulletcounter == 2)
        {
            racer_fire_rocket_aim(vehic, player, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
            vehic.lock_strength = 0;
            vehic.lock_target = NULL;
            vehic.misc_bulletcounter = 0;
            vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
            vehic.lip = time;
            player.vehicle_ammo2 = 0;
        }
    }
    else if (vehic.misc_bulletcounter == 0)
        player.vehicle_ammo2 = 100;
 
    player.vehicle_reload2 = bound(0, 100 * (time - vehic.lip) / (vehic.delay - vehic.lip), 100);
 
    if (vehic.vehicle_flags & VHF_SHIELDREGEN)
        vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 
    if (vehic.vehicle_flags & VHF_HEALTHREGEN)
        vehicles_regen_resource(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false, RES_HEALTH);
 
    if (vehic.vehicle_flags & VHF_ENERGYREGEN)
        vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 
    VEHICLE_UPDATE_PLAYER_RESOURCE(player, vehic, health, racer, RES_HEALTH);
    VEHICLE_UPDATE_PLAYER(player, vehic, energy, racer);
 
    if (vehic.vehicle_flags & VHF_HASSHIELD)
        VEHICLE_UPDATE_PLAYER(player, vehic, shield, racer);
 
    PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
#endif
 
    setorigin(player, vehic.origin + '0 0 32');
#ifdef SVQC
    player.oldorigin = player.origin; // negate fall damage
#endif
    player.velocity = vehic.velocity;
}

References anglemods(), ATTEN_NORM, autocvar_g_vehicle_racer_afterburn_cost, autocvar_g_vehicle_racer_downforce, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_friction, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_pitchlimit, autocvar_g_vehicle_racer_pitchspeed, autocvar_g_vehicle_racer_rocket_locked_time, autocvar_g_vehicle_racer_rocket_locking_releasetime, autocvar_g_vehicle_racer_rocket_locking_time, autocvar_g_vehicle_racer_rocket_locktarget, autocvar_g_vehicle_racer_rocket_refire, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_speed_afterburn, autocvar_g_vehicle_racer_speed_forward, autocvar_g_vehicle_racer_speed_strafe, autocvar_g_vehicle_racer_thinkrate, autocvar_g_vehicle_racer_turnroll, autocvar_g_vehicle_racer_turnspeed, autocvar_g_vehicle_racer_water_downforce, autocvar_g_vehicle_racer_water_speed_forward, autocvar_g_vehicle_racer_water_speed_strafe, autocvar_g_vehicle_racer_water_time, autocvar_g_vehicle_racer_waterburn_cost, autocvar_g_vehicle_racer_waterburn_speed, bound(), CH_TRIGGER_SINGLE, crosshair_trace(), DAMAGE_NO, DPCONTENTS_LIQUIDSMASK, DPCONTENTS_WATER, entity(), game_stopped, health, IS_DEAD, makevectors, Mod_Q1BSP_SuperContentsFromNativeContents(), MOVE_NORMAL, movement, MOVETYPE_NONE, NULL, PHYS_CS, PHYS_INPUT_BUTTON_ATCK, PHYS_INPUT_BUTTON_ATCK2, PHYS_INPUT_BUTTON_CROUCH, PHYS_INPUT_BUTTON_JUMP, PHYS_INPUT_BUTTON_ZOOM, pointparticles, racer_align4point(), racer_fire_rocket_aim(), random(), real_origin(), set_movetype(), shortangle_f(), SOLID_NOT, sound, time, trace_endpos, trace_fraction, UpdateAuxiliaryXhair(), v_forward, v_right, v_up, vector, vehicle_energy, vehicle_health, vehicle_shield, VEHICLE_UPDATE_PLAYER, VEHICLE_UPDATE_PLAYER_RESOURCE, vehicles_frame(), vehicles_locktarget(), vehicles_regen(), vehicles_regen_resource(), VHF_ENERGYREGEN, VHF_HASSHIELD, VHF_HEALTHREGEN, VHF_SHIELDREGEN, vlen(), VOL_VEHICLEENGINE, weaponentities, weaponLocked(), weaponUseForbidden(), Weapon::wr_checkammo1(), and Weapon::wr_think().

racer_think()

void racer_think

(

entity

this

)

Definition at line 397 of file racer.qc.

{
    float dt = autocvar_g_vehicle_racer_thinkrate;
 
    this.nextthink = time + dt;
 
    tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 
    vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
    df.z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * autocvar_g_vehicle_racer_springlength * 2;
 
    float forced = autocvar_g_vehicle_racer_upforcedamper;
 
    //int cont = pointcontents(this.origin - '0 0 64');
    traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
    //if (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
    if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
    {
        forced = autocvar_g_vehicle_racer_water_upforcedamper;
        this.velocity.z += 200;
    }
 
    this.velocity += df * dt;
    if (this.velocity.z > 0)
        this.velocity.z *= 1 - forced * dt;
 
    this.angles.x *= 1 - autocvar_g_vehicle_racer_anglestabilizer * dt;
    this.angles.z *= 1 - autocvar_g_vehicle_racer_anglestabilizer * dt;
 
    CSQCMODEL_AUTOUPDATE(this);
}

References angles, autocvar_g_vehicle_racer_anglestabilizer, autocvar_g_vehicle_racer_friction, autocvar_g_vehicle_racer_hoverpower, autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_thinkrate, autocvar_g_vehicle_racer_upforcedamper, autocvar_g_vehicle_racer_water_upforcedamper, CSQCMODEL_AUTOUPDATE, DPCONTENTS_LIQUIDSMASK, entity(), maxs, mins, MOVE_NOMONSTERS, nextthink, origin, sin(), time, trace_dpstartcontents, trace_fraction, vector, and velocity.

Referenced by racer_exit().

spawnfunc()

spawnfunc

(

vehicle_racer

)

Definition at line 520 of file racer.qc.

{
    if (!autocvar_g_vehicle_racer
    || !vehicle_initialize(this, VEH_RACER, false))
    {
        delete(this);
        return;
    }
}

References autocvar_g_vehicle_racer, and vehicle_initialize().

vector()

var vector	(	entity	this,
		string	tag_name,
		float	spring_length,
		float	max_power )

References entity().

Variable Documentation

autocvar_g_vehicle_racer

bool autocvar_g_vehicle_racer = true

Definition at line 11 of file racer.qc.

Referenced by spawnfunc().

autocvar_g_vehicle_racer_afterburn_cost

float autocvar_g_vehicle_racer_afterburn_cost = 130

Definition at line 17 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_anglestabilizer

float autocvar_g_vehicle_racer_anglestabilizer = 1.75

Definition at line 30 of file racer.qc.

Referenced by racer_align4point(), and racer_think().

autocvar_g_vehicle_racer_blowup_coredamage

float autocvar_g_vehicle_racer_blowup_coredamage = 250

Definition at line 72 of file racer.qc.

Referenced by racer_blowup().

autocvar_g_vehicle_racer_blowup_edgedamage

float autocvar_g_vehicle_racer_blowup_edgedamage = 15

Definition at line 73 of file racer.qc.

Referenced by racer_blowup().

autocvar_g_vehicle_racer_blowup_forceintensity

float autocvar_g_vehicle_racer_blowup_forceintensity = 250

Definition at line 74 of file racer.qc.

Referenced by racer_blowup().

autocvar_g_vehicle_racer_blowup_radius

float autocvar_g_vehicle_racer_blowup_radius = 250

Definition at line 71 of file racer.qc.

Referenced by racer_blowup().

autocvar_g_vehicle_racer_bouncefactor

float autocvar_g_vehicle_racer_bouncefactor = 0.25

Definition at line 77 of file racer.qc.

autocvar_g_vehicle_racer_bouncepain

vector autocvar_g_vehicle_racer_bouncepain = '200 0.15 150'

Definition at line 81 of file racer.qc.

autocvar_g_vehicle_racer_bouncestop

float autocvar_g_vehicle_racer_bouncestop = 0

Definition at line 79 of file racer.qc.

autocvar_g_vehicle_racer_downforce

float autocvar_g_vehicle_racer_downforce = 0.01

Definition at line 31 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_energy

float autocvar_g_vehicle_racer_energy = 100

Definition at line 52 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_energy_regen

float autocvar_g_vehicle_racer_energy_regen = 90

Definition at line 53 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_energy_regen_pause

float autocvar_g_vehicle_racer_energy_regen_pause = 0.35

Definition at line 54 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_friction

float autocvar_g_vehicle_racer_friction = 0.45

Definition at line 37 of file racer.qc.

Referenced by racer_frame(), and racer_think().

autocvar_g_vehicle_racer_health

float autocvar_g_vehicle_racer_health = 200

Definition at line 56 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_health_regen

float autocvar_g_vehicle_racer_health_regen = 0

Definition at line 57 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_health_regen_pause

float autocvar_g_vehicle_racer_health_regen_pause = 0

Definition at line 58 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_hoverpower

float autocvar_g_vehicle_racer_hoverpower = 8000

Definition at line 46 of file racer.qc.

Referenced by racer_align4point(), and racer_think().

autocvar_g_vehicle_racer_hovertype

int autocvar_g_vehicle_racer_hovertype = 0

Definition at line 44 of file racer.qc.

autocvar_g_vehicle_racer_pitchlimit

float autocvar_g_vehicle_racer_pitchlimit = 30

Definition at line 25 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_pitchspeed

float autocvar_g_vehicle_racer_pitchspeed = 125

Definition at line 50 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_respawntime

float autocvar_g_vehicle_racer_respawntime = 35

Definition at line 69 of file racer.qc.

Referenced by racer_blowup().

autocvar_g_vehicle_racer_rocket_locked_time

float autocvar_g_vehicle_racer_rocket_locked_time = 4

Definition at line 67 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_rocket_locking_releasetime

float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5

Definition at line 66 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_rocket_locking_time

float autocvar_g_vehicle_racer_rocket_locking_time = 0.35

Definition at line 65 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_rocket_locktarget

bool autocvar_g_vehicle_racer_rocket_locktarget = true

Definition at line 64 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_shield

float autocvar_g_vehicle_racer_shield = 100

Definition at line 60 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_shield_regen

float autocvar_g_vehicle_racer_shield_regen = 30

Definition at line 61 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_shield_regen_pause

float autocvar_g_vehicle_racer_shield_regen_pause = 1

Definition at line 62 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_speed_afterburn

float autocvar_g_vehicle_racer_speed_afterburn = 3000

Definition at line 15 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_speed_forward

float autocvar_g_vehicle_racer_speed_forward = 650

Definition at line 33 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_speed_strafe

float autocvar_g_vehicle_racer_speed_strafe = 650

Definition at line 34 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_springlength

float autocvar_g_vehicle_racer_springlength = 90

Definition at line 35 of file racer.qc.

Referenced by racer_align4point(), and racer_think().

autocvar_g_vehicle_racer_thinkrate

float autocvar_g_vehicle_racer_thinkrate = 0.05

Definition at line 13 of file racer.qc.

Referenced by racer_frame(), and racer_think().

autocvar_g_vehicle_racer_turnroll

float autocvar_g_vehicle_racer_turnroll = 30

Definition at line 48 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_turnspeed

float autocvar_g_vehicle_racer_turnspeed = 220

Definition at line 49 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_upforcedamper

float autocvar_g_vehicle_racer_upforcedamper = 2

Definition at line 36 of file racer.qc.

Referenced by racer_align4point(), and racer_think().

autocvar_g_vehicle_racer_water_downforce

float autocvar_g_vehicle_racer_water_downforce = 0.03

Definition at line 27 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_water_speed_forward

float autocvar_g_vehicle_racer_water_speed_forward = 600

Definition at line 22 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_water_speed_strafe

float autocvar_g_vehicle_racer_water_speed_strafe = 600

Definition at line 23 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_water_time

float autocvar_g_vehicle_racer_water_time = 5

Definition at line 39 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_water_upforcedamper

float autocvar_g_vehicle_racer_water_upforcedamper = 15

Definition at line 28 of file racer.qc.

Referenced by racer_align4point(), and racer_think().

autocvar_g_vehicle_racer_waterburn_cost

float autocvar_g_vehicle_racer_waterburn_cost = 5

Definition at line 19 of file racer.qc.

Referenced by racer_frame().

autocvar_g_vehicle_racer_waterburn_speed

float autocvar_g_vehicle_racer_waterburn_speed = 750

Definition at line 20 of file racer.qc.

Referenced by racer_frame().

racer_air_finished

float racer_air_finished

Definition at line 84 of file racer.qc.

Referenced by racer_align4point().

racer_watertime

float racer_watertime

Definition at line 83 of file racer.qc.