sv_buffs.qc File Reference

#include "sv_buffs.qh"
#include <common/mapobjects/target/music.qh>
#include <common/mutators/mutator/status_effects/_mod.qh>
#include <common/gametypes/_mod.qh>
#include <server/items/items.qh>
#include "buff/_mod.qh"

Include dependency graph for sv_buffs.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
float	buff_Available (entity buff)
bool	buff_Customize (entity this, entity client)
void	buff_Delete (entity this)
void	buff_Effect (entity player, string eff)
entity	buff_FirstFromFlags (entity actor)
void	buff_Init (entity this)
void	buff_Init_Compat (entity ent, entity replacement)
void	buff_NewType (entity ent)
void	buff_RemoveAll (entity actor, int removal_type)
void	buff_Reset (entity this)
void	buff_Respawn (entity this)
void	buff_SetCooldown (entity this, float cd)
void	buff_SpawnReplacement (entity ent, entity old)
void	buff_Think (entity this)
void	buff_Touch (entity this, entity toucher)
void	buff_Waypoint_Reset (entity this)
void	buff_Waypoint_Spawn (entity e)
bool	buff_Waypoint_visible_for_player (entity this, entity player, entity view)
bool	buffs_BuffModel_Customize (entity this, entity client)
void	buffs_BuffModel_Remove (entity player)
void	buffs_BuffModel_Spawn (entity player)
void	buffs_BuffModel_Think (entity this)
void	buffs_BuffModel_Update (entity this)
void	buffs_DelayedInit (entity this)
void	buffs_Initialize ()
bool	buffs_RemovePlayer (entity player)
	MUTATOR_HOOKFUNCTION (buffs, BuildMutatorsPrettyString)
	MUTATOR_HOOKFUNCTION (buffs, BuildMutatorsString)
	MUTATOR_HOOKFUNCTION (buffs, ClientDisconnect)
	MUTATOR_HOOKFUNCTION (buffs, Damage_Calculate)
	MUTATOR_HOOKFUNCTION (buffs, FilterItem)
	MUTATOR_HOOKFUNCTION (buffs, MakePlayerObserver)
	MUTATOR_HOOKFUNCTION (buffs, PlayerPreThink)
	MUTATOR_HOOKFUNCTION (buffs, PlayerUseKey, CBC_ORDER_FIRST)

Variables
int	buff_seencount

Function Documentation

buff_Available()

float buff_Available

(

entity

buff

)

Definition at line 256 of file sv_buffs.qc.

{
    if (!buff)
        return false;
    if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_AMMO) || cvar("g_melee_only")))
        return false;
    if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
        return false;
    return cvar(strcat("g_buffs_", buff.netname));
}

References cvar(), entity(), IT_UNLIMITED_AMMO, start_items, and strcat().

Referenced by buff_Init(), buff_NewType(), and GiveItems().

buff_Customize()

bool buff_Customize	(	entity	this,
		entity	client )

Definition at line 400 of file sv_buffs.qc.

{
    entity player = WaypointSprite_getviewentity(client);
    if ((!this.buff_active || !this.buffdef) || (this.team_forced && player.team != this.team_forced))
    {
        this.alpha = 0.3;
        if (this.effects & EF_FULLBRIGHT)
            this.effects &= ~EF_FULLBRIGHT;
        this.pflags = 0;
    }
    else
    {
        this.alpha = 1;
        if (!(this.effects & EF_FULLBRIGHT))
            this.effects |= EF_FULLBRIGHT;
        this.light_lev = 220 + 36 * sin(time);
        this.pflags = PFLAGS_FULLDYNAMIC;
    }
    return true;
}

References alpha, buff_active, buffdef, EF_FULLBRIGHT, effects, entity(), light_lev, pflags, PFLAGS_FULLDYNAMIC, sin(), team_forced, time, and WaypointSprite_getviewentity().

Referenced by buff_Init().

buff_Delete()

void buff_Delete

(

entity

this

)

Definition at line 421 of file sv_buffs.qc.

{
    WaypointSprite_Kill(this.buff_waypoint);
    delete_fn(this);
}

References buff_waypoint, delete_fn(), entity(), and WaypointSprite_Kill().

Referenced by buff_Init().

buff_Effect()

void buff_Effect	(	entity	player,
		string	eff )

Definition at line 103 of file sv_buffs.qc.

{
    if (!autocvar_g_buffs_effects)
        return;
 
    if (time >= player.buff_effect_delay)
    {
        Send_Effect_(eff, player.origin + (player.mins + player.maxs) * 0.5, '0 0 0', 1);
        player.buff_effect_delay = time + 0.05; // prevent spam
    }
}

References autocvar_g_buffs_effects, entity(), Send_Effect_(), and time.

buff_FirstFromFlags()

entity buff_FirstFromFlags

(

entity

actor

)

Definition at line 293 of file sv_buffs.qc.

{
    if (!actor.statuseffects)
        return NULL;
    FOREACH(StatusEffects, it.instanceOfBuff && it.m_active(it, actor), {
        return it;
    });
    return NULL;
}

References entity(), FOREACH, and NULL.

Referenced by buff_Think(), buff_Touch(), buff_Waypoint_visible_for_player(), buffs_BuffModel_Customize(), buffs_BuffModel_Think(), MUTATOR_HOOKFUNCTION(), Obituary(), and target_init_use().

buff_Init()

void buff_Init

(

entity

this

)

Definition at line 427 of file sv_buffs.qc.

{
    if (!autocvar_g_buffs)
    {
        delete(this);
        return;
    }
 
    entity buff = this.buffdef;
 
    // item_buff_random provides a null type so force randomization in that case
    // otherwise replace the buff type if it's unavailable and the option is enabled
    if (!buff || (autocvar_g_buffs_replace_available && !buff_Available(buff)))
    {
        buff_NewType(this);
        buff = this.buffdef;
    }
 
    // the buff type is still invalid or unavailable, simply delete the item
    if (!buff || !buff_Available(buff))
    {
        delete(this);
        return;
    }
 
    this.classname = "item_buff";
    this.solid = SOLID_TRIGGER;
    this.flags = FL_ITEM;
    this.bot_pickup = true;
    this.bot_pickupevalfunc = generic_pickupevalfunc;
    this.bot_pickupbasevalue = 1000;
    IL_PUSH(g_items, this);
    setthink(this, buff_Think);
    settouch(this, buff_Touch);
    setmodel(this, MDL_BUFF);
    setsize(this, ITEM_D_MINS, ITEM_L_MAXS);
    this.reset = buff_Reset;
    this.nextthink = time + 0.1;
    this.gravity = 1;
    set_movetype(this, MOVETYPE_TOSS);
    this.scale = 1;
    this.skin = buff.m_skin;
    this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
    this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
    setcefc(this, buff_Customize);
    //this.gravity = 100;
    this.color = buff.m_color;
    this.glowmod = buff.m_color;
    buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + max(0, game_starttime - time));
    this.buff_active = !this.buff_activetime;
    this.pflags = PFLAGS_FULLDYNAMIC;
    this.dtor = buff_Delete;
 
    if (!this.buffs_finished)
        this.buffs_finished = this.count; // legacy support
 
    if (this.spawnflags & 1)
        this.noalign = true;
    if (this.noalign)
        set_movetype(this, MOVETYPE_NONE); // reset by random location
 
    if (autocvar_g_buffs_random_location || (this.spawnflags & 64))
        buff_Respawn(this);
}

References autocvar_g_buffs_cooldown_activate, autocvar_g_buffs_random_location, autocvar_g_buffs_replace_available, bot_pickup, bot_pickupbasevalue, buff_active, buff_activetime, buff_Available(), buff_Customize(), buff_Delete(), buff_NewType(), buff_Reset(), buff_Respawn(), buff_SetCooldown(), buff_Think(), buff_Touch(), buffdef, buffs_finished, classname, color, count, DPCONTENTS_BODY, DPCONTENTS_SOLID, dphitcontentsmask, EF_FULLBRIGHT, EF_NOSHADOW, EF_STARDUST, effects, entity(), FL_ITEM, flags, g_items, game_starttime, generic_pickupevalfunc(), glowmod, gravity, IL_PUSH(), ITEM_D_MINS, ITEM_L_MAXS, max(), MOVETYPE_NONE, MOVETYPE_TOSS, nextthink, noalign, pflags, PFLAGS_FULLDYNAMIC, scale, set_movetype(), setcefc, setmodel, setthink, settouch, skin, solid, SOLID_TRIGGER, spawnflags, and time.

Referenced by buff_Init_Compat(), buff_SpawnReplacement(), and buffs_DelayedInit().

buff_Init_Compat()

void buff_Init_Compat	(	entity	ent,
		entity	replacement )

Definition at line 492 of file sv_buffs.qc.

{
    if (teamplay)
    {
        if (ent.spawnflags & 2)
            ent.team_forced = NUM_TEAM_1;
        else if (ent.spawnflags & 4)
            ent.team_forced = NUM_TEAM_2;
    }
 
    ent.buffdef = replacement;
 
    buff_Init(ent);
}

References buff_Init(), entity(), NUM_TEAM_1, NUM_TEAM_2, and teamplay.

buff_NewType()

void buff_NewType

(

entity

ent

)

Definition at line 269 of file sv_buffs.qc.

{
    RandomSelection_Init();
    FOREACH(StatusEffects, it.instanceOfBuff && buff_Available(it), {
        // if it's already been chosen, give it a lower priority
        float myseencount = (it.buff_seencount > 0) ? it.buff_seencount : 1; // no division by zero please!
        RandomSelection_AddEnt(it, max(0.2, 1 / myseencount), 1);
    });
    entity newbuff = RandomSelection_chosen_ent;
    if (!newbuff)
        return;
    ++newbuff.buff_seencount; // lower chances of seeing this buff again soon
    ent.buffdef = newbuff;
}

References buff_Available(), entity(), FOREACH, max(), RandomSelection_AddEnt, RandomSelection_chosen_ent, and RandomSelection_Init().

Referenced by buff_Init(), buff_Reset(), and buff_Think().

buff_RemoveAll()

void buff_RemoveAll	(	entity	actor,
		int	removal_type )

Definition at line 284 of file sv_buffs.qc.

{
    if (!actor.statuseffects)
        return;
    FOREACH(StatusEffects, it.instanceOfBuff, {
        it.m_remove(it, actor, removal_type);
    });
}

References entity(), and FOREACH.

Referenced by buff_Touch(), GiveBuff(), MUTATOR_HOOKFUNCTION(), MUTATOR_HOOKFUNCTION(), and target_init_use().

buff_Reset()

void buff_Reset

(

entity

this

)

Definition at line 387 of file sv_buffs.qc.

{
    if (autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
        buff_NewType(this);
    this.owner = NULL;
    buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
    buff_Waypoint_Reset(this);
    this.buff_activetime_updated = false;
 
    if (autocvar_g_buffs_random_location || (this.spawnflags & 64))
        buff_Respawn(this);
}

References autocvar_g_buffs_cooldown_activate, autocvar_g_buffs_random_location, autocvar_g_buffs_randomize, autocvar_g_buffs_randomize_teamplay, buff_activetime_updated, buff_NewType(), buff_Respawn(), buff_SetCooldown(), buff_Waypoint_Reset(), entity(), NULL, owner, spawnflags, and teamplay.

Referenced by buff_Init().

buff_Respawn()

void buff_Respawn

(

entity

this

)

Definition at line 153 of file sv_buffs.qc.

{
    if (game_stopped)
        return;
 
    vector oldbufforigin = this.origin;
    this.velocity = '0 0 200';
 
    if (!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
        ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
    {
        entity spot = SelectSpawnPoint(this, true);
        setorigin(this, spot.origin);
        this.velocity = (randomvec() * 100) + '0 0 200';
        this.angles = spot.angles;
    }
 
    tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 
    setorigin(this, trace_endpos); // attempt to unstick
 
    set_movetype(this, MOVETYPE_TOSS);
 
    makevectors(this.angles);
    this.angles = '0 0 0';
    if (autocvar_g_buffs_random_lifetime > 0)
        this.lifetime = time + autocvar_g_buffs_random_lifetime;
 
    Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
    Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 
    WaypointSprite_Ping(this.buff_waypoint);
 
    sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
}

References angles, ATTEN_NONE, autocvar_g_buffs_random_lifetime, autocvar_g_buffs_random_location_attempts, buff_waypoint, CENTER_OR_VIEWOFS, CH_TRIGGER, DPCONTENTS_BODY, DPCONTENTS_CORPSE, DPCONTENTS_DONOTENTER, DPCONTENTS_LAVA, DPCONTENTS_PLAYERCLIP, DPCONTENTS_SKY, DPCONTENTS_SLIME, DPCONTENTS_SOLID, entity(), game_stopped, lifetime, makevectors, maxs, mins, MOVE_NOMONSTERS, MoveToRandomMapLocation(), MOVETYPE_TOSS, origin, Q3SURFACEFLAG_SKY, randomvec(), SelectSpawnPoint(), Send_Effect(), set_movetype(), sound, time, trace_endpos, vector, velocity, VOL_BASE, and WaypointSprite_Ping().

Referenced by buff_Init(), buff_Reset(), buff_Think(), and buff_Touch().

buff_SetCooldown()

void buff_SetCooldown	(	entity	this,
		float	cd )

Definition at line 140 of file sv_buffs.qc.

{
    cd = max(0, cd);
 
    if (!this.buff_waypoint)
        buff_Waypoint_Spawn(this);
    if (this.buff_waypoint)
        WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 
    this.buff_activetime = cd;
    this.buff_active = !cd;
}

References buff_active, buff_activetime, buff_waypoint, buff_Waypoint_Spawn(), entity(), max(), time, and WaypointSprite_UpdateBuildFinished().

Referenced by buff_Init(), buff_Reset(), and buff_Think().

buff_SpawnReplacement()

void buff_SpawnReplacement	(	entity	ent,
		entity	old )

Definition at line 507 of file sv_buffs.qc.

{
    setorigin(ent, old.origin);
    ent.angles = old.angles;
    ent.noalign = ITEM_SHOULD_KEEP_POSITION(old);
 
    buff_Init(ent);
}

References buff_Init(), entity(), and ITEM_SHOULD_KEEP_POSITION.

Referenced by MUTATOR_HOOKFUNCTION().

buff_Think()

void buff_Think

(

entity

this

)

Definition at line 303 of file sv_buffs.qc.

{
    if (this.buff_waypoint && autocvar_g_buffs_waypoint_distance <= 0)
        WaypointSprite_Kill(this.buff_waypoint);
 
    if (this.buffdef != this.oldbuffs)
    {
        entity buff = this.buffdef;
        this.color = buff.m_color;
        this.glowmod = buff.m_color;
        this.skin = buff.m_skin;
 
        setmodel(this, MDL_BUFF);
        setsize(this, ITEM_D_MINS, ITEM_L_MAXS);
 
        if (this.buff_waypoint)
        {
            //WaypointSprite_Disown(this.buff_waypoint, 1);
            WaypointSprite_Kill(this.buff_waypoint);
            buff_Waypoint_Spawn(this);
            if (this.buff_activetime)
                WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
        }
 
        this.oldbuffs = this.buffdef;
    }
 
    if (!game_stopped)
    if ((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
    if (!this.buff_activetime_updated)
    {
        buff_SetCooldown(this, this.buff_activetime);
        this.buff_activetime_updated = true;
    }
 
    if (!this.buff_active && !this.buff_activetime)
    if (!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || this.owner.vehicle
        || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway)
        || this.buffdef != buff_FirstFromFlags(this.owner))
    {
        buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
        this.owner = NULL;
        if (autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
            buff_NewType(this);
 
        if (autocvar_g_buffs_random_location || (this.spawnflags & 64))
            buff_Respawn(this);
    }
 
    if (this.buff_activetime)
    if (!game_stopped)
    if ((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
    {
        this.buff_activetime = max(0, this.buff_activetime - frametime);
 
        if (!this.buff_activetime)
        {
            this.buff_active = true;
            sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
            Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
        }
    }
 
    if (this.buff_active)
    {
        if (this.team_forced && !this.buff_waypoint)
            buff_Waypoint_Spawn(this);
 
        if (this.lifetime && time >= this.lifetime)
            buff_Respawn(this);
    }
 
    this.nextthink = time;
    //this.angles_y = time * 110.1;
}

References ATTN_NORM, autocvar_g_buffs_cooldown_respawn, autocvar_g_buffs_pickup_anyway, autocvar_g_buffs_random_location, autocvar_g_buffs_randomize, autocvar_g_buffs_randomize_teamplay, autocvar_g_buffs_waypoint_distance, buff_active, buff_activetime, buff_activetime_updated, buff_FirstFromFlags(), buff_NewType(), buff_Respawn(), buff_SetCooldown(), buff_waypoint, buff_Waypoint_Spawn(), buffdef, CENTER_OR_VIEWOFS, CH_TRIGGER, color, entity(), frametime, game_starttime, game_stopped, glowmod, IS_DEAD, ITEM_D_MINS, ITEM_L_MAXS, lifetime, max(), nextthink, NULL, oldbuffs, owner, round_handler_IsActive, round_handler_IsRoundStarted, Send_Effect(), setmodel, skin, sound, spawnflags, STAT, team_forced, teamplay, time, VOL_BASE, WaypointSprite_Kill(), and WaypointSprite_UpdateBuildFinished().

Referenced by buff_Init().

buff_Touch()

void buff_Touch	(	entity	this,
		entity	toucher )

Definition at line 189 of file sv_buffs.qc.

{
    if (game_stopped)
        return;
 
    if (ITEM_TOUCH_NEEDKILL())
    {
        buff_Respawn(this);
        return;
    }
 
    if (!this.buff_active)
        return;
 
    if (MUTATOR_CALLHOOK(BuffTouch, this, toucher))
        return;
    toucher = M_ARGV(1, entity);
 
    if (!IS_PLAYER(toucher))
        return; // incase mutator changed toucher
 
    if ((this.team_forced && toucher.team != this.team_forced)
        || toucher.vehicle
        || !this.buffdef // TODO: error out or maybe reset type if this occurs?
        || time < toucher.buff_shield)
    {
        // can't touch this
        return;
    }
 
    entity heldbuff = buff_FirstFromFlags(toucher);
    entity thebuff = this.buffdef;
 
    if (heldbuff)
    {
        if (CS_CVAR(toucher).cvar_cl_buffs_autoreplace && heldbuff != thebuff)
        {
            // TODO: lost-gained notification for this case
            int buffid = heldbuff.m_id;
            Send_Notification(NOTIF_ONE, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
            if (!IS_INDEPENDENT_PLAYER(toucher))
                Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
            //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
        }
        else
            return; // do nothing
    }
 
    this.owner = toucher;
    this.buff_active = false;
    this.lifetime = 0;
    Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, thebuff.m_id);
    if (!IS_INDEPENDENT_PLAYER(toucher))
        Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, thebuff.m_id);
 
    Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
    sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
    float bufftime = (this.buffs_finished) ? this.buffs_finished : thebuff.m_time(thebuff);
 
    buff_RemoveAll(toucher, STATUSEFFECT_REMOVE_NORMAL); // remove previous buffs so that a new one may be added
    if (!bufftime)
        bufftime = 999;
    StatusEffects_apply(thebuff, toucher, time + bufftime, 0);
 
    STAT(LAST_PICKUP, toucher) = time;
}

References ATTN_NORM, buff_active, buff_FirstFromFlags(), buff_RemoveAll(), buff_Respawn(), buffdef, buffs_finished, CENTER_OR_VIEWOFS, CH_TRIGGER, CS_CVAR, entity(), game_stopped, IS_INDEPENDENT_PLAYER, IS_PLAYER, ITEM_TOUCH_NEEDKILL, lifetime, M_ARGV, MUTATOR_CALLHOOK, owner, Send_Effect(), Send_Notification(), sound, STAT, STATUSEFFECT_REMOVE_NORMAL, StatusEffects_apply(), team_forced, time, toucher, and VOL_BASE.

Referenced by buff_Init().

buff_Waypoint_Reset()

void buff_Waypoint_Reset

(

entity

this

)

Definition at line 379 of file sv_buffs.qc.

{
    WaypointSprite_Kill(this.buff_waypoint);
 
    if (this.buff_activetime)
        buff_Waypoint_Spawn(this);
}

References buff_activetime, buff_waypoint, buff_Waypoint_Spawn(), entity(), and WaypointSprite_Kill().

Referenced by buff_Reset().

buff_Waypoint_Spawn()

void buff_Waypoint_Spawn

(

entity

e

)

Definition at line 128 of file sv_buffs.qc.

{
    if (autocvar_g_buffs_waypoint_distance <= 0)
        return;
 
    entity buff = e.buffdef;
    entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team_forced, e, buff_waypoint, true, RADARICON_Buff);
    wp.wp_extra = buff.m_id;
    WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
    e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
}

References autocvar_g_buffs_waypoint_distance, buff_waypoint, buff_Waypoint_visible_for_player(), entity(), NULL, WaypointSprite_Spawn(), and WaypointSprite_UpdateTeamRadar().

Referenced by buff_SetCooldown(), buff_Think(), and buff_Waypoint_Reset().

buff_Waypoint_visible_for_player()

bool buff_Waypoint_visible_for_player	(	entity	this,
		entity	player,
		entity	view )

Definition at line 116 of file sv_buffs.qc.

{
    if (!this.owner.buff_active && !this.owner.buff_activetime || !this.owner.buffdef)
        return false;
 
    entity heldbuff = buff_FirstFromFlags(view); // TODO: cache this information so it isn't performing a loop every frame
    if (heldbuff) 
        return CS_CVAR(view).cvar_cl_buffs_autoreplace == false || heldbuff != this.owner.buffdef;
 
    return WaypointSprite_visible_for_player(this, player, view);
}

References buff_FirstFromFlags(), CS_CVAR, entity(), owner, and WaypointSprite_visible_for_player().

Referenced by buff_Waypoint_Spawn().

buffs_BuffModel_Customize()

bool buffs_BuffModel_Customize	(	entity	this,
		entity	client )

Definition at line 10 of file sv_buffs.qc.

{
    entity player = WaypointSprite_getviewentity(client);
    entity myowner = this.owner;
    entity heldbuff = buff_FirstFromFlags(myowner);
 
    if (!heldbuff)
        return false;
 
    if (myowner.alpha <= 0.5 && myowner.alpha != 0 && DIFF_TEAM(player, myowner))
        return false;
 
    if (MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
        return false;
 
    if (player == myowner)
    {
        // somewhat hide the model, but keep the glow
        this.effects = 0;
        this.alpha = -1;
    }
    else
    {
        this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
        this.alpha = myowner.alpha;
    }
    return true;
}

References alpha, buff_FirstFromFlags(), DIFF_TEAM, EF_FULLBRIGHT, EF_LOWPRECISION, effects, entity(), MUTATOR_CALLHOOK, owner, and WaypointSprite_getviewentity().

Referenced by buffs_BuffModel_Spawn().

buffs_BuffModel_Remove()

void buffs_BuffModel_Remove

(

entity

player

)

Definition at line 70 of file sv_buffs.qc.

{
    if (player.buff_model)
        delete(player.buff_model);
    player.buff_model = NULL;
}

References entity(), and NULL.

Referenced by buffs_RemovePlayer().

buffs_BuffModel_Spawn()

void buffs_BuffModel_Spawn

(

entity

player

)

Definition at line 77 of file sv_buffs.qc.

{
    player.buff_model = new(buff_model);
    setmodel(player.buff_model, MDL_BUFF);
    setsize(player.buff_model, '0 0 -40', '0 0 40');
    setattachment(player.buff_model, player, "");
    setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
    player.buff_model.owner = player;
    player.buff_model.exteriormodeltoclient = player;
    player.buff_model.scale = 0.7;
    player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
    player.buff_model.light_lev = 200;
    setthink(player.buff_model, buffs_BuffModel_Think);
    player.buff_model.nextthink = time;
    setcefc(player.buff_model, buffs_BuffModel_Customize);
}

References buff_model, buffs_BuffModel_Customize(), buffs_BuffModel_Think(), entity(), PFLAGS_FULLDYNAMIC, setcefc, setmodel, setthink, and time.

Referenced by buffs_BuffModel_Update().

buffs_BuffModel_Think()

void buffs_BuffModel_Think

(

entity

this

)

Definition at line 39 of file sv_buffs.qc.

{
    this.nextthink = time;
    entity player = this.owner;
    if (player.alpha < 0 || player.buff_model != this)
    {
        if (player) // remnant from ChatBubbleThink, same question... WHY?!
            player.buff_model = NULL;
        delete(this);
        return;
    }
 
    entity heldbuff = buff_FirstFromFlags(player);
 
    if (!heldbuff)
    {
        this.effects = EF_NODRAW;
        return;
    }
 
    this.color = heldbuff.m_color;
    this.glowmod = heldbuff.m_color;
    this.skin = heldbuff.m_skin;
 
    this.effects = player.effects;
    this.effects |= EF_LOWPRECISION;
    this.effects = this.effects & EFMASK_CHEAP; // eat performance
 
    this.alpha = player.alpha;
}

References alpha, buff_FirstFromFlags(), color, EF_LOWPRECISION, EF_NODRAW, effects, EFMASK_CHEAP, entity(), glowmod, nextthink, NULL, owner, skin, and time.

Referenced by buffs_BuffModel_Spawn().

buffs_BuffModel_Update()

void buffs_BuffModel_Update

(

entity

this

)

Definition at line 94 of file sv_buffs.qc.

{
    if (this.alpha < 0)
        return;
    // spawn a buff model entity if needed
    if (!this.buff_model)
        buffs_BuffModel_Spawn(this);
}

References alpha, buff_model, buffs_BuffModel_Spawn(), and entity().

Referenced by MUTATOR_HOOKFUNCTION().

buffs_DelayedInit()

void buffs_DelayedInit

(

entity

this

)

Definition at line 703 of file sv_buffs.qc.

{
    if (autocvar_g_buffs_spawn_count > 0)
    if (find(NULL, classname, "item_buff") == NULL)
        for (int i = 0; i < autocvar_g_buffs_spawn_count; ++i)
        {
            entity e = spawn();
            e.spawnflags |= 64; // always randomize
            e.velocity = randomvec() * 250; // this gets reset anyway if random location works
            buff_Init(e);
        }
}

References autocvar_g_buffs_spawn_count, buff_Init(), classname, entity(), find(), NULL, randomvec(), and spawn.

Referenced by buffs_Initialize().

buffs_Initialize()

void buffs_Initialize

(

)

Definition at line 716 of file sv_buffs.qc.

{
    // if buffs are above 0, allow random spawning
    if (autocvar_g_buffs > 0 && autocvar_g_buffs_spawn_count > 0)
        InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
}

References autocvar_g_buffs_spawn_count, buffs_DelayedInit(), InitializeEntity(), INITPRIO_FINDTARGET, and NULL.

Referenced by REGISTER_MUTATOR().

buffs_RemovePlayer()

bool buffs_RemovePlayer

(

entity

player

)

Definition at line 635 of file sv_buffs.qc.

{
    buffs_BuffModel_Remove(player);
    return false;
}

References buffs_BuffModel_Remove(), and entity().

Referenced by MUTATOR_HOOKFUNCTION(), and MUTATOR_HOOKFUNCTION().

MUTATOR_HOOKFUNCTION() [1/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		BuildMutatorsPrettyString	)

Definition at line 697 of file sv_buffs.qc.

{
    if (autocvar_g_buffs > 0)
        M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
}

References M_ARGV, and strcat().

MUTATOR_HOOKFUNCTION() [2/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		BuildMutatorsString	)

Definition at line 691 of file sv_buffs.qc.

{
    if (autocvar_g_buffs > 0) // only report as a mutator if they're enabled
        M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
}

References M_ARGV, and strcat().

MUTATOR_HOOKFUNCTION() [3/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		ClientDisconnect	)

Definition at line 645 of file sv_buffs.qc.

{
    entity player = M_ARGV(0, entity);
    return buffs_RemovePlayer(player);
}

References buffs_RemovePlayer(), ClientDisconnect, entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [4/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		Damage_Calculate	)

Definition at line 544 of file sv_buffs.qc.

{
    entity frag_attacker = M_ARGV(1, entity);
    entity frag_target = M_ARGV(2, entity);
    float frag_deathtype = M_ARGV(3, float);
    float frag_damage = M_ARGV(4, float);
    vector frag_force = M_ARGV(6, vector);
 
    if (frag_deathtype == DEATH_BUFF.m_id)
        return;
 
    if (StatusEffects_active(BUFF_RESISTANCE, frag_target))
        frag_damage = buff_Resistance_CalculateDamage(frag_damage);
 
    if (StatusEffects_active(BUFF_MEDIC, frag_target))
    if (GetResource(frag_target, RES_HEALTH) - frag_damage <= 0)
    if (!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
    if (frag_attacker)
        frag_damage = buff_Medic_CalculateSurviveDamage(frag_damage, GetResource(frag_target, RES_HEALTH));
 
    if (StatusEffects_active(BUFF_JUMP, frag_target))
        frag_damage = buff_Jump_ChangeDamage(frag_damage, frag_deathtype);
 
    if (StatusEffects_active(BUFF_VENGEANCE, frag_target))
    if (frag_attacker && frag_attacker != frag_target)
    if (!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
    {
        entity dmgent = new_pure(dmgent);
 
        dmgent.dmg = buff_Vengeance_CalculateDamage(frag_damage);
        dmgent.enemy = frag_attacker;
        dmgent.owner = frag_target;
        setthink(dmgent, buff_Vengeance_DelayedDamage);
        dmgent.nextthink = time + 0.1;
    }
 
    if (StatusEffects_active(BUFF_BASH, frag_target))
        frag_force = buff_Bash_TargetCalculateForce(frag_force, frag_target, frag_attacker);
 
    if (StatusEffects_active(BUFF_BASH, frag_attacker))
        frag_force = buff_Bash_AttackerCalculateForce(frag_force, frag_target, frag_attacker);
 
    if (StatusEffects_active(BUFF_DISABILITY, frag_attacker))
        buff_Disability_ApplyStunned(frag_target, frag_attacker);
 
    if (StatusEffects_active(BUFF_INFERNO, frag_target))
    {
        if (frag_deathtype == DEATH_FIRE.m_id)
            frag_damage = 0;
        if (frag_deathtype == DEATH_LAVA.m_id)
            frag_damage *= 0.5; // TODO: cvarize?
    }
 
    if (frag_attacker != frag_target)
    {
        if (StatusEffects_active(BUFF_LUCK, frag_attacker))
            frag_damage = buff_Luck_CalculateDamage(frag_damage);
 
        if (StatusEffects_active(BUFF_INFERNO, frag_attacker))
        {
            float btime = buff_Inferno_CalculateTime(frag_damage);
            Fire_AddDamage(frag_target, frag_attacker, buff_Inferno_CalculateDamage(frag_damage), btime, DEATH_BUFF.m_id);
        }
    }
 
    M_ARGV(4, float) = frag_damage;
    M_ARGV(6, vector) = frag_force;
}

References buff_Bash_AttackerCalculateForce(), buff_Bash_TargetCalculateForce(), buff_Disability_ApplyStunned(), buff_Inferno_CalculateDamage(), buff_Inferno_CalculateTime(), buff_Jump_ChangeDamage(), buff_Luck_CalculateDamage(), buff_Medic_CalculateSurviveDamage(), buff_Resistance_CalculateDamage(), buff_Vengeance_CalculateDamage(), buff_Vengeance_DelayedDamage(), entity(), Fire_AddDamage(), frag_damage, frag_force, frag_target, GetResource(), ITEM_DAMAGE_NEEDKILL, M_ARGV, new_pure, setthink, StatusEffects_active(), time, and vector.

MUTATOR_HOOKFUNCTION() [5/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		FilterItem	)

Definition at line 651 of file sv_buffs.qc.

{
    if (autocvar_g_buffs < 0)
        return false; // no auto replacing of entities in this mode
 
    entity item = M_ARGV(0, entity);
 
    if (autocvar_g_buffs_replace_powerups && item.itemdef.instanceOfPowerup)
    {
        entity e = spawn();
        buff_SpawnReplacement(e, item);
        return true;
    }
 
    return false;
}

References autocvar_g_buffs_replace_powerups, buff_SpawnReplacement(), entity(), M_ARGV, and spawn.

MUTATOR_HOOKFUNCTION() [6/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		MakePlayerObserver	)

Definition at line 640 of file sv_buffs.qc.

{
    entity player = M_ARGV(0, entity);
    return buffs_RemovePlayer(player);
}

References buffs_RemovePlayer(), entity(), and M_ARGV.

MUTATOR_HOOKFUNCTION() [7/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		PlayerPreThink	)

Definition at line 668 of file sv_buffs.qc.

{
    entity player = M_ARGV(0, entity);
 
    if (game_stopped || IS_DEAD(player) || !IS_PLAYER(player))
        return;
 
    // NOTE: this is kept here to ensure crouches are picked up each player movement frame
    if (StatusEffects_active(BUFF_FLIGHT, player))
    {
        if (!PHYS_INPUT_BUTTON_CROUCH(player))
            player.buff_flight_crouchheld = false;
        else if (!player.buff_flight_crouchheld)
        {
            player.buff_flight_crouchheld = true;
            player.gravity *= -1;
        }
    }
 
    if (IS_PLAYER(player))
        buffs_BuffModel_Update(player);
}

References buffs_BuffModel_Update(), entity(), game_stopped, IS_DEAD, IS_PLAYER, M_ARGV, PHYS_INPUT_BUTTON_CROUCH, PlayerPreThink, and StatusEffects_active().

MUTATOR_HOOKFUNCTION() [8/8]

MUTATOR_HOOKFUNCTION	(	buffs	,
		PlayerUseKey	,
		CBC_ORDER_FIRST	)

Definition at line 613 of file sv_buffs.qc.

{
    if (MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop)
        return;
 
    entity player = M_ARGV(0, entity);
 
    entity heldbuff = buff_FirstFromFlags(player);
    if (heldbuff)
    {
        int buffid = heldbuff.m_id;
        Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
        if (!IS_INDEPENDENT_PLAYER(player))
            Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 
        buff_RemoveAll(player, STATUSEFFECT_REMOVE_NORMAL);
        player.buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
        sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
        return true;
    }
}

References ATTN_NORM, autocvar_g_buffs_drop, autocvar_g_buffs_pickup_delay, buff_FirstFromFlags(), buff_RemoveAll(), CBC_ORDER_FIRST, CH_TRIGGER, entity(), game_stopped, IS_INDEPENDENT_PLAYER, M_ARGV, max(), MUTATOR_RETURNVALUE, PlayerUseKey(), Send_Notification(), sound, STATUSEFFECT_REMOVE_NORMAL, time, and VOL_BASE.

Variable Documentation

buff_seencount

int buff_seencount

Definition at line 267 of file sv_buffs.qc.