sv_domination.qc File Reference

#include "sv_domination.qh"
#include <server/client.qh>
#include <server/command/vote.qh>
#include <server/damage.qh>
#include <server/gamelog.qh>
#include <server/items/items.qh>
#include <server/teamplay.qh>
#include <server/world.qh>
#include <common/mapobjects/platforms.qh>
#include <common/mapobjects/triggers.qh>

Include dependency graph for sv_domination.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	AnimateDomPoint (entity this)
void	dom_controlpoint_setup (entity this)
void	dom_DelayedInit (entity this)
void	dom_EventLog (string mode, float team_before, entity actor)
void	dom_Initialize ()
void	dom_spawnpoint (vector org)
void	dom_spawnteam (string teamname, float teamcolor, string pointmodel, float pointskin, Sound capsound, string capnarration, string capmessage)
void	dom_spawnteams (int teams)
bool	Domination_CheckPlayers ()
bool	Domination_CheckWinner ()
void	Domination_count_controlpoints ()
void	Domination_RoundStart ()
void	dompoint_captured (entity this)
void	dompointthink (entity this)
void	dompointtouch (entity this, entity toucher)
void	havocbot_goalrating_controlpoints (entity this, float ratingscale, vector org, float sradius)
void	havocbot_role_dom (entity this)
	MUTATOR_HOOKFUNCTION (dom, ClientConnect)
	MUTATOR_HOOKFUNCTION (dom, HavocBot_ChooseRole)
	MUTATOR_HOOKFUNCTION (dom, PlayerSpawn)
	MUTATOR_HOOKFUNCTION (dom, reset_map_players)
	MUTATOR_HOOKFUNCTION (dom, TeamBalance_CheckAllowedTeams)
void	ScoreRules_dom (int teams)
void	set_dom_state (entity e)
	spawnfunc (dom_controlpoint)
	spawnfunc (dom_team)
	spawnfunc (team_dom_point)

Variables
int	autocvar_g_domination_default_teams
bool	autocvar_g_domination_disable_frags
int	autocvar_g_domination_point_amt
bool	autocvar_g_domination_point_fullbright
float	autocvar_g_domination_point_rate
float	autocvar_g_domination_round_timelimit
int	autocvar_g_domination_teams_override
float	autocvar_g_domination_warmup
bool	g_domination
int	total_control_points

Function Documentation

AnimateDomPoint()

void AnimateDomPoint

(

entity

this

)

Definition at line 140 of file sv_domination.qc.

{
    if(this.pain_finished > time)
        return;
    this.pain_finished = time + this.t_width;
    if(this.nextthink > this.pain_finished)
        this.nextthink = this.pain_finished;
 
    this.frame = this.frame + 1;
    if(this.frame > this.t_length)
        this.frame = 0;
}

References entity(), frame, nextthink, pain_finished, t_length, t_width, and time.

Referenced by dompointthink().

dom_controlpoint_setup()

void dom_controlpoint_setup

(

entity

this

)

Definition at line 253 of file sv_domination.qc.

{
    entity head;
    // find the spawnfunc_dom_team representing unclaimed points
    head = find(NULL, classname, "dom_team");
    while(head && head.netname != "")
        head = find(head, classname, "dom_team");
    if (!head)
        objerror(this, "no spawnfunc_dom_team with netname \"\" found\n");
 
    // copy important properties from spawnfunc_dom_team entity
    this.goalentity = head;
    _setmodel(this, head.mdl); // precision already set
    this.skin = head.skin;
 
    this.cnt = -1;
 
    if(this.message == "")
        this.message = " has captured a control point";
 
    if(this.frags <= 0)
        this.frags = 1;
    if(this.wait <= 0)
        this.wait = 5;
 
    float points, waittime;
    if (autocvar_g_domination_point_amt)
        points = autocvar_g_domination_point_amt;
    else
        points = this.frags;
    if (autocvar_g_domination_point_rate)
        waittime = autocvar_g_domination_point_rate;
    else
        waittime = this.wait;
 
    total_pps += points/waittime;
 
    if(!this.t_width)
        this.t_width = 0.02; // frame animation rate
    if(!this.t_length)
        this.t_length = 239; // maximum frame
 
    setthink(this, dompointthink);
    this.nextthink = time;
    settouch(this, dompointtouch);
    this.solid = SOLID_TRIGGER;
    if(!this.flags & FL_ITEM)
        IL_PUSH(g_items, this);
    this.flags = FL_ITEM;
    setsize(this, '-48 -48 -32', '48 48 32'); // 0.8.6 used '-32 -32 -32', '32 32 32' with sv_legacy_bbox_expand 1 and FL_ITEM
    setorigin(this, this.origin + '0 0 20');
    DropToFloor_QC_DelayedInit(this);
 
    waypoint_spawnforitem(this);
    WaypointSprite_SpawnFixed(WP_DomNeut, this.origin + '0 0 32', this, sprite, RADARICON_DOMPOINT);
}

References autocvar_g_domination_point_amt, autocvar_g_domination_point_rate, classname, cnt, dompointthink(), dompointtouch(), DropToFloor_QC_DelayedInit(), entity(), find(), FL_ITEM, flags, frags, g_items, goalentity, IL_PUSH(), message, nextthink, NULL, objerror, origin, setthink, settouch, skin, solid, SOLID_TRIGGER, sprite, t_length, t_width, time, total_pps, wait, waypoint_spawnforitem(), and WaypointSprite_SpawnFixed().

Referenced by spawnfunc().

dom_DelayedInit()

void dom_DelayedInit

(

entity

this

)

Definition at line 630 of file sv_domination.qc.

{
    // if no teams are found, spawn defaults
    if(find(NULL, classname, "dom_team") == NULL || autocvar_g_domination_teams_override >= 2)
    {
        LOG_TRACE("No \"dom_team\" entities found on this map, creating them anyway.");
        domination_teams = autocvar_g_domination_teams_override;
        if (domination_teams < 2)
            domination_teams = autocvar_g_domination_default_teams;
        domination_teams = BITS(bound(2, domination_teams, 4));
        dom_spawnteams(domination_teams);
    }
    else
    {
        entity balance = TeamBalance_CheckAllowedTeams(NULL);
        domination_teams = TeamBalance_GetAllowedTeams(balance);
        TeamBalance_Destroy(balance);
    }
 
    domination_roundbased = autocvar_g_domination_roundbased;
 
    ScoreRules_dom(domination_teams);
 
    if(domination_roundbased)
    {
        round_handler_Spawn(Domination_CheckPlayers, Domination_CheckWinner, Domination_RoundStart);
        round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
    }
}

References autocvar_g_domination_default_teams, autocvar_g_domination_round_timelimit, autocvar_g_domination_roundbased, autocvar_g_domination_teams_override, autocvar_g_domination_warmup, BITS, bound(), classname, dom_spawnteams(), Domination_CheckPlayers(), Domination_CheckWinner(), domination_roundbased, Domination_RoundStart(), domination_teams, entity(), find(), LOG_TRACE, NULL, round_handler_Init(), round_handler_Spawn(), ScoreRules_dom(), TeamBalance_CheckAllowedTeams(), TeamBalance_Destroy(), and TeamBalance_GetAllowedTeams().

Referenced by dom_Initialize().

dom_EventLog()

void dom_EventLog	(	string	mode,
		float	team_before,
		entity	actor )

Definition at line 24 of file sv_domination.qc.

{
    if(autocvar_sv_eventlog)
        GameLogEcho(strcat(":dom:", mode, ":", ftos(team_before), ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
}

References autocvar_sv_eventlog, entity(), ftos(), GameLogEcho(), NULL, and strcat().

Referenced by dompoint_captured().

dom_Initialize()

void dom_Initialize

(

)

Definition at line 660 of file sv_domination.qc.

{
    g_domination = true;
    g_dompoints = IL_NEW();
 
    InitializeEntity(NULL, dom_DelayedInit, INITPRIO_GAMETYPE);
}

References dom_DelayedInit(), g_domination, g_dompoints, IL_NEW, InitializeEntity(), INITPRIO_GAMETYPE, and NULL.

Referenced by REGISTER_MUTATOR().

dom_spawnpoint()

void dom_spawnpoint

(

vector

org

)

Definition at line 608 of file sv_domination.qc.

{
    entity e = spawn();
    setthink(e, spawnfunc_dom_controlpoint);
    e.nextthink = time;
    setorigin(e, org);
    spawnfunc_dom_controlpoint(e);
}

References entity(), org, setthink, spawn, time, and vector.

dom_spawnteam()

void dom_spawnteam	(	string	teamname,
		float	teamcolor,
		string	pointmodel,
		float	pointskin,
		Sound	capsound,
		string	capnarration,
		string	capmessage )

Definition at line 584 of file sv_domination.qc.

{
    TC(Sound, capsound);
    entity e = new_pure(dom_team);
    e.netname = strzone(teamname);
    e.cnt = teamcolor;
    e.model = pointmodel;
    e.skin = pointskin;
    e.noise = strzone(Sound_fixpath(capsound));
    e.noise1 = strzone(capnarration);
    e.message = strzone(capmessage);
 
    // this code is identical to spawnfunc_dom_team
    _setmodel(e, e.model); // precision not needed
    e.mdl = e.model;
    e.dmg = e.modelindex;
    e.model = "";
    e.modelindex = 0;
    // this would have to be changed if used in quakeworld
    e.team = e.cnt + 1;
 
    //eprint(e);
}

References entity(), new_pure, Sound_fixpath, strzone(), and TC.

Referenced by dom_spawnteams().

dom_spawnteams()

void dom_spawnteams

(

int

teams

)

Definition at line 618 of file sv_domination.qc.

{
    TC(int, teams);
    dom_spawnteam(Team_ColoredFullName(NUM_TEAM_1), NUM_TEAM_1-1, "models/domination/dom_red.md3", 0, SND_DOM_CLAIM, "", "Red team has captured a control point");
    dom_spawnteam(Team_ColoredFullName(NUM_TEAM_2), NUM_TEAM_2-1, "models/domination/dom_blue.md3", 0, SND_DOM_CLAIM, "", "Blue team has captured a control point");
    if(teams & BIT(2))
        dom_spawnteam(Team_ColoredFullName(NUM_TEAM_3), NUM_TEAM_3-1, "models/domination/dom_yellow.md3", 0, SND_DOM_CLAIM, "", "Yellow team has captured a control point");
    if(teams & BIT(3))
        dom_spawnteam(Team_ColoredFullName(NUM_TEAM_4), NUM_TEAM_4-1, "models/domination/dom_pink.md3", 0, SND_DOM_CLAIM, "", "Pink team has captured a control point");
    dom_spawnteam("", 0, "models/domination/dom_unclaimed.md3", 0, SND_Null, "", "");
}

References BIT, dom_spawnteam(), NUM_TEAM_1, NUM_TEAM_2, NUM_TEAM_3, NUM_TEAM_4, TC, Team_ColoredFullName, and teams.

Referenced by dom_DelayedInit().

Domination_CheckPlayers()

bool Domination_CheckPlayers

(

)

Definition at line 362 of file sv_domination.qc.

{
    return true;
}

Referenced by dom_DelayedInit().

Domination_CheckWinner()

bool Domination_CheckWinner

(

)

Definition at line 332 of file sv_domination.qc.

{
    if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 
        game_stopped = true;
        round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
        return true;
    }
 
    Domination_count_controlpoints();
    int winner_team = Team_GetWinnerTeam_WithOwnedItems(total_control_points);
    if (winner_team == -1)
        return 0;
 
    if(winner_team > 0)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
        TeamScore_AddToTeam(winner_team, ST_DOM_CAPS, +1);
    }
 
    game_stopped = true;
    round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 
    return true;
}

References APP_TEAM_NUM, autocvar_g_domination_round_timelimit, autocvar_g_domination_warmup, Domination_count_controlpoints(), game_stopped, NULL, round_handler_GetEndTime, round_handler_Init(), Send_Notification(), ST_DOM_CAPS, Team_GetWinnerTeam_WithOwnedItems(), TeamScore_AddToTeam(), time, and total_control_points.

Referenced by dom_DelayedInit().

Domination_count_controlpoints()

void Domination_count_controlpoints

(

)

Definition at line 311 of file sv_domination.qc.

{
    total_control_points = 0;
    for (int i = 1; i <= NUM_TEAMS; ++i)
    {
        Team_SetNumberOfOwnedItems(Team_GetTeamFromIndex(i), 0);
    }
    IL_EACH(g_dompoints, true,
    {
        ++total_control_points;
        if (!Entity_HasValidTeam(it.goalentity))
        {
            continue;
        }
        entity team_ = Entity_GetTeam(it.goalentity);
        int num_control_points = Team_GetNumberOfOwnedItems(team_);
        ++num_control_points;
        Team_SetNumberOfOwnedItems(team_, num_control_points);
    });
}

References entity(), Entity_GetTeam(), Entity_HasValidTeam(), g_dompoints, IL_EACH, NUM_TEAMS, Team_GetNumberOfOwnedItems(), Team_GetTeamFromIndex(), Team_SetNumberOfOwnedItems(), and total_control_points.

Referenced by Domination_CheckWinner().

Domination_RoundStart()

void Domination_RoundStart

(

)

Definition at line 367 of file sv_domination.qc.

{
    FOREACH_CLIENT(IS_PLAYER(it), { it.player_blocked = false; });
}

References FOREACH_CLIENT, and IS_PLAYER.

Referenced by dom_DelayedInit().

dompoint_captured()

void dompoint_captured

(

entity

this

)

Definition at line 41 of file sv_domination.qc.

{
    float old_delay, old_team, real_team;
 
    // now that the delay has expired, switch to the latest team to lay claim to this point
    entity head = this.owner;
 
    real_team = this.cnt;
    this.cnt = -1;
 
    dom_EventLog("taken", this.team, this.dmg_inflictor);
    this.dmg_inflictor = NULL;
 
    this.goalentity = head;
    this.model = head.mdl;
    this.modelindex = head.dmg;
    this.skin = head.skin;
 
    float points, wait_time;
    if (autocvar_g_domination_point_amt)
        points = autocvar_g_domination_point_amt;
    else
        points = this.frags;
    if (autocvar_g_domination_point_rate)
        wait_time = autocvar_g_domination_point_rate;
    else
        wait_time = this.wait;
 
    if(domination_roundbased)
        bprint(sprintf("^3%s^3%s\n", head.netname, this.message));
    else
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_DOMINATION_CAPTURE_TIME, head.netname, this.message, points, wait_time);
 
    if(this.enemy.playerid == this.enemy_playerid)
        GameRules_scoring_add(this.enemy, DOM_TAKES, 1);
    else
        this.enemy = NULL;
 
    if (head.noise != "")
    {
        if(this.enemy)
            _sound(this.enemy, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
        else
            _sound(this, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
    }
    if (head.noise1 != "")
        play2all(head.noise1);
 
    this.delay = time + wait_time;
 
    // do trigger work
    old_delay = this.delay;
    old_team = this.team;
    this.team = real_team;
    this.delay = 0;
    SUB_UseTargets (this, this, NULL);
    this.delay = old_delay;
    this.team = old_team;
 
    entity msg = WP_DomNeut;
    switch(real_team)
    {
        case NUM_TEAM_1: msg = WP_DomRed; break;
        case NUM_TEAM_2: msg = WP_DomBlue; break;
        case NUM_TEAM_3: msg = WP_DomYellow; break;
        case NUM_TEAM_4: msg = WP_DomPink; break;
    }
 
    WaypointSprite_UpdateSprites(this.sprite, msg, WP_Null, WP_Null);
 
    total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
    IL_EACH(g_dompoints, true,
    {
        if (autocvar_g_domination_point_amt)
            points = autocvar_g_domination_point_amt;
        else
            points = it.frags;
        if (autocvar_g_domination_point_rate)
            wait_time = autocvar_g_domination_point_rate;
        else
            wait_time = it.wait;
        switch(it.goalentity.team)
        {
            case NUM_TEAM_1: pps_red += points/wait_time; break;
            case NUM_TEAM_2: pps_blue += points/wait_time; break;
            case NUM_TEAM_3: pps_yellow += points/wait_time; break;
            case NUM_TEAM_4: pps_pink += points/wait_time; break;
        }
        total_pps += points/wait_time;
    });
 
    WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, colormapPaletteColor(this.goalentity.team - 1, 0));
    WaypointSprite_Ping(this.sprite);
 
    this.captime = time;
 
    FOREACH_CLIENT(IS_REAL_CLIENT(it), { set_dom_state(it); });
}

References _sound, ATTEN_NORM, autocvar_g_domination_point_amt, autocvar_g_domination_point_rate, bprint(), captime, CH_TRIGGER, cnt, colormapPaletteColor, delay, dmg_inflictor, dom_EventLog(), domination_roundbased, enemy, entity(), FOREACH_CLIENT, frags, g_dompoints, GameRules_scoring_add, goalentity, IL_EACH, IS_REAL_CLIENT, model, modelindex, NULL, NUM_TEAM_1, NUM_TEAM_2, NUM_TEAM_3, NUM_TEAM_4, owner, play2all(), pps_blue, pps_pink, pps_red, pps_yellow, Send_Notification(), set_dom_state(), skin, sprite, SUB_UseTargets(), team, time, total_pps, VOL_BASE, wait, WaypointSprite_Ping(), WaypointSprite_UpdateSprites(), and WaypointSprite_UpdateTeamRadar().

Referenced by dompointtouch().

dompointthink()

void dompointthink

(

entity

this

)

Definition at line 153 of file sv_domination.qc.

{
    float fragamt;
 
    this.nextthink = time + 0.1;
 
    //this.frame = this.frame + 1;
    //if(this.frame > 119)
    //  this.frame = 0;
    AnimateDomPoint(this);
 
    // give points
 
    if (game_stopped || this.delay > time || time < game_starttime)  // game has ended, don't keep giving points
        return;
 
    if(autocvar_g_domination_point_rate)
        this.delay = time + autocvar_g_domination_point_rate;
    else
        this.delay = time + this.wait;
 
    // give credit to the team
    // NOTE: this defaults to 0
    if (!domination_roundbased)
    if (this.goalentity.netname != "")
    {
        if(autocvar_g_domination_point_amt)
            fragamt = autocvar_g_domination_point_amt;
        else
            fragamt = this.frags;
        TeamScore_AddToTeam(this.goalentity.team, ST_SCORE, fragamt);
        TeamScore_AddToTeam(this.goalentity.team, ST_DOM_TICKS, fragamt);
 
        // give credit to the individual player, if they are still there
        if (this.enemy.playerid == this.enemy_playerid)
        {
            GameRules_scoring_add(this.enemy, SCORE, fragamt);
            GameRules_scoring_add(this.enemy, DOM_TICKS, fragamt);
        }
        else
            this.enemy = NULL;
    }
}

References AnimateDomPoint(), autocvar_g_domination_point_amt, autocvar_g_domination_point_rate, delay, domination_roundbased, enemy, entity(), frags, game_starttime, game_stopped, GameRules_scoring_add, goalentity, nextthink, NULL, ST_DOM_TICKS, ST_SCORE, TeamScore_AddToTeam(), time, and wait.

Referenced by dom_controlpoint_setup().

dompointtouch()

void dompointtouch	(	entity	this,
		entity	toucher )

Definition at line 197 of file sv_domination.qc.

{
    if(!IS_PLAYER(toucher))
        return;
    if(IS_DEAD(toucher))
        return;
    if(IS_INDEPENDENT_PLAYER(toucher))
        return;
 
    if(round_handler_IsActive() && !round_handler_IsRoundStarted())
        return;
 
    if(time < this.captime + 0.3)
        return;
 
    // only valid teams can claim it
    entity head = find(NULL, classname, "dom_team");
    while (head && head.team != toucher.team)
        head = find(head, classname, "dom_team");
    if (!head || head.netname == "" || head == this.goalentity)
        return;
 
    // delay capture
 
    this.team = this.goalentity.team; // this stores the PREVIOUS team!
 
    this.cnt = toucher.team;
    this.owner = head; // team to switch to after the delay
    this.dmg_inflictor = toucher;
 
    // this.state = 1;
    // this.delay = time + cvar("g_domination_point_capturetime");
    //this.nextthink = time + cvar("g_domination_point_capturetime");
    //this.think = dompoint_captured;
 
    // go to neutral team in the mean time
    head = find(NULL, classname, "dom_team");
    while (head && head.netname != "")
        head = find(head, classname, "dom_team");
    if(head == NULL)
        return;
 
    WaypointSprite_UpdateSprites(this.sprite, WP_DomNeut, WP_Null, WP_Null);
    WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, '0 1 1');
    WaypointSprite_Ping(this.sprite);
 
    this.goalentity = head;
    this.model = head.mdl;
    this.modelindex = head.dmg;
    this.skin = head.skin;
 
    this.enemy = toucher; // individual player scoring
    this.enemy_playerid = toucher.playerid;
    dompoint_captured(this);
}

References captime, classname, cnt, dmg_inflictor, dompoint_captured(), enemy, enemy_playerid, entity(), find(), goalentity, IS_DEAD, IS_INDEPENDENT_PLAYER, IS_PLAYER, model, modelindex, NULL, owner, round_handler_IsActive, round_handler_IsRoundStarted, skin, sprite, team, time, toucher, WaypointSprite_Ping(), WaypointSprite_UpdateSprites(), and WaypointSprite_UpdateTeamRadar().

Referenced by dom_controlpoint_setup().

havocbot_goalrating_controlpoints()

void havocbot_goalrating_controlpoints	(	entity	this,
		float	ratingscale,
		vector	org,
		float	sradius )

Definition at line 373 of file sv_domination.qc.

{
    IL_EACH(g_dompoints, vdist((((it.absmin + it.absmax) * 0.5) - org), <, sradius),
    {
        if(it.cnt > -1) // this is just being fought
            navigation_routerating(this, it, ratingscale, 5000);
        else if(it.goalentity.cnt == 0) // unclaimed
            navigation_routerating(this, it, ratingscale, 5000);
        else if(it.goalentity.team != this.team) // other team's point
            navigation_routerating(this, it, ratingscale, 5000);
    });
}

References entity(), g_dompoints, IL_EACH, org, vdist, and vector.

Referenced by havocbot_role_dom().

havocbot_role_dom()

void havocbot_role_dom

(

entity

this

)

Definition at line 386 of file sv_domination.qc.

{
    if(IS_DEAD(this))
        return;
 
    if (navigation_goalrating_timeout(this))
    {
        navigation_goalrating_start(this);
        havocbot_goalrating_controlpoints(this, 10000, this.origin, 15000);
        havocbot_goalrating_items(this, 20000, this.origin, 8000);
        //havocbot_goalrating_enemyplayers(this, 1500, this.origin, 2000);
        havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
        navigation_goalrating_end(this);
 
        navigation_goalrating_timeout_set(this);
    }
}

References entity(), havocbot_goalrating_controlpoints(), havocbot_goalrating_items(), havocbot_goalrating_waypoints(), IS_DEAD, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), and origin.

Referenced by MUTATOR_HOOKFUNCTION().

MUTATOR_HOOKFUNCTION() [1/5]

MUTATOR_HOOKFUNCTION	(	dom	,
		ClientConnect	)

Definition at line 453 of file sv_domination.qc.

{
    entity player = M_ARGV(0, entity);
 
    set_dom_state(player);
}

References ClientConnect, entity(), M_ARGV, and set_dom_state().

MUTATOR_HOOKFUNCTION() [2/5]

MUTATOR_HOOKFUNCTION	(	dom	,
		HavocBot_ChooseRole	)

Definition at line 460 of file sv_domination.qc.

{
    entity bot = M_ARGV(0, entity);
 
    bot.havocbot_role = havocbot_role_dom;
    return true;
}

References entity(), havocbot_role_dom(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [3/5]

MUTATOR_HOOKFUNCTION	(	dom	,
		PlayerSpawn	)

Definition at line 445 of file sv_domination.qc.

{
    entity player = M_ARGV(0, entity);
 
    if(domination_roundbased)
        player.player_blocked = !round_handler_IsRoundStarted();
}

References domination_roundbased, entity(), M_ARGV, and round_handler_IsRoundStarted.

MUTATOR_HOOKFUNCTION() [4/5]

MUTATOR_HOOKFUNCTION	(	dom	,
		reset_map_players	)

Definition at line 429 of file sv_domination.qc.

{
    total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
    FOREACH_CLIENT(true, {
        if (IS_PLAYER(it))
        {
            PutClientInServer(it);
            if(domination_roundbased)
                it.player_blocked = 1;
        }
        if(IS_REAL_CLIENT(it))
            set_dom_state(it);
    });
    return true;
}

References domination_roundbased, FOREACH_CLIENT, IS_PLAYER, IS_REAL_CLIENT, pps_blue, pps_pink, pps_red, pps_yellow, PutClientInServer, set_dom_state(), and total_pps.

MUTATOR_HOOKFUNCTION() [5/5]

MUTATOR_HOOKFUNCTION	(	dom	,
		TeamBalance_CheckAllowedTeams	)

Definition at line 404 of file sv_domination.qc.

{
    // fallback?
    M_ARGV(0, float) = domination_teams;
    string ret_string = "dom_team";
 
    entity head = find(NULL, classname, ret_string);
    while(head)
    {
        if(head.netname != "")
        {
            if (Team_IsValidTeam(head.team))
            {
                M_ARGV(0, float) |= Team_TeamToBit(head.team);
            }
        }
 
        head = find(head, classname, ret_string);
    }
 
    M_ARGV(1, string) = string_null;
 
    return true;
}

References classname, domination_teams, entity(), find(), M_ARGV, NULL, string_null, Team_IsValidTeam(), Team_TeamToBit(), and TeamBalance_CheckAllowedTeams().

ScoreRules_dom()

void ScoreRules_dom

(

int

teams

)

Definition at line 558 of file sv_domination.qc.

{
    if(domination_roundbased)
    {
        GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
            field_team(ST_DOM_CAPS, "caps", SFL_SORT_PRIO_PRIMARY);
            field(SP_DOM_TAKES, "takes", 0);
        });
    }
    else
    {
        float sp_domticks, sp_score;
        sp_score = sp_domticks = 0;
        if(autocvar_g_domination_disable_frags)
            sp_domticks = SFL_SORT_PRIO_PRIMARY;
        else
            sp_score = SFL_SORT_PRIO_PRIMARY;
        GameRules_scoring(teams, sp_score, sp_score, {
            field_team(ST_DOM_TICKS, "ticks", sp_domticks);
            field(SP_DOM_TICKS, "ticks", sp_domticks);
            field(SP_DOM_TAKES, "takes", 0);
        });
    }
}

References autocvar_g_domination_disable_frags, domination_roundbased, GameRules_scoring, SFL_SORT_PRIO_PRIMARY, ST_DOM_CAPS, ST_DOM_TICKS, and teams.

Referenced by dom_DelayedInit().

set_dom_state()

void set_dom_state

(

entity

e

)

Definition at line 30 of file sv_domination.qc.

{
    STAT(DOM_TOTAL_PPS, e) = total_pps;
    STAT(DOM_PPS_RED, e) = pps_red;
    STAT(DOM_PPS_BLUE, e) = pps_blue;
    if(domination_teams & BIT(2))
        STAT(DOM_PPS_YELLOW, e) = pps_yellow;
    if(domination_teams & BIT(3))
        STAT(DOM_PPS_PINK, e) = pps_pink;
}

References BIT, domination_teams, entity(), pps_blue, pps_pink, pps_red, pps_yellow, STAT, and total_pps.

Referenced by dompoint_captured(), MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

spawnfunc() [1/3]

spawnfunc

(

dom_controlpoint

)

Definition at line 471 of file sv_domination.qc.

{
    if(!g_domination)
    {
        delete(this);
        return;
    }
    setthink(this, dom_controlpoint_setup);
    this.nextthink = time + 0.1;
    this.reset = dom_controlpoint_setup;
 
    if(!this.scale)
        this.scale = 0.6;
 
    this.effects = this.effects | EF_LOWPRECISION;
    if (autocvar_g_domination_point_fullbright)
        this.effects |= EF_FULLBRIGHT;
 
    IL_PUSH(g_dompoints, this);
}

References autocvar_g_domination_point_fullbright, dom_controlpoint_setup(), EF_FULLBRIGHT, EF_LOWPRECISION, effects, g_domination, g_dompoints, IL_PUSH(), nextthink, scale, setthink, and time.

spawnfunc() [2/3]

spawnfunc

(

dom_team

)

Definition at line 535 of file sv_domination.qc.

{
    if(!g_domination || autocvar_g_domination_teams_override >= 2)
    {
        delete(this);
        return;
    }
    precache_model(this.model);
    if (this.noise != "")
        precache_sound(this.noise);
    if (this.noise1 != "")
        precache_sound(this.noise1);
    _setmodel(this, this.model); // precision not needed
    this.mdl = this.model;
    this.dmg = this.modelindex;
    this.model = "";
    this.modelindex = 0;
    // this would have to be changed if used in quakeworld
    if(this.cnt)
        this.team = this.cnt + 1; // WHY are these different anyway?
}

References autocvar_g_domination_teams_override, cnt, dmg, g_domination, mdl, model, modelindex, noise, noise1, precache_sound(), and team.

spawnfunc() [3/3]

spawnfunc

(

team_dom_point

)

Definition at line 504 of file sv_domination.qc.

{
    spawnfunc_dom_controlpoint(this);
}

Variable Documentation

autocvar_g_domination_default_teams

int autocvar_g_domination_default_teams

Definition at line 15 of file sv_domination.qc.

Referenced by dom_DelayedInit().

autocvar_g_domination_disable_frags

bool autocvar_g_domination_disable_frags

Definition at line 16 of file sv_domination.qc.

Referenced by ScoreRules_dom().

autocvar_g_domination_point_amt

int autocvar_g_domination_point_amt

Definition at line 17 of file sv_domination.qc.

Referenced by dom_controlpoint_setup(), dompoint_captured(), and dompointthink().

autocvar_g_domination_point_fullbright

bool autocvar_g_domination_point_fullbright

Definition at line 18 of file sv_domination.qc.

Referenced by spawnfunc().

autocvar_g_domination_point_rate

float autocvar_g_domination_point_rate

Definition at line 21 of file sv_domination.qc.

Referenced by dom_controlpoint_setup(), dompoint_captured(), and dompointthink().

autocvar_g_domination_round_timelimit

float autocvar_g_domination_round_timelimit

Definition at line 19 of file sv_domination.qc.

Referenced by dom_DelayedInit(), and Domination_CheckWinner().

autocvar_g_domination_teams_override

int autocvar_g_domination_teams_override

Definition at line 22 of file sv_domination.qc.

Referenced by dom_DelayedInit(), and spawnfunc().

autocvar_g_domination_warmup

float autocvar_g_domination_warmup

Definition at line 20 of file sv_domination.qc.

Referenced by dom_DelayedInit(), and Domination_CheckWinner().

g_domination

bool g_domination

Definition at line 13 of file sv_domination.qc.

Referenced by dom_Initialize(), spawnfunc(), and spawnfunc().

total_control_points

int total_control_points

Definition at line 310 of file sv_domination.qc.

Referenced by Domination_CheckWinner(), and Domination_count_controlpoints().