electro.qc File Reference

#include "electro.qh"
#include <common/effects/qc/_mod.qh>
#include <common/gametypes/gametype/ctf/ctf.qh>
#include <common/items/item/ammo.qh>

Include dependency graph for electro.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	electro_orb_draw (entity this)
bool	electro_orb_send (entity this, entity to, int sf)
void	electro_orb_setup (entity e)
	NET_HANDLE (Electro_Orb, bool isNew)
void	W_Electro_Attack_Bolt (Weapon thiswep, entity actor,.entity weaponentity)
void	W_Electro_Attack_Orb (Weapon thiswep, entity actor,.entity weaponentity)
void	W_Electro_Bolt_Think (entity this)
void	W_Electro_CheckAttack (Weapon thiswep, entity actor,.entity weaponentity, int fire)
void	W_Electro_Explode (entity this, entity directhitentity)
void	W_Electro_Explode_use (entity this, entity actor, entity trigger)
void	W_Electro_ExplodeCombo (entity this)
void	W_Electro_ExplodeComboThink (entity this)
void	W_Electro_Orb_Damage (entity this, entity inflictor, entity attacker, float damage, int deathtype,.entity weaponentity, vector hitloc, vector force)
void	W_Electro_Orb_ExplodeOverTime (entity this)
void	W_Electro_Orb_Follow_Think (entity this)
void	W_Electro_Orb_Stick (entity this, entity to)
void	W_Electro_Orb_Touch (entity this, entity toucher)
bool	W_Electro_search_cond (entity e)
void	W_Electro_TouchExplode (entity this, entity toucher)
void	W_Electro_TriggerCombo (vector org, float rad, entity own)

Variables
bool	bot_secondary_electromooth
const float	ELECTRO_COMBO_OVERTIME_DELAY = 0.0625
float	ltime

Function Documentation

electro_orb_draw()

void electro_orb_draw

(

entity

this

)

Definition at line 8 of file electro.qc.

{
    float dt = time - this.move_time;
    this.move_time = time;
    if (dt <= 0)
        return;
 
    float myscale = bound(0, (this.ltime - time) * 4, 1);
    this.scale = (WEP_CVAR(WEP_ELECTRO, combo_radius) * 0.05) * myscale;
    this.angles += dt * this.avelocity;
}

References angles, avelocity, bound(), entity(), ltime, move_time, scale, time, and WEP_CVAR.

Referenced by electro_orb_setup().

electro_orb_send()

bool electro_orb_send	(	entity	this,
		entity	to,
		int	sf )

Definition at line 56 of file electro.qc.

{
    int channel = MSG_ENTITY;
    WriteHeader(channel, Electro_Orb);
    WriteVector(channel, this.origin);
    WriteByte(channel, etof(this.realowner));
    // round time delta to a 1/10th of a second
    WriteByte(channel, (this.ltime - time) * 10 + 0.5);
    return true;
}

References entity(), etof, ltime, MSG_ENTITY, origin, realowner, time, WriteByte(), and WriteHeader.

Referenced by W_Electro_Orb_ExplodeOverTime().

electro_orb_setup()

void electro_orb_setup

(

entity

e

)

Definition at line 20 of file electro.qc.

{
    setmodel(e, MDL_PROJECTILE_ELECTRO);
    setsize(e, '-4 -4 -4', '4 4 4');
 
    setorigin(e, e.origin);
 
    e.draw = electro_orb_draw;
    IL_PUSH(g_drawables, e);
    SetResourceExplicit(e, RES_HEALTH, 255);
    set_movetype(e, MOVETYPE_NONE);
    e.solid = SOLID_NOT;
    e.avelocity = '7 0 11';
    e.drawmask = MASK_NORMAL;
    e.alpha = 0.7;
}

References electro_orb_draw(), entity(), g_drawables, IL_PUSH(), MASK_NORMAL, MOVETYPE_NONE, set_movetype(), setmodel, SetResourceExplicit(), and SOLID_NOT.

Referenced by NET_HANDLE().

NET_HANDLE()

NET_HANDLE	(	Electro_Orb	,
		bool	isNew )

Definition at line 41 of file electro.qc.

{
    Net_Accept(Electro_Orb);
    this.origin = ReadVector();
    int myowner = ReadByte();
    setorigin(this, this.origin);
    this.colormap = entcs_GetClientColors(myowner - 1);
    this.ltime = time + ReadByte() / 10.0;
    // this.ltime = time + this.orb_lifetime;
    electro_orb_setup(this);
    return true;
}

References colormap, electro_orb_setup(), entcs_GetClientColors(), ltime, origin, ReadByte(), ReadVector, and time.

W_Electro_Attack_Bolt()

void W_Electro_Attack_Bolt	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity )

Definition at line 300 of file electro.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(WEP_ELECTRO, ammo), weaponentity);
 
    W_SetupShot_ProjectileSize(
        actor,
        weaponentity,
        '0 0 -3',
        '0 0 -3',
        false,
        2,
        SND_ELECTRO_FIRE,
        CH_WEAPON_A,
        WEP_CVAR_PRI(WEP_ELECTRO, damage),
        thiswep.m_id
    );
 
    W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 
    entity proj = new(electro_bolt);
    proj.owner = proj.realowner = actor;
    proj.bot_dodge = true;
    proj.bot_dodgerating = WEP_CVAR_PRI(WEP_ELECTRO, damage);
    proj.use = W_Electro_Explode_use;
    setthink(proj, W_Electro_Bolt_Think);
    proj.nextthink = time;
    proj.ltime = time + WEP_CVAR_PRI(WEP_ELECTRO, lifetime);
    PROJECTILE_MAKETRIGGER(proj);
    proj.projectiledeathtype = thiswep.m_id;
    proj.weaponentity_fld = weaponentity;
    setorigin(proj, w_shotorg);
 
    // if (IS_CSQC)
    set_movetype(proj, MOVETYPE_FLY);
    W_SetupProjVelocity_PRI(proj, WEP_ELECTRO);
    proj.angles = vectoangles(proj.velocity);
    settouch(proj, W_Electro_TouchExplode);
    setsize(proj, '0 0 -3', '0 0 -3');
    proj.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, proj);
    IL_PUSH(g_bot_dodge, proj);
    proj.missile_flags = MIF_SPLASH;
 
    CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
 
    MUTATOR_CALLHOOK(EditProjectile, actor, proj);
    // proj.com_phys_pos = proj.origin;
    // proj.com_phys_vel = proj.velocity;
}

References ammo, CH_WEAPON_A, CSQCProjectile(), entity(), FL_PROJECTILE, g_bot_dodge, g_projectiles, IL_PUSH(), lifetime, Weapon::m_id, MIF_SPLASH, MOVETYPE_FLY, MUTATOR_CALLHOOK, PROJECTILE_ELECTRO_BEAM, PROJECTILE_MAKETRIGGER, set_movetype(), setthink, settouch, time, vectoangles(), W_DecreaseAmmo(), W_Electro_Bolt_Think(), W_Electro_Explode_use(), W_Electro_TouchExplode(), W_MuzzleFlash(), W_SetupProjVelocity_PRI, W_SetupShot_ProjectileSize, w_shotdir, w_shotorg, and WEP_CVAR_PRI.

W_Electro_Attack_Orb()

void W_Electro_Attack_Orb	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity )

Definition at line 499 of file electro.qc.

{
    W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(WEP_ELECTRO, ammo), weaponentity);
 
    W_SetupShot_ProjectileSize(
        actor,
        weaponentity,
        '-4 -4 -4',
        '4 4 4',
        false,
        2,
        SND_ELECTRO_FIRE2,
        CH_WEAPON_A,
        WEP_CVAR_SEC(WEP_ELECTRO, damage),
        thiswep.m_id | HITTYPE_SECONDARY
    );
 
    w_shotdir = v_forward; // no TrueAim for grenades please
 
    W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 
    entity proj = new(electro_orb);
    proj.owner = proj.realowner = actor;
    proj.use = W_Electro_Explode_use;
    setthink(proj, adaptor_think2use_hittype_splash);
    proj.bot_dodge = true;
    proj.bot_dodgerating = WEP_CVAR_SEC(WEP_ELECTRO, damage);
    proj.nextthink = time + WEP_CVAR_SEC(WEP_ELECTRO, lifetime);
    proj.death_time = time + WEP_CVAR_SEC(WEP_ELECTRO, lifetime);
    PROJECTILE_MAKETRIGGER(proj);
    proj.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
    proj.weaponentity_fld = weaponentity;
    setorigin(proj, w_shotorg);
 
    //proj.glow_size = 50;
    //proj.glow_color = 45;
    set_movetype(proj, MOVETYPE_BOUNCE);
    W_SetupProjVelocity_UP_SEC(proj, WEP_ELECTRO);
    settouch(proj, W_Electro_Orb_Touch);
    setsize(proj, '-4 -4 -4', '4 4 4');
    proj.takedamage = DAMAGE_YES;
    proj.damageforcescale = WEP_CVAR_SEC(WEP_ELECTRO, damageforcescale);
    SetResourceExplicit(proj, RES_HEALTH, WEP_CVAR_SEC(WEP_ELECTRO, health));
    proj.event_damage = W_Electro_Orb_Damage;
    proj.flags = FL_PROJECTILE;
    IL_PUSH(g_projectiles, proj);
    IL_PUSH(g_bot_dodge, proj);
    proj.damagedbycontents = (WEP_CVAR_SEC(WEP_ELECTRO, damagedbycontents));
    if (proj.damagedbycontents)
        IL_PUSH(g_damagedbycontents, proj);
 
    proj.bouncefactor = WEP_CVAR_SEC(WEP_ELECTRO, bouncefactor);
    proj.bouncestop = WEP_CVAR_SEC(WEP_ELECTRO, bouncestop);
    proj.missile_flags = MIF_SPLASH | MIF_ARC;
 
    if (WEP_CVAR_SEC(WEP_ELECTRO, limit) > 0)
    {
        if (!LimitedElectroBallRubbleList)
            LimitedElectroBallRubbleList = IL_NEW();
        ListNewChildRubble(LimitedElectroBallRubbleList, proj);
        LimitedChildrenRubble(LimitedElectroBallRubbleList, "electro_orb", WEP_CVAR_SEC(WEP_ELECTRO, limit), adaptor_think2use_hittype_splash, actor);
    }
 
    CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
 
    MUTATOR_CALLHOOK(EditProjectile, actor, proj);
}

References adaptor_think2use_hittype_splash(), ammo, bouncefactor, bouncestop, CH_WEAPON_A, CSQCProjectile(), DAMAGE_YES, damagedbycontents, damageforcescale, entity(), FL_PROJECTILE, g_bot_dodge, g_damagedbycontents, g_projectiles, health, HITTYPE_SECONDARY, IL_NEW, IL_PUSH(), lifetime, LimitedChildrenRubble(), LimitedElectroBallRubbleList, ListNewChildRubble(), Weapon::m_id, MIF_ARC, MIF_SPLASH, MOVETYPE_BOUNCE, MUTATOR_CALLHOOK, PROJECTILE_ELECTRO, PROJECTILE_MAKETRIGGER, set_movetype(), SetResourceExplicit(), setthink, settouch, time, v_forward, W_DecreaseAmmo(), W_Electro_Explode_use(), W_Electro_Orb_Damage(), W_Electro_Orb_Touch(), W_MuzzleFlash(), W_SetupProjVelocity_UP_SEC, W_SetupShot_ProjectileSize, w_shotdir, w_shotorg, and WEP_CVAR_SEC.

Referenced by W_Electro_CheckAttack().

W_Electro_Bolt_Think()

void W_Electro_Bolt_Think

(

entity

this

)

Definition at line 242 of file electro.qc.

{
    // sys_phys_update_single(this);
    if (time >= this.ltime)
    {
        this.use(this, NULL, NULL);
        return;
    }
 
    if (WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_radius))
    {
        int found = 0;
        WarpZone_SearchInRadius_otherent = this.realowner;
        entity e = WarpZone_SearchInRadius(this.origin, WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_radius), MOVE_NOMONSTERS, W_Electro_search_cond);
 
        // loop through nearby orbs and trigger them
        for (; e; e = e.chain)
        {
            bool explode;
            if (this.owner == e.owner)
                explode = WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_own);
            else if (SAME_TEAM(this.owner, e.owner))
                explode = WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_teammate);
            else
                explode = WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_enemy);
 
            if (explode)
            {
                // change owner to whoever caused the combo explosion
                e.realowner = this.realowner;
                e.takedamage = DAMAGE_NO;
                e.classname = "electro_orb_chain";
 
                // Only first orb explosion uses midaircombo_speed, others use the normal combo_speed.
                // This allows to avoid the delay on the first explosion which looks better
                // (the bolt and orb should explode together because they interacted together)
                // while keeping the chaining delay.
                setthink(e, W_Electro_ExplodeCombo);
                float delay = (WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_speed))
                    ? vlen(e.WarpZone_findradius_dist) / WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_speed)
                    : 0;
                e.nextthink = time + delay;
 
                ++found;
            }
        }
 
        // if we triggered an orb, should we explode? if not, lets try again next time
        if (found && WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_explode))
            this.use(this, NULL, NULL);
        else
            this.nextthink = min(time + WEP_CVAR_PRI(WEP_ELECTRO, midaircombo_interval), this.ltime);
    }
    else
        this.nextthink = this.ltime;
    // this.nextthink = time;
}

References DAMAGE_NO, delay, entity(), ltime, min(), MOVE_NOMONSTERS, nextthink, NULL, origin, owner, realowner, SAME_TEAM, setthink, time, use, vlen(), W_Electro_ExplodeCombo(), W_Electro_search_cond(), WarpZone_SearchInRadius(), WarpZone_SearchInRadius_otherent, and WEP_CVAR_PRI.

Referenced by W_Electro_Attack_Bolt().

W_Electro_CheckAttack()

void W_Electro_CheckAttack	(	Weapon	thiswep,
		entity	actor,
		.entity	weaponentity,
		int	fire )

Definition at line 567 of file electro.qc.

{
    if (actor.(weaponentity).electro_count > 1
    && PHYS_INPUT_BUTTON_ATCK2(actor)
    && weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
    {
        W_Electro_Attack_Orb(thiswep, actor, weaponentity);
        --actor.(weaponentity).electro_count;
        actor.(weaponentity).electro_secondarytime = time;
        weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(WEP_ELECTRO, animtime), W_Electro_CheckAttack);
        return;
    }
    w_ready(thiswep, actor, weaponentity, fire);
}

References electro_count, electro_secondarytime, entity(), PHYS_INPUT_BUTTON_ATCK2, time, W_Electro_Attack_Orb(), W_Electro_CheckAttack(), w_ready(), weapon_prepareattack(), weapon_thinkf(), and WEP_CVAR_SEC.

Referenced by W_Electro_CheckAttack().

W_Electro_Explode()

void W_Electro_Explode	(	entity	this,
		entity	directhitentity )

Definition at line 185 of file electro.qc.

{
    if (directhitentity.takedamage == DAMAGE_AIM
    && IS_PLAYER(directhitentity) && DIFF_TEAM(this.realowner, directhitentity) && !IS_DEAD(directhitentity)
    && IsFlying(directhitentity))
        Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 
    this.event_damage = func_null;
    this.takedamage = DAMAGE_NO;
    if (!this.velocity)
        this.velocity = this.movedir; // .velocity must be != '0 0 0' for particle fx and decal to work
 
    if (this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
        RadiusDamage(this, this.realowner,
            WEP_CVAR_SEC(WEP_ELECTRO, damage),
            WEP_CVAR_SEC(WEP_ELECTRO, edgedamage),
            WEP_CVAR_SEC(WEP_ELECTRO, radius),
            NULL,
            NULL,
            WEP_CVAR_SEC(WEP_ELECTRO, force),
            this.projectiledeathtype,
            this.weaponentity_fld,
            directhitentity
        );
    else
    {
        W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(WEP_ELECTRO, comboradius), this.realowner);
        RadiusDamage(this, this.realowner,
            WEP_CVAR_PRI(WEP_ELECTRO, damage),
            WEP_CVAR_PRI(WEP_ELECTRO, edgedamage),
            WEP_CVAR_PRI(WEP_ELECTRO, radius),
            NULL,
            NULL,
            WEP_CVAR_PRI(WEP_ELECTRO, force),
            this.projectiledeathtype,
            this.weaponentity_fld,
            directhitentity
        );
    }
 
    delete(this);
}

References classname, DAMAGE_AIM, DAMAGE_NO, DIFF_TEAM, entity(), func_null(), IS_DEAD, IS_PLAYER, IsFlying(), move_movetype, movedir, MOVETYPE_BOUNCE, NULL, origin, projectiledeathtype, radius, RadiusDamage(), realowner, Send_Notification(), takedamage, velocity, W_Electro_TriggerCombo(), weaponentity_fld, WEP_CVAR_PRI, and WEP_CVAR_SEC.

Referenced by W_Electro_Explode_use(), W_Electro_Orb_Touch(), and W_Electro_TouchExplode().

W_Electro_Explode_use()

void W_Electro_Explode_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 228 of file electro.qc.

{
    W_Electro_Explode(this, trigger);
}

References entity(), and W_Electro_Explode().

Referenced by W_Electro_Attack_Bolt(), W_Electro_Attack_Orb(), and W_Electro_Orb_Damage().

W_Electro_ExplodeCombo()

void W_Electro_ExplodeCombo

(

entity

this

)

Definition at line 154 of file electro.qc.

{
    W_Electro_TriggerCombo(this.origin, WEP_CVAR(WEP_ELECTRO, combo_comboradius), this.realowner);
 
    this.event_damage = func_null;
    if (!this.velocity)
        this.velocity = this.movedir; // .velocity must be != '0 0 0' for particle fx and decal to work
 
    if (WEP_CVAR(WEP_ELECTRO, combo_duration))
    {
        W_Electro_Orb_ExplodeOverTime(this);
 
        delete(this);
        return;
    }
 
    RadiusDamage(this, this.realowner,
        WEP_CVAR(WEP_ELECTRO, combo_damage),
        WEP_CVAR(WEP_ELECTRO, combo_edgedamage),
        WEP_CVAR(WEP_ELECTRO, combo_radius),
        NULL,
        NULL,
        WEP_CVAR(WEP_ELECTRO, combo_force),
        WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
        this.weaponentity_fld,
        NULL
    );
 
    delete(this);
}

References entity(), func_null(), HITTYPE_BOUNCE, movedir, NULL, origin, RadiusDamage(), realowner, velocity, W_Electro_Orb_ExplodeOverTime(), W_Electro_TriggerCombo(), and WEP_CVAR.

Referenced by W_Electro_Bolt_Think(), W_Electro_Orb_Damage(), and W_Electro_TriggerCombo().

W_Electro_ExplodeComboThink()

void W_Electro_ExplodeComboThink

(

entity

this

)

Definition at line 118 of file electro.qc.

{
    W_DamageOverTime_Think(this,
        WEP_CVAR(WEP_ELECTRO, combo_duration),
        1,
        WEP_CVAR(WEP_ELECTRO, combo_damage),
        WEP_CVAR(WEP_ELECTRO, combo_edgedamage),
        WEP_CVAR(WEP_ELECTRO, combo_radius),
        0,
        NULL,
        ELECTRO_COMBO_OVERTIME_DELAY);
}

References ELECTRO_COMBO_OVERTIME_DELAY, entity(), NULL, W_DamageOverTime_Think(), and WEP_CVAR.

Referenced by W_Electro_Orb_ExplodeOverTime().

W_Electro_Orb_Damage()

void W_Electro_Orb_Damage	(	entity	this,
		entity	inflictor,
		entity	attacker,
		float	damage,
		int	deathtype,
		.entity	weaponentity,
		vector	hitloc,
		vector	force )

Definition at line 463 of file electro.qc.

{
    if (GetResource(this, RES_HEALTH) <= 0)
        return;
 
    // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
    float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
 
    if (!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
        return; // g_projectiles_damage says to halt
 
    TakeResource(this, RES_HEALTH, damage);
    if (GetResource(this, RES_HEALTH) <= 0)
    {
        this.takedamage = DAMAGE_NO;
        this.nextthink = time;
        if (is_combo)
        {
            // change owner to whoever caused the combo explosion
            this.realowner = inflictor.realowner;
            this.classname = "electro_orb_chain";
            setthink(this, W_Electro_ExplodeCombo);
            // delay combo chains, looks cooler
            // bound the length, inflictor may be in a galaxy far far away (warpzones)
            float len = min(WEP_CVAR(WEP_ELECTRO, combo_radius), vlen(this.origin - inflictor.origin));
            float delay = len / WEP_CVAR(WEP_ELECTRO, combo_speed);
            this.nextthink = time + delay;
        }
        else
        {
            this.use = W_Electro_Explode_use;
            setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
        }
    }
}

References classname, DAMAGE_NO, delay, entity(), GetResource(), min(), nextthink, origin, realowner, setthink, takedamage, TakeResource(), time, use, vector, vlen(), W_CheckProjectileDamage(), W_Electro_Explode_use(), W_Electro_ExplodeCombo(), and WEP_CVAR.

Referenced by W_Electro_Attack_Orb().

W_Electro_Orb_ExplodeOverTime()

void W_Electro_Orb_ExplodeOverTime

(

entity

this

)

Definition at line 131 of file electro.qc.

{
    entity newproj = spawn();
    newproj.classname = this.classname;
    newproj.solid = this.solid;
    setorigin(newproj, this.origin);
    setmodel(newproj, MDL_PROJECTILE_ELECTRO);
    setsize(newproj, this.mins, this.maxs);
    newproj.owner = this.owner;
    newproj.realowner = this.realowner;
    newproj.weaponentity_fld = this.weaponentity_fld;
    newproj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_BOUNCE; // use THIS type for a combo because primary can't bounce
 
    setthink(newproj, W_Electro_ExplodeComboThink);
    newproj.nextthink = time + ELECTRO_COMBO_OVERTIME_DELAY;
    newproj.teleport_time = time;
    newproj.dmg_last = 1;
    set_movetype(newproj, MOVETYPE_NONE);
 
    Net_LinkEntity(newproj, true, 0, electro_orb_send);
    newproj.SendFlags = 0xFFFFFF;
}

References classname, ELECTRO_COMBO_OVERTIME_DELAY, electro_orb_send(), entity(), HITTYPE_BOUNCE, maxs, mins, MOVETYPE_NONE, Net_LinkEntity(), origin, owner, realowner, set_movetype(), setmodel, setthink, solid, spawn, time, W_Electro_ExplodeComboThink(), and weaponentity_fld.

Referenced by W_Electro_ExplodeCombo().

W_Electro_Orb_Follow_Think()

void W_Electro_Orb_Follow_Think

(

entity

this

)

Definition at line 350 of file electro.qc.

{
    if (time > this.death_time)
    {
        adaptor_think2use_hittype_splash(this);
        return;
    }
    if (this.move_movetype == MOVETYPE_FOLLOW)
    {
        int lost = LostMovetypeFollow(this);
        if (lost == 2)
        {
            // FIXME if player disconnected, it isn't possible to drop the orb at player's origin
            // see comment in LostMovetypeFollow implementation
            delete(this);
            return;
        }
        if (lost)
        {
            // drop the orb at the corpse's location
            PROJECTILE_MAKETRIGGER(this);
            set_movetype(this, MOVETYPE_TOSS);
 
            setthink(this, adaptor_think2use_hittype_splash);
            this.nextthink = this.death_time;
            return;
        }
    }
    this.nextthink = time;
}

References adaptor_think2use_hittype_splash(), death_time, entity(), LostMovetypeFollow(), move_movetype, MOVETYPE_FOLLOW, MOVETYPE_TOSS, nextthink, PROJECTILE_MAKETRIGGER, set_movetype(), setthink, and time.

Referenced by W_Electro_Orb_Stick().

W_Electro_Orb_Stick()

void W_Electro_Orb_Stick	(	entity	this,
		entity	to )

Definition at line 381 of file electro.qc.

{
    entity newproj = spawn();
    newproj.classname = this.classname;
 
    newproj.bot_dodge = this.bot_dodge;
    newproj.bot_dodgerating = this.bot_dodgerating;
 
    newproj.owner = this.owner;
    newproj.realowner = this.realowner;
    PROJECTILE_MAKETRIGGER(newproj);
    setorigin(newproj, this.origin);
    setmodel(newproj, MDL_PROJECTILE_ELECTRO);
    setsize(newproj, this.mins, this.maxs);
    newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
    newproj.traileffectnum = _particleeffectnum(EFFECT_TR_NEXUIZPLASMA.eent_eff_name);
 
    newproj.movedir = -trace_plane_normal;
 
    newproj.takedamage = this.takedamage;
    newproj.damageforcescale = this.damageforcescale;
    SetResourceExplicit(newproj, RES_HEALTH, GetResource(this, RES_HEALTH));
    newproj.event_damage = this.event_damage;
    newproj.spawnshieldtime = this.spawnshieldtime;
    newproj.damagedbycontents = true;
    IL_PUSH(g_damagedbycontents, newproj);
 
    set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
    newproj.projectiledeathtype = this.projectiledeathtype;
    newproj.weaponentity_fld = this.weaponentity_fld;
 
    settouch(newproj, func_null);
    if (WEP_CVAR_SEC(WEP_ELECTRO, stick_lifetime) > 0)
        newproj.death_time = time + WEP_CVAR_SEC(WEP_ELECTRO, stick_lifetime);
    else
        newproj.death_time = this.death_time;
    newproj.use = this.use;
    newproj.flags = this.flags;
    IL_PUSH(g_projectiles, newproj);
    IL_PUSH(g_bot_dodge, newproj);
 
    // check if limits are enabled (we can tell by checking if the original orb is listed) and push it to the list if so
    if (LimitedElectroBallRubbleList && IL_CONTAINS(LimitedElectroBallRubbleList, this))
        ReplaceOldListedChildRubble(LimitedElectroBallRubbleList, newproj, this);
 
    delete(this);
 
    if (to)
    {
        SetMovetypeFollow(newproj, to);
 
        setthink(newproj, W_Electro_Orb_Follow_Think);
        newproj.nextthink = time;
    }
    else
    {
        setthink(newproj, adaptor_think2use_hittype_splash);
        newproj.nextthink = newproj.death_time;
    }
}

References adaptor_think2use_hittype_splash(), bot_dodge, bot_dodgerating, classname, damageforcescale, death_time, entity(), flags, func_null(), g_bot_dodge, g_damagedbycontents, g_projectiles, GetResource(), IL_CONTAINS(), IL_PUSH(), LimitedElectroBallRubbleList, maxs, mins, MOVETYPE_NONE, origin, owner, PROJECTILE_MAKETRIGGER, projectiledeathtype, realowner, ReplaceOldListedChildRubble(), set_movetype(), setmodel, SetMovetypeFollow(), SetResourceExplicit(), setthink, settouch, spawn, spawnshieldtime, takedamage, time, trace_plane_normal, use, vectoangles(), W_Electro_Orb_Follow_Think(), weaponentity_fld, and WEP_CVAR_SEC.

Referenced by W_Electro_Orb_Touch().

W_Electro_Orb_Touch()

void W_Electro_Orb_Touch	(	entity	this,
		entity	toucher )

Definition at line 442 of file electro.qc.

{
    PROJECTILE_TOUCH(this, toucher);
    if (toucher.takedamage == DAMAGE_AIM && WEP_CVAR_SEC(WEP_ELECTRO, touchexplode))
        W_Electro_Explode(this, toucher);
    else if (toucher.owner != this.owner && toucher.classname != this.classname) // don't stick to player's other projectiles!
    {
        //UpdateCSQCProjectile(this);
        spamsound(this, CH_SHOTS, SND_ELECTRO_BOUNCE, VOL_BASE, ATTEN_NORM);
        this.projectiledeathtype |= HITTYPE_BOUNCE;
 
        if (WEP_CVAR_SEC(WEP_ELECTRO, stick))
        {
            if (WEP_CVAR_SEC(WEP_ELECTRO, stick_lifetime) == 0)
                W_Electro_Explode(this, toucher);
            else
                W_Electro_Orb_Stick(this, toucher);
        }
    }
}

References ATTEN_NORM, CH_SHOTS, DAMAGE_AIM, entity(), HITTYPE_BOUNCE, PROJECTILE_TOUCH, projectiledeathtype, spamsound(), toucher, VOL_BASE, W_Electro_Explode(), W_Electro_Orb_Stick(), and WEP_CVAR_SEC.

Referenced by W_Electro_Attack_Orb().

W_Electro_search_cond()

bool W_Electro_search_cond

(

entity

e

)

Definition at line 73 of file electro.qc.

{
    return (e.classname == "electro_orb"
        && !(IS_INDEPENDENT_PLAYER(e.realowner) && WarpZone_SearchInRadius_otherent != e.realowner));
    // check if the ball we are exploding is not owned by an
    // independent player which is not the player who shot the ball
}

References entity(), IS_INDEPENDENT_PLAYER, and WarpZone_SearchInRadius_otherent.

Referenced by W_Electro_Bolt_Think(), and W_Electro_TriggerCombo().

W_Electro_TouchExplode()

void W_Electro_TouchExplode	(	entity	this,
		entity	toucher )

Definition at line 233 of file electro.qc.

{
    PROJECTILE_TOUCH(this, toucher);
    W_Electro_Explode(this, toucher);
}

References entity(), PROJECTILE_TOUCH, toucher, and W_Electro_Explode().

Referenced by W_Electro_Attack_Bolt().

W_Electro_TriggerCombo()

void W_Electro_TriggerCombo	(	vector	org,
		float	rad,
		entity	own )

Definition at line 80 of file electro.qc.

{
    WarpZone_SearchInRadius_otherent = own;
    entity e = WarpZone_SearchInRadius(org, rad, (WEP_CVAR(WEP_ELECTRO, combo_comboradius_thruwall) ? MOVE_NOTHING : MOVE_NOMONSTERS), W_Electro_search_cond);
    for (; e; e = e.chain)
    {
        // do we allow thruwall triggering?
        if (WEP_CVAR(WEP_ELECTRO, combo_comboradius_thruwall))
        {
            // if distance is greater than thruwall distance, check to make sure it's not through a wall
            if (vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(WEP_ELECTRO, combo_comboradius_thruwall)))
            {
                WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
                if (trace_fraction != 1)
                {
                    // trigger is through a wall and outside of thruwall range, abort
                    continue;
                }
            }
        }
 
        // change owner to whoever caused the combo explosion
        e.realowner = own;
        e.takedamage = DAMAGE_NO;
        e.classname = "electro_orb_chain";
 
        // now set the next one to trigger as well
        setthink(e, W_Electro_ExplodeCombo);
 
        // delay combo chains, looks cooler
        float delay = (WEP_CVAR(WEP_ELECTRO, combo_speed))
            ? vlen(e.WarpZone_findradius_dist) / WEP_CVAR(WEP_ELECTRO, combo_speed)
            : 0;
        e.nextthink = time + delay;
    }
}

References DAMAGE_NO, delay, entity(), MOVE_NOMONSTERS, MOVE_NOTHING, org, setthink, time, trace_fraction, vdist, vector, vlen(), W_Electro_ExplodeCombo(), W_Electro_search_cond(), WarpZone_SearchInRadius(), WarpZone_SearchInRadius_otherent, WarpZone_TraceLine, and WEP_CVAR.

Referenced by W_Electro_Explode(), and W_Electro_ExplodeCombo().

Variable Documentation

bot_secondary_electromooth

bool bot_secondary_electromooth

Definition at line 582 of file electro.qc.

ELECTRO_COMBO_OVERTIME_DELAY

const float ELECTRO_COMBO_OVERTIME_DELAY = 0.0625

Definition at line 117 of file electro.qc.

Referenced by W_Electro_ExplodeComboThink(), and W_Electro_Orb_ExplodeOverTime().

ltime

float ltime

Definition at line 7 of file electro.qc.