devastator.qc File Reference

#include "devastator.qh"
#include <common/items/item/ammo.qh>
#include <common/mutators/mutator/rocketflying/rocketflying.qh>
#include "vortex.qh"

Include dependency graph for devastator.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	W_Devastator_Attack (Weapon thiswep, entity actor,.entity weaponentity, int fire)
void	W_Devastator_Damage (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	W_Devastator_DoRemoteExplode (entity this,.entity weaponentity)
void	W_Devastator_Explode (entity this, entity directhitentity)
void	W_Devastator_Explode_think (entity this)
void	W_Devastator_RemoteExplode (entity this,.entity weaponentity)
vector	W_Devastator_SteerTo (vector thisdir, vector goaldir, float maxturn_cos)
void	W_Devastator_Think (entity this)
void	W_Devastator_Touch (entity this, entity toucher)
void	W_Devastator_Unregister (entity this)

Variables
entity	lastrocket

Function Documentation

W_Devastator_Attack()

void W_Devastator_Attack	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		int	fire )

Definition at line 312 of file devastator.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR(WEP_DEVASTATOR, ammo), weaponentity);
 
    W_SetupShot_ProjectileSize(actor, weaponentity, '-3 -3 -3', '3 3 3', false, 5, SND_DEVASTATOR_FIRE, CH_WEAPON_A, WEP_CVAR(WEP_DEVASTATOR, damage), thiswep.m_id);
    W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 
    entity missile = WarpZone_RefSys_SpawnSameRefSys(actor);
    missile.weaponentity_fld = weaponentity;
    missile.owner = missile.realowner = actor;
    actor.(weaponentity).lastrocket = missile;
    if(WEP_CVAR(WEP_DEVASTATOR, detonatedelay) >= 0)
        missile.spawnshieldtime = time + WEP_CVAR(WEP_DEVASTATOR, detonatedelay);
    else
        missile.spawnshieldtime = -1; // NOTE: proximity based when rocket jumping
    missile.pushltime = time + WEP_CVAR(WEP_DEVASTATOR, guidedelay);
    missile.classname = "rocket";
    missile.bot_dodge = true;
    missile.bot_dodgerating = WEP_CVAR(WEP_DEVASTATOR, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 
    missile.takedamage = DAMAGE_YES;
    missile.damageforcescale = WEP_CVAR(WEP_DEVASTATOR, damageforcescale);
    SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(WEP_DEVASTATOR, health));
    missile.event_damage = W_Devastator_Damage;
    missile.damagedbycontents = true;
    IL_PUSH(g_damagedbycontents, missile);
 
    set_movetype(missile, MOVETYPE_FLY);
    PROJECTILE_MAKETRIGGER(missile);
    missile.projectiledeathtype = thiswep.m_id;
    setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 
    setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
    W_SetupProjVelocity_Basic(missile, WEP_CVAR(WEP_DEVASTATOR, speedstart), 0);
    missile.angles = vectoangles(missile.velocity);
 
    settouch(missile, W_Devastator_Touch);
    setthink(missile, W_Devastator_Think);
    missile.nextthink = time;
    missile.cnt = time + WEP_CVAR(WEP_DEVASTATOR, lifetime);
    missile.rl_detonate_later = (fire & 2); // allow instant detonation
    missile.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, missile);
    IL_PUSH(g_bot_dodge, missile);
    missile.missile_flags = MIF_SPLASH;
 
    CSQCProjectile(missile, WEP_CVAR(WEP_DEVASTATOR, guiderate) == 0 && WEP_CVAR(WEP_DEVASTATOR, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 
    // common properties
    MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 
    if (time >= missile.nextthink)
    {
        getthink(missile)(missile);
    }
}

References ammo, CH_WEAPON_A, CSQCProjectile(), DAMAGE_YES, damageforcescale, entity(), FL_PROJECTILE, g_bot_dodge, g_damagedbycontents, g_projectiles, getthink, health, IL_PUSH(), lastrocket, lifetime, Weapon::m_id, MIF_SPLASH, MOVETYPE_FLY, MUTATOR_CALLHOOK, PROJECTILE_MAKETRIGGER, PROJECTILE_ROCKET, set_movetype(), SetResourceExplicit(), setthink, settouch, time, v_forward, vectoangles(), W_DecreaseAmmo(), W_Devastator_Damage(), W_Devastator_Think(), W_Devastator_Touch(), W_MuzzleFlash(), W_SetupProjVelocity_Basic, W_SetupShot_ProjectileSize, w_shotdir, w_shotorg, WarpZone_RefSys_SpawnSameRefSys(), and WEP_CVAR.

W_Devastator_Damage()

void W_Devastator_Damage	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 297 of file devastator.qc.

{
    if(GetResource(this, RES_HEALTH) <= 0)
        return;
 
    if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
        return; // g_projectiles_damage says to halt
 
    TakeResource(this, RES_HEALTH, damage);
    this.angles = vectoangles(this.velocity);
 
    if(GetResource(this, RES_HEALTH) <= 0)
        W_PrepareExplosionByDamage(this, attacker, W_Devastator_Explode_think);
}

References angles, entity(), GetResource(), TakeResource(), vectoangles(), vector, velocity, W_CheckProjectileDamage(), W_Devastator_Explode_think(), and W_PrepareExplosionByDamage().

Referenced by W_Devastator_Attack().

W_Devastator_DoRemoteExplode()

void W_Devastator_DoRemoteExplode	(	entity	this,
		.entity	weaponentity )

Definition at line 73 of file devastator.qc.

{
    W_Devastator_Unregister(this);
 
    this.event_damage = func_null;
    this.takedamage = DAMAGE_NO;
 
    bool handled_as_rocketjump = false;
    entity head = NULL;
    bool allow_rocketjump = WEP_CVAR(WEP_DEVASTATOR, remote_jump);
    MUTATOR_CALLHOOK(AllowRocketJumping, allow_rocketjump);
    allow_rocketjump = M_ARGV(0, bool);
 
    if(allow_rocketjump && WEP_CVAR(WEP_DEVASTATOR, remote_jump_radius))
    {
        head = WarpZone_FindRadius(
            this.origin,
            WEP_CVAR(WEP_DEVASTATOR, remote_jump_radius),
            false
        );
 
        while(head)
        {
            if(head.takedamage && (head == this.realowner))
            {
                if(vdist(this.origin - head.WarpZone_findradius_nearest, <=, WEP_CVAR(WEP_DEVASTATOR, remote_jump_radius)))
                {
                    // we handled this as a rocketjump :)
                    handled_as_rocketjump = true;
 
                    // modify velocity
                    if(WEP_CVAR(WEP_DEVASTATOR, remote_jump_velocity_z_add))
                    {
                        head.velocity_x *= 0.9;
                        head.velocity_y *= 0.9;
                        head.velocity_z = bound(
                            WEP_CVAR(WEP_DEVASTATOR, remote_jump_velocity_z_min),
                            head.velocity.z + WEP_CVAR(WEP_DEVASTATOR, remote_jump_velocity_z_add),
                            WEP_CVAR(WEP_DEVASTATOR, remote_jump_velocity_z_max)
                        );
                    }
 
                    // now do the damage
                    RadiusDamage(
                        this,
                        head,
                        WEP_CVAR(WEP_DEVASTATOR, remote_jump_damage),
                        WEP_CVAR(WEP_DEVASTATOR, remote_jump_damage),
                        WEP_CVAR(WEP_DEVASTATOR, remote_jump_radius),
                        NULL,
                        head,
                        (WEP_CVAR(WEP_DEVASTATOR, remote_jump_force) ? WEP_CVAR(WEP_DEVASTATOR, remote_jump_force) : 0),
                        this.projectiledeathtype | HITTYPE_BOUNCE,
                        this.weaponentity_fld,
                        NULL
                    );
                    break;
                }
            }
            head = head.chain;
        }
    }
 
    RadiusDamage(
        this,
        this.realowner,
        WEP_CVAR(WEP_DEVASTATOR, remote_damage),
        WEP_CVAR(WEP_DEVASTATOR, remote_edgedamage),
        WEP_CVAR(WEP_DEVASTATOR, remote_radius),
        (handled_as_rocketjump ? head : NULL),
        NULL,
        WEP_CVAR(WEP_DEVASTATOR, remote_force),
        this.projectiledeathtype | HITTYPE_BOUNCE,
        this.weaponentity_fld,
        NULL
    );
 
    Weapon thiswep = WEP_DEVASTATOR;
    if(this.realowner.(weaponentity).m_weapon == thiswep)
    {
        if(GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(WEP_DEVASTATOR, ammo))
        if(!(this.realowner.items & IT_UNLIMITED_AMMO))
        {
            this.realowner.cnt = thiswep.m_id;
            ATTACK_FINISHED(this.realowner, weaponentity) = time;
            this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
        }
    }
    delete(this);
}

References ammo, Weapon::ammo_type, ATTACK_FINISHED, bound(), DAMAGE_NO, entity(), func_null(), GetResource(), HITTYPE_BOUNCE, IT_UNLIMITED_AMMO, M_ARGV, Weapon::m_id, m_switchweapon, MUTATOR_CALLHOOK, NULL, origin, projectiledeathtype, RadiusDamage(), realowner, takedamage, time, vdist, W_Devastator_Unregister(), w_getbestweapon, WarpZone_FindRadius(), weaponentity_fld, and WEP_CVAR.

Referenced by W_Devastator_RemoteExplode().

W_Devastator_Explode()

void W_Devastator_Explode	(	entity	this,
		entity	directhitentity )

Definition at line 17 of file devastator.qc.

{
    W_Devastator_Unregister(this);
 
    if(directhitentity.takedamage == DAMAGE_AIM)
        if(IS_PLAYER(directhitentity))
            if(DIFF_TEAM(this.realowner, directhitentity))
                if(!IS_DEAD(directhitentity))
                    if(IsFlying(directhitentity))
                        Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 
    this.event_damage = func_null;
    this.takedamage = DAMAGE_NO;
 
    vector force_xyzscale = '1 1 1';
    force_xyzscale.x = WEP_CVAR(WEP_DEVASTATOR, force_xyscale);
    force_xyzscale.y = WEP_CVAR(WEP_DEVASTATOR, force_xyscale);
 
    RadiusDamageForSource(
        this,
        this.origin,
        this.velocity,
        this.realowner,
        WEP_CVAR(WEP_DEVASTATOR, damage),
        WEP_CVAR(WEP_DEVASTATOR, edgedamage),
        WEP_CVAR(WEP_DEVASTATOR, radius),
        NULL,
        NULL,
        false,
        WEP_CVAR(WEP_DEVASTATOR, force),
        force_xyzscale,
        this.projectiledeathtype,
        this.weaponentity_fld,
        directhitentity
    );
 
    Weapon thiswep = WEP_DEVASTATOR;
    .entity weaponentity = this.weaponentity_fld;
    if(this.realowner.(weaponentity).m_weapon == thiswep)
    {
        if(GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(WEP_DEVASTATOR, ammo))
        if(!(this.realowner.items & IT_UNLIMITED_AMMO))
        {
            this.realowner.cnt = thiswep.m_id;
            ATTACK_FINISHED(this.realowner, weaponentity) = time;
            this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
        }
    }
    delete(this);
}

References ammo, Weapon::ammo_type, ATTACK_FINISHED, DAMAGE_AIM, DAMAGE_NO, DIFF_TEAM, entity(), func_null(), GetResource(), IS_DEAD, IS_PLAYER, IsFlying(), IT_UNLIMITED_AMMO, Weapon::m_id, m_switchweapon, NULL, origin, projectiledeathtype, radius, RadiusDamageForSource(), realowner, Send_Notification(), takedamage, time, vector, velocity, W_Devastator_Unregister(), w_getbestweapon, weaponentity_fld, and WEP_CVAR.

Referenced by W_Devastator_Explode_think(), W_Devastator_Think(), and W_Devastator_Touch().

W_Devastator_Explode_think()

void W_Devastator_Explode_think

(

entity

this

)

Definition at line 68 of file devastator.qc.

{
    W_Devastator_Explode(this, NULL);
}

References entity(), NULL, and W_Devastator_Explode().

Referenced by W_Devastator_Damage().

W_Devastator_RemoteExplode()

void W_Devastator_RemoteExplode	(	entity	this,
		.entity	weaponentity )

Definition at line 164 of file devastator.qc.

{
    if(!IS_DEAD(this.realowner))
    if(this.realowner.(weaponentity).lastrocket)
    {
        if((this.spawnshieldtime >= 0)
            ? (time >= this.spawnshieldtime) // timer
            : (vdist(NearestPointOnBox(this.realowner, this.origin) - this.origin, >, WEP_CVAR(WEP_DEVASTATOR, remote_radius))) // safety device
        )
        {
            W_Devastator_DoRemoteExplode(this, weaponentity);
        }
    }
}

References entity(), IS_DEAD, NearestPointOnBox(), origin, realowner, spawnshieldtime, time, vdist, W_Devastator_DoRemoteExplode(), and WEP_CVAR.

Referenced by W_Devastator_Think().

W_Devastator_SteerTo()

vector W_Devastator_SteerTo	(	vector	thisdir,
		vector	goaldir,
		float	maxturn_cos )

Definition at line 179 of file devastator.qc.

{
    if(thisdir * goaldir > maxturn_cos)
        return goaldir;
    if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
        return thisdir; // refuse to guide (better than letting a numerical error happen)
    float f, m2;
    vector v;
    // solve:
    //   g = normalize(thisdir + goaldir * X)
    //   thisdir * g = maxturn
    //
    //   gg = thisdir + goaldir * X
    //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
    //
    //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
    f = thisdir * goaldir;
    //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
    //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
    m2 = maxturn_cos * maxturn_cos;
    v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
    return normalize(thisdir + goaldir * v.y); // the larger solution!
}

References normalize(), solve_quadratic(), and vector.

Referenced by W_Devastator_Think().

W_Devastator_Think()

void W_Devastator_Think

(

entity

this

)

Definition at line 212 of file devastator.qc.

{
    vector desireddir, olddir, newdir, desiredorigin, goal;
    float velspeed, f;
    this.nextthink = time;
    if(time > this.cnt)
    {
        this.projectiledeathtype |= HITTYPE_BOUNCE;
        W_Devastator_Explode(this, NULL);
        return;
    }
 
    // accelerate
    makevectors(this.angles.x * '-1 0 0' + this.angles.y * '0 1 0');
    velspeed = WEP_CVAR(WEP_DEVASTATOR, speed) * W_WeaponSpeedFactor(this.realowner) - (this.velocity * v_forward);
    if(velspeed > 0)
        this.velocity = this.velocity + v_forward * min(WEP_CVAR(WEP_DEVASTATOR, speedaccel) * W_WeaponSpeedFactor(this.realowner) * frametime, velspeed);
 
    // laser guided, or remote detonation
    .entity weaponentity = this.weaponentity_fld;
    if(this.realowner.(weaponentity).m_weapon == WEP_DEVASTATOR)
    {
        if(this == this.realowner.(weaponentity).lastrocket)
        if(!this.realowner.(weaponentity).rl_release)
        if(!PHYS_INPUT_BUTTON_ATCK2(this))
        if(WEP_CVAR(WEP_DEVASTATOR, guiderate))
        if(time > this.pushltime)
        if(!IS_DEAD(this.realowner))
        {
            f = WEP_CVAR(WEP_DEVASTATOR, guideratedelay);
            if(f)
                f = bound(0, (time - this.pushltime) / f, 1);
            else
                f = 1;
 
            vector md = this.realowner.(weaponentity).movedir;
            vector dv = v_right * -md.y + v_up * md.z;
 
            if(!W_DualWielding(this.realowner))
                dv = '0 0 0'; // don't override!
 
            velspeed = vlen(this.velocity);
 
            makevectors(this.realowner.v_angle);
            desireddir = WarpZone_RefSys_TransformVelocity(this.realowner, this, v_forward);
            desiredorigin = WarpZone_RefSys_TransformOrigin(this.realowner, this, this.realowner.origin + this.realowner.view_ofs + dv);
            olddir = normalize(this.velocity);
 
            // now it gets tricky... we want to move like some curve to approximate the target direction
            // but we are limiting the rate at which we can turn!
            goal = desiredorigin + ((this.origin - desiredorigin) * desireddir + WEP_CVAR(WEP_DEVASTATOR, guidegoal)) * desireddir;
            newdir = W_Devastator_SteerTo(olddir, normalize(goal - this.origin), cos(WEP_CVAR(WEP_DEVASTATOR, guiderate) * f * frametime * DEG2RAD));
 
            this.velocity = newdir * velspeed;
            this.angles = vectoangles(this.velocity);
 
            if(!this.count)
            {
                Send_Effect(EFFECT_ROCKET_GUIDE, this.origin, this.velocity, 1);
                // TODO add a better sound here
                sound(this.realowner, CH_WEAPON_B, SND_DEVASTATOR_MODE, VOL_BASE, ATTN_NORM);
                this.count = 1;
            }
        }
 
        if(this.rl_detonate_later)
            W_Devastator_RemoteExplode(this, weaponentity);
    }
 
    if(this.csqcprojectile_clientanimate == 0)
        UpdateCSQCProjectile(this);
}

References angles, ATTN_NORM, bound(), CH_WEAPON_B, cnt, cos(), count, csqcprojectile_clientanimate, DEG2RAD, entity(), frametime, HITTYPE_BOUNCE, IS_DEAD, makevectors, min(), movedir, nextthink, normalize(), NULL, origin, PHYS_INPUT_BUTTON_ATCK2, projectiledeathtype, pushltime, realowner, rl_detonate_later, Send_Effect(), sound, speed, time, UpdateCSQCProjectile(), v_forward, v_right, v_up, vectoangles(), vector, velocity, vlen(), VOL_BASE, W_Devastator_Explode(), W_Devastator_RemoteExplode(), W_Devastator_SteerTo(), W_DualWielding(), W_WeaponSpeedFactor(), WarpZone_RefSys_TransformOrigin(), WarpZone_RefSys_TransformVelocity(), weaponentity_fld, and WEP_CVAR.

Referenced by W_Devastator_Attack().

W_Devastator_Touch()

void W_Devastator_Touch	(	entity	this,
		entity	toucher )

Definition at line 285 of file devastator.qc.

{
    if(WarpZone_Projectile_Touch(this, toucher))
    {
        if(wasfreed(this))
            W_Devastator_Unregister(this);
        return;
    }
    W_Devastator_Unregister(this);
    W_Devastator_Explode(this, toucher);
}

References entity(), toucher, W_Devastator_Explode(), W_Devastator_Unregister(), and WarpZone_Projectile_Touch().

Referenced by W_Devastator_Attack().

W_Devastator_Unregister()

void W_Devastator_Unregister

(

entity

this

)

Definition at line 7 of file devastator.qc.

{
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if(this.realowner.(weaponentity).lastrocket == this)
            this.realowner.(weaponentity).lastrocket = NULL;
    }
}

References entity(), lastrocket, MAX_WEAPONSLOTS, NULL, realowner, and weaponentities.

Referenced by W_Devastator_DoRemoteExplode(), W_Devastator_Explode(), and W_Devastator_Touch().

Variable Documentation

lastrocket

entity lastrocket

Definition at line 5 of file devastator.qc.

Referenced by W_Devastator_Attack(), and W_Devastator_Unregister().