sv_assault.qc File Reference

#include "sv_assault.qh"
#include <server/command/vote.qh>
#include <common/mapobjects/func/breakable.qh>
#include <common/mapobjects/triggers.qh>
#include <common/turrets/sv_turrets.qh>
#include <server/damage.qh>
#include <server/world.qh>
#include <server/spawnpoints.qh>

Include dependency graph for sv_assault.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	AS_ROUND_DELAY   5

Functions
void	as_round_think ()
bool	assault_decreaser_sprite_visible (entity this, entity player, entity view)
void	assault_new_round (entity this)
void	assault_objective_decrease_use (entity this, entity actor, entity trigger)
void	assault_objective_reset (entity this)
void	assault_objective_use (entity this, entity actor, entity trigger)
void	assault_roundstart_use (entity this, entity actor, entity trigger)
void	assault_roundstart_use_this (entity this)
void	assault_setenemytoobjective (entity this)
void	assault_wall_think (entity this)
bool	destructible_heal (entity targ, entity inflictor, float amount, float limit)
void	havocbot_ast_reset_role (entity this)
void	havocbot_goalrating_ast_targets (entity this, float ratingscale)
void	havocbot_role_ast_defense (entity this)
void	havocbot_role_ast_offense (entity this)
void	havocbot_role_ast_setrole (entity this, float role)
	MUTATOR_HOOKFUNCTION (as, CheckRules_World)
	MUTATOR_HOOKFUNCTION (as, HavocBot_ChooseRole)
	MUTATOR_HOOKFUNCTION (as, OnEntityPreSpawn)
	MUTATOR_HOOKFUNCTION (as, PlayerSpawn)
	MUTATOR_HOOKFUNCTION (as, PlayHitsound)
	MUTATOR_HOOKFUNCTION (as, ReadLevelCvars)
	MUTATOR_HOOKFUNCTION (as, ReadyRestart_Deny)
	MUTATOR_HOOKFUNCTION (as, TeamBalance_CheckAllowedTeams)
	MUTATOR_HOOKFUNCTION (as, TurretSpawn)
	MUTATOR_HOOKFUNCTION (as, VehicleInit)
	spawnfunc (func_assault_destructible)
	spawnfunc (func_assault_wall)
	spawnfunc (info_player_attacker)
	spawnfunc (info_player_defender)
	spawnfunc (target_assault_roundend)
	spawnfunc (target_assault_roundstart)
	spawnfunc (target_objective)
	spawnfunc (target_objective_decrease)
void	target_assault_roundend_reset (entity this)
void	target_assault_roundend_use (entity this, entity actor, entity trigger)
void	target_objective_decrease_activate (entity this)
void	target_objective_decrease_findtarget (entity this)
vector	target_objective_spawn_evalfunc (entity this, entity player, entity spot, vector current)
int	WinningCondition_Assault ()

Variables
entity	as_round
bool	assault_turrets_teamswap_forbidden
entity	ent_winning
entity	sprite

Macro Definition Documentation

AS_ROUND_DELAY

#define AS_ROUND_DELAY   5

Definition at line 12 of file sv_assault.qc.

Referenced by assault_new_round(), and WinningCondition_Assault().

Function Documentation

as_round_think()

void as_round_think

(

)

Definition at line 223 of file sv_assault.qc.

{
    game_stopped = false;
    assault_new_round(as_round.ent_winning);
    delete(as_round);
    as_round = NULL;
}

References as_round, assault_new_round(), game_stopped, and NULL.

Referenced by WinningCondition_Assault().

assault_decreaser_sprite_visible()

bool assault_decreaser_sprite_visible	(	entity	this,
		entity	player,
		entity	view )

Definition at line 98 of file sv_assault.qc.

{
    if(GetResource(this.assault_decreaser.enemy, RES_HEALTH) >= ASSAULT_VALUE_INACTIVE)
        return false;
 
    return true;
}

References assault_decreaser, ASSAULT_VALUE_INACTIVE, entity(), and GetResource().

Referenced by target_objective_decrease_activate().

assault_new_round()

void assault_new_round

(

entity

this

)

Definition at line 196 of file sv_assault.qc.

{
    // up round counter
    this.winning = this.winning + 1;
 
    // swap attacker/defender roles
    if(assault_attacker_team == NUM_TEAM_1)
        assault_attacker_team = NUM_TEAM_2;
    else
        assault_attacker_team = NUM_TEAM_1;
 
    IL_EACH(g_saved_team, !IS_CLIENT(it),
    {
        if(it.team_saved == NUM_TEAM_1)
            it.team_saved = NUM_TEAM_2;
        else if(it.team_saved == NUM_TEAM_2)
            it.team_saved = NUM_TEAM_1;
    });
 
    // reset the level with a countdown
    cvar_set("timelimit", ftos(ceil(time - AS_ROUND_DELAY - game_starttime) / 60));
    bprint("Starting second round...\n");
    ReadyRestart_force(true); // sets game_starttime
}

References AS_ROUND_DELAY, assault_attacker_team, bprint(), ceil(), cvar_set(), entity(), ftos(), g_saved_team, game_starttime, IL_EACH, IS_CLIENT, NUM_TEAM_1, NUM_TEAM_2, ReadyRestart_force(), time, and winning.

Referenced by as_round_think().

assault_objective_decrease_use()

void assault_objective_decrease_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 44 of file sv_assault.qc.

{
    if(actor.team != assault_attacker_team)
    {
        // wrong team triggered decrease
        return;
    }
 
    if(trigger.assault_sprite)
    {
        WaypointSprite_Disown(trigger.assault_sprite, waypointsprite_deadlifetime);
        if(trigger.classname == "func_assault_destructible")
            trigger.sprite = NULL; // TODO: just unsetting it?!
    }
    else
        return; // already activated! cannot activate again!
 
    float hlth = GetResource(this.enemy, RES_HEALTH);
    if (hlth < ASSAULT_VALUE_INACTIVE)
    {
        if (hlth - this.dmg > 0.5)
        {
            GameRules_scoring_add_team(actor, SCORE, this.dmg);
            TakeResource(this.enemy, RES_HEALTH, this.dmg);
        }
        else
        {
            GameRules_scoring_add_team(actor, SCORE, hlth);
            GameRules_scoring_add_team(actor, ASSAULT_OBJECTIVES, 1);
            SetResourceExplicit(this.enemy, RES_HEALTH, -1);
 
            if(this.enemy.message)
                FOREACH_CLIENT(IS_PLAYER(it), { centerprint(it, this.enemy.message); });
 
            SUB_UseTargets(this.enemy, this, trigger);
        }
    }
}

References assault_attacker_team, ASSAULT_VALUE_INACTIVE, centerprint(), dmg, enemy, entity(), FOREACH_CLIENT, GameRules_scoring_add_team, GetResource(), IS_PLAYER, NULL, SetResourceExplicit(), SUB_UseTargets(), TakeResource(), waypointsprite_deadlifetime, and WaypointSprite_Disown().

Referenced by spawnfunc().

assault_objective_reset()

void assault_objective_reset

(

entity

this

)

Definition at line 38 of file sv_assault.qc.

{
    SetResourceExplicit(this, RES_HEALTH, ASSAULT_VALUE_INACTIVE);
}

References ASSAULT_VALUE_INACTIVE, entity(), and SetResourceExplicit().

Referenced by spawnfunc().

assault_objective_use()

void assault_objective_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 15 of file sv_assault.qc.

{
    // activate objective
    SetResourceExplicit(this, RES_HEALTH, 100);
    //print("^2Activated objective ", this.targetname, "=", etos(this), "\n");
    //print("Activator is ", actor.classname, "\n");
 
    IL_EACH(g_assault_objectivedecreasers, it.target == this.targetname,
    {
        target_objective_decrease_activate(it);
    });
}

References entity(), g_assault_objectivedecreasers, IL_EACH, and SetResourceExplicit().

Referenced by spawnfunc().

assault_roundstart_use()

void assault_roundstart_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 153 of file sv_assault.qc.

{
    SUB_UseTargets(this, this, trigger);
 
    // (Re)spawn all turrets
    IL_EACH(g_turrets, true,
    {
        if (!assault_turrets_teamswap_forbidden)
        {
            // Swap turret teams
            if(it.team == NUM_TEAM_1)
                it.team = NUM_TEAM_2;
            else
                it.team = NUM_TEAM_1;
        }
 
        // Doubles as teamchange
        turret_respawn(it);
    });
}

References assault_turrets_teamswap_forbidden, entity(), g_turrets, IL_EACH, NUM_TEAM_1, NUM_TEAM_2, SUB_UseTargets(), and turret_respawn().

Referenced by assault_roundstart_use_this(), and spawnfunc().

assault_roundstart_use_this()

void assault_roundstart_use_this

(

entity

this

)

Definition at line 173 of file sv_assault.qc.

{
    assault_roundstart_use(this, NULL, NULL);
}

References assault_roundstart_use(), entity(), and NULL.

Referenced by spawnfunc().

assault_setenemytoobjective()

void assault_setenemytoobjective

(

entity

this

)

Definition at line 83 of file sv_assault.qc.

{
    IL_EACH(g_assault_objectives, it.targetname == this.target,
    {
        if(this.enemy == NULL)
            this.enemy = it;
        else
            objerror(this, "more than one objective as target - fix the map!");
        break;
    });
 
    if(this.enemy == NULL)
        objerror(this, "no objective as target - fix the map!");
}

References enemy, entity(), g_assault_objectives, IL_EACH, NULL, and objerror.

Referenced by spawnfunc(), and target_objective_decrease_findtarget().

assault_wall_think()

void assault_wall_think

(

entity

this

)

Definition at line 178 of file sv_assault.qc.

{
    if(GetResource(this.enemy, RES_HEALTH) < 0)
    {
        this.model = "";
        this.solid = SOLID_NOT;
    }
    else
    {
        this.model = this.mdl;
        this.solid = SOLID_BSP;
    }
 
    this.nextthink = time + 0.2;
}

References enemy, entity(), GetResource(), mdl, model, nextthink, solid, SOLID_BSP, SOLID_NOT, and time.

Referenced by spawnfunc().

destructible_heal()

bool destructible_heal	(	entity	targ,
		entity	inflictor,
		float	amount,
		float	limit )

Definition at line 333 of file sv_assault.qc.

{
    float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
    float hlth = GetResource(targ, RES_HEALTH);
    if (hlth <= 0 || hlth >= true_limit)
        return false;
 
    GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
    if(targ.sprite)
    {
        WaypointSprite_UpdateHealth(targ.sprite, GetResource(targ, RES_HEALTH));
    }
    func_breakable_colormod(targ);
    return true;
}

References entity(), func_breakable_colormod(), GetResource(), GiveResourceWithLimit(), RES_LIMIT_NONE, and WaypointSprite_UpdateHealth().

Referenced by spawnfunc().

havocbot_ast_reset_role()

void havocbot_ast_reset_role

(

entity

this

)

Definition at line 549 of file sv_assault.qc.

{
    if(IS_DEAD(this))
        return;
 
    if(this.team == assault_attacker_team)
        havocbot_role_ast_setrole(this, HAVOCBOT_AST_ROLE_OFFENSE);
    else
        havocbot_role_ast_setrole(this, HAVOCBOT_AST_ROLE_DEFENSE);
}

References assault_attacker_team, entity(), HAVOCBOT_AST_ROLE_DEFENSE, HAVOCBOT_AST_ROLE_OFFENSE, havocbot_role_ast_setrole(), IS_DEAD, and team.

Referenced by havocbot_role_ast_defense(), havocbot_role_ast_offense(), MUTATOR_HOOKFUNCTION(), and void().

havocbot_goalrating_ast_targets()

void havocbot_goalrating_ast_targets	(	entity	this,
		float	ratingscale )

dprint("waypoints around target were found\n");

Definition at line 398 of file sv_assault.qc.

{
    IL_EACH(g_assault_destructibles, it.bot_attack,
    {
        if (it.target == "")
            continue;
 
        bool found = false;
        entity destr = it;
        IL_EACH(g_assault_objectivedecreasers, it.targetname == destr.target,
        {
            float hlth = GetResource(it.enemy, RES_HEALTH);
            if (hlth > 0 && hlth < ASSAULT_VALUE_INACTIVE)
            {
                found = true;
                break;
            }
        });
 
        if(!found)
            continue;
 
        vector p = 0.5 * (it.absmin + it.absmax);
 
        // Find and rate waypoints around it
        found = false;
        entity best = NULL;
        float bestvalue = FLOAT_MAX;
        entity des = it;
        for (float radius = 500; radius <= 1500 && !found; radius += 500)
        {
            FOREACH_ENTITY_RADIUS(p, radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
            {
                if(checkpvs(it.origin, des))
                {
                    found = true;
                    if(it.cnt < bestvalue)
                    {
                        best = it;
                        bestvalue = it.cnt;
                    }
                }
            });
        }
 
        if(best)
        {
        //  te_lightning2(NULL, '0 0 0', best.origin);
        //  te_knightspike(best.origin);
 
            navigation_routerating(this, best, ratingscale, 4000);
            best.cnt += 1;
 
            this.havocbot_attack_time = 0;
 
            if(checkpvs(this.origin + this.view_ofs, it))
            if(checkpvs(this.origin + this.view_ofs, best))
            {
            //  dprint("increasing attack time for this target\n");
                this.havocbot_attack_time = time + 2;
            }
        }
    });
}

References best, entity(), FLOAT_MAX, FOREACH_ENTITY_RADIUS, g_assault_destructibles, IL_EACH, NULL, radius, vector, and WAYPOINTFLAG_GENERATED.

Referenced by havocbot_role_ast_defense(), and havocbot_role_ast_offense().

havocbot_role_ast_defense()

void havocbot_role_ast_defense

(

entity

this

)

Definition at line 499 of file sv_assault.qc.

{
    if(IS_DEAD(this))
    {
        this.havocbot_attack_time = 0;
        havocbot_ast_reset_role(this);
        return;
    }
 
    // Set the role timeout if necessary
    if (!this.havocbot_role_timeout)
        this.havocbot_role_timeout = time + 120;
 
    if (time > this.havocbot_role_timeout)
    {
        havocbot_ast_reset_role(this);
        return;
    }
 
    if(this.havocbot_attack_time>time)
        return;
 
    if (navigation_goalrating_timeout(this))
    {
        // role: defense
        navigation_goalrating_start(this);
        havocbot_goalrating_enemyplayers(this, 10000, this.origin, 3000);
        havocbot_goalrating_ast_targets(this, 20000);
        havocbot_goalrating_items(this, 30000, this.origin, 10000);
        navigation_goalrating_end(this);
 
        navigation_goalrating_timeout_set(this);
    }
}

References entity(), havocbot_ast_reset_role(), havocbot_attack_time, havocbot_goalrating_ast_targets(), havocbot_goalrating_enemyplayers(), havocbot_goalrating_items(), havocbot_role_timeout, IS_DEAD, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), origin, and time.

Referenced by havocbot_role_ast_setrole(), and void().

havocbot_role_ast_offense()

void havocbot_role_ast_offense

(

entity

this

)

Definition at line 464 of file sv_assault.qc.

{
    if(IS_DEAD(this))
    {
        this.havocbot_attack_time = 0;
        havocbot_ast_reset_role(this);
        return;
    }
 
    // Set the role timeout if necessary
    if (!this.havocbot_role_timeout)
        this.havocbot_role_timeout = time + 120;
 
    if (time > this.havocbot_role_timeout)
    {
        havocbot_ast_reset_role(this);
        return;
    }
 
    if(this.havocbot_attack_time>time)
        return;
 
    if (navigation_goalrating_timeout(this))
    {
        // role: offense
        navigation_goalrating_start(this);
        havocbot_goalrating_enemyplayers(this, 10000, this.origin, 650);
        havocbot_goalrating_ast_targets(this, 20000);
        havocbot_goalrating_items(this, 30000, this.origin, 10000);
        navigation_goalrating_end(this);
 
        navigation_goalrating_timeout_set(this);
    }
}

References entity(), havocbot_ast_reset_role(), havocbot_attack_time, havocbot_goalrating_ast_targets(), havocbot_goalrating_enemyplayers(), havocbot_goalrating_items(), havocbot_role_timeout, IS_DEAD, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), origin, and time.

Referenced by havocbot_role_ast_setrole(), and void().

havocbot_role_ast_setrole()

void havocbot_role_ast_setrole	(	entity	this,
		float	role )

Definition at line 534 of file sv_assault.qc.

{
    switch(role)
    {
        case HAVOCBOT_AST_ROLE_DEFENSE:
            this.havocbot_role = havocbot_role_ast_defense;
            this.havocbot_role_timeout = 0;
            break;
        case HAVOCBOT_AST_ROLE_OFFENSE:
            this.havocbot_role = havocbot_role_ast_offense;
            this.havocbot_role_timeout = 0;
            break;
    }
}

References entity(), HAVOCBOT_AST_ROLE_DEFENSE, HAVOCBOT_AST_ROLE_OFFENSE, havocbot_role_ast_defense(), havocbot_role_ast_offense(), and havocbot_role_timeout.

Referenced by havocbot_ast_reset_role().

MUTATOR_HOOKFUNCTION() [1/10]

MUTATOR_HOOKFUNCTION	(	as	,
		CheckRules_World	)

Definition at line 608 of file sv_assault.qc.

{
    M_ARGV(0, float) = WinningCondition_Assault();
    return true;
}

References CheckRules_World(), M_ARGV, and WinningCondition_Assault().

MUTATOR_HOOKFUNCTION() [2/10]

MUTATOR_HOOKFUNCTION	(	as	,
		HavocBot_ChooseRole	)

Definition at line 586 of file sv_assault.qc.

{
    entity bot = M_ARGV(0, entity);
 
    havocbot_ast_reset_role(bot);
    return true;
}

References entity(), havocbot_ast_reset_role(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [3/10]

MUTATOR_HOOKFUNCTION	(	as	,
		OnEntityPreSpawn	)

Definition at line 621 of file sv_assault.qc.

{
    entity ent = M_ARGV(0, entity);
 
    switch(ent.classname)
    {
        case "info_player_team1":
        case "info_player_team2":
        case "info_player_team3":
        case "info_player_team4":
            return true;
    }
}

References entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [4/10]

MUTATOR_HOOKFUNCTION	(	as	,
		PlayerSpawn	)

Definition at line 561 of file sv_assault.qc.

{
    entity player = M_ARGV(0, entity);
 
    if(player.team == assault_attacker_team)
        Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
    else
        Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
}

References assault_attacker_team, entity(), M_ARGV, and Send_Notification().

MUTATOR_HOOKFUNCTION() [5/10]

MUTATOR_HOOKFUNCTION	(	as	,
		PlayHitsound	)

Definition at line 594 of file sv_assault.qc.

{
    entity frag_victim = M_ARGV(0, entity);
 
    return (frag_victim.classname == "func_assault_destructible");
}

References entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [6/10]

MUTATOR_HOOKFUNCTION	(	as	,
		ReadLevelCvars	)

Definition at line 614 of file sv_assault.qc.

{
    // incompatible
    warmup_stage = 0;
    sv_ready_restart_after_countdown = 0;
}

References sv_ready_restart_after_countdown, and warmup_stage.

MUTATOR_HOOKFUNCTION() [7/10]

MUTATOR_HOOKFUNCTION	(	as	,
		ReadyRestart_Deny	)

Definition at line 635 of file sv_assault.qc.

{
    // Readyrestart is forbidden because Assault is actually played in 2 different games, called
    // rounds, where the map is completely restarted and the timelimit of the second round is set
    // to the time the previous attacker team took to destroy the main objective
    // In campaign it's allowed because Assault is played in a single game / round
    if (autocvar_g_campaign)
    {
        assault_turrets_teamswap_forbidden = true;
        return false;
    }
    return true;
}

References assault_turrets_teamswap_forbidden, and autocvar_g_campaign.

MUTATOR_HOOKFUNCTION() [8/10]

MUTATOR_HOOKFUNCTION	(	as	,
		TeamBalance_CheckAllowedTeams	)

Definition at line 601 of file sv_assault.qc.

{
    // assault always has 2 teams
    M_ARGV(0, float) = BIT(0) | BIT(1);
    return true;
}

References BIT, M_ARGV, and TeamBalance_CheckAllowedTeams().

MUTATOR_HOOKFUNCTION() [9/10]

MUTATOR_HOOKFUNCTION	(	as	,
		TurretSpawn	)

Definition at line 571 of file sv_assault.qc.

{
    entity turret = M_ARGV(0, entity);
 
    if(!turret.team || turret.team == FLOAT_MAX)
        turret.team = assault_attacker_team; // this gets reversed when match starts (assault_roundstart_use)
}

References assault_attacker_team, entity(), FLOAT_MAX, and M_ARGV.

MUTATOR_HOOKFUNCTION() [10/10]

MUTATOR_HOOKFUNCTION	(	as	,
		VehicleInit	)

Definition at line 579 of file sv_assault.qc.

{
    entity veh = M_ARGV(0, entity);
 
    veh.nextthink = time + 0.5;
}

References entity(), M_ARGV, and time.

spawnfunc() [1/8]

spawnfunc

(

func_assault_destructible

)

Definition at line 349 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    this.spawnflags = 3;
    this.event_heal = destructible_heal;
    IL_PUSH(g_assault_destructibles, this);
 
    if(assault_attacker_team == NUM_TEAM_1)
        this.team = NUM_TEAM_2;
    else
        this.team = NUM_TEAM_1;
 
    func_breakable_setup(this);
}

References assault_attacker_team, destructible_heal(), func_breakable_setup(), g_assault, g_assault_destructibles, IL_PUSH(), NUM_TEAM_1, NUM_TEAM_2, spawnflags, and team.

spawnfunc() [2/8]

spawnfunc

(

func_assault_wall

)

Definition at line 365 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    this.mdl = this.model;
    _setmodel(this, this.mdl);
    this.solid = SOLID_BSP;
    setthink(this, assault_wall_think);
    this.nextthink = time;
    InitializeEntity(this, assault_setenemytoobjective, INITPRIO_FINDTARGET);
}

References assault_setenemytoobjective(), assault_wall_think(), g_assault, InitializeEntity(), INITPRIO_FINDTARGET, mdl, model, nextthink, setthink, solid, SOLID_BSP, and time.

spawnfunc() [3/8]

spawnfunc

(

info_player_attacker

)

Definition at line 288 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    this.team = NUM_TEAM_1; // red, gets swapped every round
    spawnfunc_info_player_deathmatch(this);
}

References g_assault, NUM_TEAM_1, and team.

spawnfunc() [4/8]

spawnfunc

(

info_player_defender

)

Definition at line 296 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    this.team = NUM_TEAM_2; // blue, gets swapped every round
    spawnfunc_info_player_deathmatch(this);
}

References g_assault, NUM_TEAM_2, and team.

spawnfunc() [5/8]

spawnfunc

(

target_assault_roundend

)

Definition at line 377 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    this.winning = 0; // round not yet won by attackers
    this.use = target_assault_roundend_use;
    this.cnt = 0; // first round
    this.reset = target_assault_roundend_reset;
}

References cnt, g_assault, target_assault_roundend_reset(), target_assault_roundend_use(), use, and winning.

spawnfunc() [6/8]

spawnfunc

(

target_assault_roundstart

)

Definition at line 387 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    assault_attacker_team = NUM_TEAM_1;
    this.use = assault_roundstart_use;
    this.reset2 = assault_roundstart_use_this;
    InitializeEntity(this, assault_roundstart_use_this, INITPRIO_FINDTARGET);
}

References assault_attacker_team, assault_roundstart_use(), assault_roundstart_use_this(), g_assault, InitializeEntity(), INITPRIO_FINDTARGET, NUM_TEAM_1, and use.

spawnfunc() [7/8]

spawnfunc

(

target_objective

)

Definition at line 304 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    IL_PUSH(g_assault_objectives, this);
    this.use = assault_objective_use;
    this.reset = assault_objective_reset;
    this.reset(this);
    this.spawn_evalfunc = target_objective_spawn_evalfunc;
}

References assault_objective_reset(), assault_objective_use(), g_assault, g_assault_objectives, IL_PUSH(), spawn_evalfunc, target_objective_spawn_evalfunc(), and use.

spawnfunc() [8/8]

spawnfunc

(

target_objective_decrease

)

Definition at line 315 of file sv_assault.qc.

{
    if (!g_assault) { delete(this); return; }
 
    IL_PUSH(g_assault_objectivedecreasers, this);
 
    if(!this.dmg)
        this.dmg = 101;
 
    this.use = assault_objective_decrease_use;
    SetResourceExplicit(this, RES_HEALTH, ASSAULT_VALUE_INACTIVE);
    this.max_health = ASSAULT_VALUE_INACTIVE;
    this.enemy = NULL;
 
    InitializeEntity(this, target_objective_decrease_findtarget, INITPRIO_FINDTARGET);
}

References assault_objective_decrease_use(), ASSAULT_VALUE_INACTIVE, dmg, enemy, g_assault, g_assault_objectivedecreasers, IL_PUSH(), InitializeEntity(), INITPRIO_FINDTARGET, max_health, NULL, SetResourceExplicit(), target_objective_decrease_findtarget(), and use.

target_assault_roundend_reset()

void target_assault_roundend_reset

(

entity

this

)

Definition at line 140 of file sv_assault.qc.

{
    //print("round end reset\n");
    ++this.cnt; // up round counter
    this.winning = false; // up round
}

References cnt, entity(), and winning.

Referenced by spawnfunc().

target_assault_roundend_use()

void target_assault_roundend_use	(	entity	this,
		entity	actor,
		entity	trigger )

Definition at line 147 of file sv_assault.qc.

{
    this.winning = 1; // round has been won by attackers
}

References entity(), and winning.

Referenced by spawnfunc().

target_objective_decrease_activate()

void target_objective_decrease_activate

(

entity

this

)

Definition at line 106 of file sv_assault.qc.

{
    entity spr;
    this.owner = NULL;
    FOREACH_ENTITY_STRING(target, this.targetname,
    {
        if(it.assault_sprite != NULL)
        {
            WaypointSprite_Disown(it.assault_sprite, waypointsprite_deadlifetime);
            if(it.classname == "func_assault_destructible")
                it.sprite = NULL; // TODO: just unsetting it?!
        }
 
        spr = WaypointSprite_SpawnFixed(WP_AssaultDefend, 0.5 * (it.absmin + it.absmax), it, assault_sprite, RADARICON_OBJECTIVE);
        spr.assault_decreaser = this;
        spr.waypointsprite_visible_for_player = assault_decreaser_sprite_visible;
        WaypointSprite_UpdateRule(spr, assault_attacker_team, SPRITERULE_TEAMPLAY);
        if(it.classname == "func_assault_destructible")
        {
            WaypointSprite_UpdateSprites(spr, WP_AssaultDefend, WP_AssaultDestroy, WP_AssaultDestroy);
            WaypointSprite_UpdateMaxHealth(spr, it.max_health);
            WaypointSprite_UpdateHealth(spr, GetResource(it, RES_HEALTH));
            it.sprite = spr;
        }
        else
            WaypointSprite_UpdateSprites(spr, WP_AssaultDefend, WP_AssaultPush, WP_AssaultPush);
    });
}

References assault_attacker_team, assault_decreaser_sprite_visible(), assault_sprite, entity(), FOREACH_ENTITY_STRING, GetResource(), NULL, owner, SPRITERULE_TEAMPLAY, target, targetname, waypointsprite_deadlifetime, WaypointSprite_Disown(), WaypointSprite_SpawnFixed(), WaypointSprite_UpdateHealth(), WaypointSprite_UpdateMaxHealth(), WaypointSprite_UpdateRule(), and WaypointSprite_UpdateSprites().

target_objective_decrease_findtarget()

void target_objective_decrease_findtarget

(

entity

this

)

Definition at line 135 of file sv_assault.qc.

{
    assault_setenemytoobjective(this);
}

References assault_setenemytoobjective(), and entity().

Referenced by spawnfunc().

target_objective_spawn_evalfunc()

vector target_objective_spawn_evalfunc	(	entity	this,
		entity	player,
		entity	spot,
		vector	current )

Definition at line 28 of file sv_assault.qc.

{
    float hlth = GetResource(this, RES_HEALTH);
    if (hlth < 0 || hlth >= ASSAULT_VALUE_INACTIVE)
        return '-1 0 0';
    return current;
}

References ASSAULT_VALUE_INACTIVE, entity(), GetResource(), and vector.

Referenced by spawnfunc().

WinningCondition_Assault()

int WinningCondition_Assault

(

)

Definition at line 233 of file sv_assault.qc.

{
    if(as_round)
        return WINNING_NO;
 
    WinningConditionHelper(NULL); // set worldstatus
 
    int status = WINNING_NO;
    // as the timelimit has not yet passed just assume the defending team will win
    if(assault_attacker_team == NUM_TEAM_1)
    {
        SetWinners(team, NUM_TEAM_2);
    }
    else
    {
        SetWinners(team, NUM_TEAM_1);
    }
 
    entity ent;
    ent = find(NULL, classname, "target_assault_roundend");
    if(ent)
    {
        if(ent.winning) // round end has been triggered by attacking team
        {
            bprint(Team_ColoredFullName(assault_attacker_team), " destroyed the objective in ", process_time(2, ceil(time - game_starttime)), "\n");
            SetWinners(team, assault_attacker_team);
 
            TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
 
            // in campaign the game ends when the player destroys the objective, there's no second round
            if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round or the only round in campaign
            {
                status = WINNING_YES;
            }
            else
            {
                Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ASSAULT_OBJ_DESTROYED, ceil(time - game_starttime));
                as_round = new(as_round);
                as_round.think = as_round_think;
                as_round.ent_winning = ent;
                as_round.nextthink = time + AS_ROUND_DELAY;
                game_stopped = true;
 
                // make sure timelimit isn't hit while the game is blocked
                if(autocvar_timelimit > 0)
                if(time + AS_ROUND_DELAY >= game_starttime + autocvar_timelimit * 60)
                    cvar_set("timelimit", ftos(autocvar_timelimit + AS_ROUND_DELAY / 60));
            }
        }
    }
 
    return status;
}

References as_round, AS_ROUND_DELAY, as_round_think(), assault_attacker_team, autocvar_g_campaign, autocvar_timelimit, bprint(), ceil(), classname, cvar_set(), entity(), find(), ftos(), game_starttime, game_stopped, NULL, NUM_TEAM_1, NUM_TEAM_2, process_time(), Send_Notification(), SetWinners(), ST_ASSAULT_OBJECTIVES, team, Team_ColoredFullName, TeamScore_AddToTeam(), time, WINNING_NO, WINNING_YES, and WinningConditionHelper().

Referenced by MUTATOR_HOOKFUNCTION().

Variable Documentation

as_round

entity as_round

Definition at line 221 of file sv_assault.qc.

Referenced by as_round_think(), and WinningCondition_Assault().

assault_turrets_teamswap_forbidden

bool assault_turrets_teamswap_forbidden

Definition at line 152 of file sv_assault.qc.

Referenced by assault_roundstart_use(), and MUTATOR_HOOKFUNCTION().

ent_winning

entity ent_winning

Definition at line 222 of file sv_assault.qc.

sprite

entity sprite

Definition at line 11 of file sv_assault.qc.

Referenced by defrag_waypointsprites(), dom_controlpoint_setup(), dompoint_captured(), dompointtouch(), func_breakable_behave_restore(), func_breakable_damage(), monster_changeteam(), Monster_Damage(), Monster_Remove(), Monster_Spawn_Setup(), ons_ControlPoint_Reset(), ons_ControlPoint_Setup(), ons_GeneratorDamage(), ons_GeneratorReset(), ons_GeneratorSetup(), spawnfunc(), and SpawnGoal().